bluealsa: upgrade 4.0.0+git -> 4.3.0

The change in the license file was the update of the year in the copyright
line.

glib-2.0-native and python3-packaging-native (with python3native) is
required to have gdbus-codegen at build time.

Signed-off-by: Jörg Sommer <joerg.sommer@navimatix.de>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 25 insertions, 13 deletions

diff --git a/meta-multimedia/recipes-multimedia/bluealsa/bluealsa_git.bb b/meta-multimedia/recipes-multimedia/bluealsa/bluealsa_4.3.0.bb
index 5007c88ff..419d6e8d2 100644
--- a/meta-multimedia/recipes-multimedia/bluealsa/bluealsa_git.bb
+++ b/meta-multimedia/recipes-multimedia/bluealsa/bluealsa_4.3.0.bb
@@ -1,22 +1,30 @@
 SUMMARY = "Bluetooth Audio ALSA Backend"
+DESCRIPTION = "\
+    BlueALSA is a replacement for BlueZ >= 5, with which one can achieve the \
+    same Bluetooth audio profile support as with PulseAudio, but with fewer \
+    dependencies and at a lower level in the software stack. It is designed \
+    specifically for use on small, low-powered, dedicated audio or audio/visual \
+    systems where the high-level audio management features of PulseAudio or \
+    PipeWire are not required. \
+"
 HOMEPAGE = "https://github.com/Arkq/bluez-alsa"
+BUGTRACKER = "https://github.com/arkq/bluez-alsa/issues"
 SECTION = "libs"
 
 LICENSE = "MIT"
-LIC_FILES_CHKSUM = "file://LICENSE;md5=8449a4f133a93f6254b496d4fb476e83"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=143bc4e73f39cc5e89d6e096ac0315ba"
 
-SRC_URI = "git://github.com/Arkq/bluez-alsa.git;protocol=https;branch=master"
+DEPENDS += "alsa-lib bluez5 dbus glib-2.0-native python3-packaging-native sbc"
 
-SRCREV = "dd05a1baa261b94da9ba977b5e3392c8b4dc7a5e"
-PV = "4.0.0+git"
+SRC_URI = "git://github.com/Arkq/bluez-alsa.git;protocol=https;branch=master"
 
-S  = "${WORKDIR}/git"
+SRCREV = "959573c2cccef5cf074f5b2fa7941abbd699c5f4"
 
-DEPENDS += "alsa-lib bluez5 dbus glib-2.0 sbc"
+S = "${WORKDIR}/git"
 
 PACKAGECONFIG ??= "aplay cli hcitop ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
-PACKAGECONFIG[a2dpconf]  = "--enable-a2dpconf,--disable-a2dpconf"
-PACKAGECONFIG[aac]  = "--enable-aac,--disable-aac,fdk-aac"
+PACKAGECONFIG[a2dpconf] = "--enable-a2dpconf,--disable-a2dpconf"
+PACKAGECONFIG[aac] = "--enable-aac,--disable-aac,fdk-aac"
 PACKAGECONFIG[aplay] = "--enable-aplay,--disable-aplay"
 PACKAGECONFIG[cli] = "--enable-cli,--disable-cli"
 PACKAGECONFIG[coverage] = "--with-coverage,--without-coverage,lcov-native"
@@ -25,8 +33,10 @@ PACKAGECONFIG[debug-time] = "--enable-debug-time,--disable-debug-time"
 PACKAGECONFIG[faststream] = "--enable-faststream,--disable-faststream"
 PACKAGECONFIG[hcitop] = "--enable-hcitop,--disable-hcitop,libbsd ncurses"
 PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind"
+PACKAGECONFIG[midi] = "--enable-midi,--disable-midi"
 PACKAGECONFIG[mp3lame] = "--enable-mp3lame,--disable-mp3lame,lame"
 PACKAGECONFIG[mpg123] = "--enable-mpg123,--disable-mpg123,mpg123,mpg123"
+PACKAGECONFIG[msbc] = "--enable-msbc,--disable-msbc,spandsp"
 PACKAGECONFIG[ofono] = "--enable-ofono,--disable-ofono,ofono"
 PACKAGECONFIG[payloadcheck] = "--enable-payloadcheck,--disable-payloadcheck"
 PACKAGECONFIG[rfcomm] = "--enable-rfcomm,--disable-rfcomm"
@@ -35,9 +45,10 @@ PACKAGECONFIG[systemd] = "--enable-systemd --with-systemdsystemunitdir=${systemd
 PACKAGECONFIG[test] = "--enable-test,--disable-test,libcheck libsndfile1"
 PACKAGECONFIG[upower] = "--enable-upower,--disable-upower,,upower"
 
-inherit autotools pkgconfig systemd
+inherit autotools pkgconfig python3native systemd
 
-EXTRA_OECONF = " \
+# These proprietary codecs are not available in Yocto
+EXTRA_OECONF = "\
     --disable-aptx \
     --disable-lc3plus \
     --disable-ldac \
@@ -45,10 +56,11 @@ EXTRA_OECONF = " \
 "
 
 PACKAGE_BEFORE_PN = "${PN}-aplay"
-RRECOMMENDS:${PN} = "${PN}-aplay"
 
-FILES:${PN}-aplay = "${bindir}/bluealsa-aplay"
-FILES:${PN} += "${libdir}/alsa-lib/*"
+FILES:${PN}-aplay += "${bindir}/bluealsa-aplay"
+FILES:${PN} += "${libdir}/alsa-lib/* ${datadir}/dbus-1/system.d"
+
+RRECOMMENDS:${PN} = "${PN}-aplay"
 
 SYSTEMD_PACKAGES += "${PN}-aplay"
 SYSTEMD_SERVICE:${PN} = "bluealsa.service"