diff options
author | Andreas Müller <schnitzeltony@gmail.com> | 2018-03-18 20:08:33 +0100 |
---|---|---|
committer | Armin Kuster <akuster808@gmail.com> | 2018-03-29 16:45:05 -0700 |
commit | 2a8a5b5cd0258657e145f65f54c3145e42116f7c (patch) | |
tree | d90faf0a51bc39f728afb29145ada94b2334591d /meta-oe/recipes-support/poppler/poppler_0.62.0.bb | |
parent | 2a3bc6d719068bd71b7c6daae200fce2c0958ead (diff) | |
download | meta-openembedded-2a8a5b5cd0258657e145f65f54c3145e42116f7c.tar.gz |
poppler: update 0.57.0 -> 0.62.0
* poppler moved from autotools to cmake
* qt4 backend was removed
* build tested with all and none in packageconfig
Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
Signed-off-by: Armin Kuster <akuster808@gmail.com>
Diffstat (limited to 'meta-oe/recipes-support/poppler/poppler_0.62.0.bb')
-rw-r--r-- | meta-oe/recipes-support/poppler/poppler_0.62.0.bb | 55 |
1 files changed, 55 insertions, 0 deletions
diff --git a/meta-oe/recipes-support/poppler/poppler_0.62.0.bb b/meta-oe/recipes-support/poppler/poppler_0.62.0.bb new file mode 100644 index 000000000..696621938 --- /dev/null +++ b/meta-oe/recipes-support/poppler/poppler_0.62.0.bb | |||
@@ -0,0 +1,55 @@ | |||
1 | SUMMARY = "Poppler is a PDF rendering library based on the xpdf-3.0 code base" | ||
2 | LICENSE = "GPLv2" | ||
3 | LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe" | ||
4 | |||
5 | SRC_URI = " \ | ||
6 | http://poppler.freedesktop.org/${BP}.tar.xz \ | ||
7 | file://0001-Do-not-overwrite-all-our-build-flags.patch \ | ||
8 | " | ||
9 | SRC_URI[md5sum] = "42b801f2defaccb6b6cf1bf783ee1552" | ||
10 | SRC_URI[sha256sum] = "5b9a73dfd4d6f61d165ada1e4f0abd2d420494bf9d0b1c15d0db3f7b83a729c6" | ||
11 | |||
12 | DEPENDS = "fontconfig zlib cairo lcms" | ||
13 | |||
14 | inherit cmake pkgconfig gobject-introspection | ||
15 | |||
16 | PACKAGECONFIG ??= "jpeg openjpeg png tiff nss ${@bb.utils.contains('BBFILE_COLLECTIONS', 'qt5-layer', 'qt5', '', d)}" | ||
17 | PACKAGECONFIG[jpeg] = "-DWITH_JPEG=ON -DENABLE_DCTDECODER=libjpeg,-DWITH_JPEG=OFF -DENABLE_DCTDECODER=none,jpeg" | ||
18 | PACKAGECONFIG[png] = "-DWITH_PNG=ON,-DWITH_PNG=OFF,libpng" | ||
19 | PACKAGECONFIG[tiff] = "-DWITH_TIFF=ON,-DWITH_TIFF=OFF,tiff" | ||
20 | PACKAGECONFIG[curl] = "-DENABLE_LIBCURL=ON,-DENABLE_LIBCURL=OFF,curl" | ||
21 | PACKAGECONFIG[openjpeg] = "-DENABLE_LIBOPENJPEG=openjpeg2,-DENABLE_LIBOPENJPEG=none,openjpeg" | ||
22 | PACKAGECONFIG[qt5] = "-DENABLE_QT5=ON,-DENABLE_QT5=OFF,qtbase qttools-native" | ||
23 | PACKAGECONFIG[nss] = "-DWITH_NSS3=ON,-DWITH_NSS3=OFF,nss" | ||
24 | |||
25 | # surprise - did not expect this to work :) | ||
26 | inherit ${@bb.utils.contains('PACKAGECONFIG', 'qt5', 'cmake_qt5', '', d)} | ||
27 | |||
28 | SECURITY_CFLAGS = "${SECURITY_NO_PIE_CFLAGS}" | ||
29 | |||
30 | EXTRA_OECMAKE += " \ | ||
31 | -DENABLE_XPDF_HEADERS=ON \ | ||
32 | -DBUILD_GTK_TESTS=OFF \ | ||
33 | -DENABLE_ZLIB=ON \ | ||
34 | " | ||
35 | |||
36 | do_configure_append() { | ||
37 | # poppler macro uses pkg-config to check for g-ir runtimes. Something | ||
38 | # makes them point to /usr/bin. Align them to sysroot - that's where the | ||
39 | # git-wrappers are: | ||
40 | sed -i 's: ${bindir}/g-ir: ${STAGING_BINDIR}/g-ir:' ${B}/build.ninja | ||
41 | } | ||
42 | |||
43 | # check for TARGET_FPU=soft and inform configure of the result so it can disable some floating points | ||
44 | def get_poppler_fpu_setting(bb, d): | ||
45 | if d.getVar('TARGET_FPU') in [ 'soft' ]: | ||
46 | return "-DUSE_FIXEDPOINT=ON" | ||
47 | return "" | ||
48 | |||
49 | EXTRA_OECMAKE += "${@get_poppler_fpu_setting(bb, d)}" | ||
50 | |||
51 | PACKAGES =+ "libpoppler libpoppler-glib" | ||
52 | FILES_libpoppler = "${libdir}/libpoppler.so.*" | ||
53 | FILES_libpoppler-glib = "${libdir}/libpoppler-glib.so.*" | ||
54 | |||
55 | RDEPENDS_libpoppler = "poppler-data" | ||