pax-utils: 1.0.5 -> 1.1.4

- Support autotools:
  *) Touch NEWS/AUTHORS/ChangeLog to workaroud failure
     caused by 'automake --add-missing'
  *) Add patch to fix configure failure caused by missing
     macro definition in m4 directory

- Add PACKAGECONFIG flags for libcap, libseccomp and pyelftools,
  and disable them by default.

- Add PACKAGECONFIG flag for largefile.

- Since we add PACKAGECONFIG flags for pyelftools, we do not need
  python in RDEPENDS.

BTW:
Currently oe-core does not support libseccomp.
(https://github.com/seccomp/libseccomp)

Currently oe-core does not support pyelftools.
(https://github.com/eliben/pyelftools)

(From OE-Core rev: d966a4ed8f0de7dc9b08880505c668421e6d4488)

Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 36 insertions, 0 deletions

diff --git a/meta/recipes-devtools/pax-utils/pax-utils_1.1.4.bb b/meta/recipes-devtools/pax-utils/pax-utils_1.1.4.bb
new file mode 100644
index 0000000000..48b342e2e3
--- /dev/null
+++ b/meta/recipes-devtools/pax-utils/pax-utils_1.1.4.bb
@@ -0,0 +1,36 @@
+SUMMARY = "Security-focused ELF files checking tool"
+DESCRIPTION = "This is a small set of various PaX aware and related \
+utilities for ELF binaries. It can check ELF binary files and running \
+processes for issues that might be relevant when using ELF binaries \
+along with PaX, such as non-PIC code or executable stack and heap."
+HOMEPAGE = "http://www.gentoo.org/proj/en/hardened/pax-utils.xml"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=eb723b61539feef013de476e68b5c50a"
+
+SRC_URI = "http://gentoo.osuosl.org/distfiles/pax-utils-${PV}.tar.xz \
+           file://fix-configure-failure.patch \
+"
+
+SRC_URI[md5sum] = "1bfbb5237881f0c5e476b2f7ffcc00d5"
+SRC_URI[sha256sum] = "796860fbd48c5f811e699e8492dc1110459bad0a62efa8d346b74a4f6f556414"
+
+RDEPENDS_${PN} += "bash"
+
+do_configure_prepend() {
+    touch ${S}/NEWS ${S}/AUTHORS ${S}/ChangeLog
+}
+
+do_install() {
+    oe_runmake PREFIX=${D}${prefix} DESTDIR=${D} install
+}
+
+BBCLASSEXTEND = "native"
+
+inherit autotools pkgconfig
+
+PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'largefile', 'largefile', '', d)} \
+"
+PACKAGECONFIG[libcap] = "--with-caps, --without-caps, libcap"
+PACKAGECONFIG[libseccomp] = "--with-seccomp, --without-seccomp, libseccomp"
+PACKAGECONFIG[largefile] = "--enable-largefile,--disable-largefile,,"
+PACKAGECONFIG[pyelftools] = "--with-python, --without-python,, pyelftools"