diff options
author | Ross Burton <ross.burton@arm.com> | 2023-07-03 13:19:25 +0100 |
---|---|---|
committer | Richard Purdie <richard.purdie@linuxfoundation.org> | 2023-07-10 11:36:34 +0100 |
commit | 238b4ff55e1a1c267dda5277f12b2bcb1fb2f5ea (patch) | |
tree | 3d23c49b90c6bbd691aa4db86ee637ab330595a4 /meta/recipes-multimedia/libtiff/tiff_4.5.1.bb | |
parent | 7379a88457283bd597820a35a33088f688950c73 (diff) | |
download | poky-238b4ff55e1a1c267dda5277f12b2bcb1fb2f5ea.tar.gz |
tiff: upgrade to 4.5.1
Also remove old CVE_CHECK_IGNOREs which are no longer needed due to CPE
updates.
(From OE-Core rev: 2200fde7011c4206382150c2602b2eb17423d45e)
Signed-off-by: Ross Burton <ross.burton@arm.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-multimedia/libtiff/tiff_4.5.1.bb')
-rw-r--r-- | meta/recipes-multimedia/libtiff/tiff_4.5.1.bb | 61 |
1 files changed, 61 insertions, 0 deletions
diff --git a/meta/recipes-multimedia/libtiff/tiff_4.5.1.bb b/meta/recipes-multimedia/libtiff/tiff_4.5.1.bb new file mode 100644 index 0000000000..5af3f84265 --- /dev/null +++ b/meta/recipes-multimedia/libtiff/tiff_4.5.1.bb | |||
@@ -0,0 +1,61 @@ | |||
1 | SUMMARY = "Provides support for the Tag Image File Format (TIFF)" | ||
2 | DESCRIPTION = "Library provides support for the Tag Image File Format \ | ||
3 | (TIFF), a widely used format for storing image data. This library \ | ||
4 | provide means to easily access and create TIFF image files." | ||
5 | HOMEPAGE = "http://www.libtiff.org/" | ||
6 | LICENSE = "BSD-2-Clause" | ||
7 | LIC_FILES_CHKSUM = "file://LICENSE.md;md5=a3e32d664d6db1386b4689c8121531c3" | ||
8 | |||
9 | CVE_PRODUCT = "libtiff" | ||
10 | |||
11 | SRC_URI = "http://download.osgeo.org/libtiff/tiff-${PV}.tar.gz" | ||
12 | |||
13 | SRC_URI[sha256sum] = "d7f38b6788e4a8f5da7940c5ac9424f494d8a79eba53d555f4a507167dca5e2b" | ||
14 | |||
15 | # exclude betas | ||
16 | UPSTREAM_CHECK_REGEX = "tiff-(?P<pver>\d+(\.\d+)+).tar" | ||
17 | |||
18 | # Tested with check from https://security-tracker.debian.org/tracker/CVE-2015-7313 | ||
19 | # and 4.3.0 doesn't have the issue | ||
20 | CVE_CHECK_IGNORE += "CVE-2015-7313" | ||
21 | |||
22 | inherit autotools multilib_header | ||
23 | |||
24 | CACHED_CONFIGUREVARS = "ax_cv_check_gl_libgl=no" | ||
25 | |||
26 | PACKAGECONFIG ?= "cxx jpeg zlib lzma \ | ||
27 | strip-chopping extrasample-as-alpha check-ycbcr-subsampling" | ||
28 | |||
29 | PACKAGECONFIG[cxx] = "--enable-cxx,--disable-cxx,," | ||
30 | PACKAGECONFIG[jbig] = "--enable-jbig,--disable-jbig,jbig," | ||
31 | PACKAGECONFIG[jpeg] = "--enable-jpeg,--disable-jpeg,jpeg," | ||
32 | PACKAGECONFIG[zlib] = "--enable-zlib,--disable-zlib,zlib," | ||
33 | PACKAGECONFIG[lzma] = "--enable-lzma,--disable-lzma,xz," | ||
34 | PACKAGECONFIG[webp] = "--enable-webp,--disable-webp,libwebp," | ||
35 | PACKAGECONFIG[zstd] = "--enable-zstd,--disable-zstd,zstd," | ||
36 | PACKAGECONFIG[libdeflate] = "--enable-libdeflate,--disable-libdeflate,libdeflate," | ||
37 | |||
38 | # Convert single-strip uncompressed images to multiple strips of specified | ||
39 | # size (default: 8192) to reduce memory usage | ||
40 | PACKAGECONFIG[strip-chopping] = "--enable-strip-chopping,--disable-strip-chopping,," | ||
41 | |||
42 | # Treat a fourth sample with no EXTRASAMPLE_ value as being ASSOCALPHA | ||
43 | PACKAGECONFIG[extrasample-as-alpha] = "--enable-extrasample-as-alpha,--disable-extrasample-as-alpha,," | ||
44 | |||
45 | # Control picking up YCbCr subsample info. Disable to support files lacking | ||
46 | # the tag | ||
47 | PACKAGECONFIG[check-ycbcr-subsampling] = "--enable-check-ycbcr-subsampling,--disable-check-ycbcr-subsampling,," | ||
48 | |||
49 | # Support a mechanism allowing reading large strips (usually one strip files) | ||
50 | # in chunks when using TIFFReadScanline. Experimental 4.0+ feature | ||
51 | PACKAGECONFIG[chunky-strip-read] = "--enable-chunky-strip-read,--disable-chunky-strip-read,," | ||
52 | |||
53 | PACKAGES =+ "tiffxx tiff-utils" | ||
54 | FILES:tiffxx = "${libdir}/libtiffxx.so.*" | ||
55 | FILES:tiff-utils = "${bindir}/*" | ||
56 | |||
57 | do_install:append() { | ||
58 | oe_multilib_header tiffconf.h | ||
59 | } | ||
60 | |||
61 | BBCLASSEXTEND = "native nativesdk" | ||