initials: silence "populate_sysroot manifest not found" warnings

A number of recipes in meta-java use autotools.bbclass for building; internally
it uses the sstate-control populate_sysroot manifests to locate and copy
aslocals for configure dependencies as part of the do_configure step.
The manifest path differs depending on if it's a native package or not so
autotools.bbclass looks at the package name to determine if its native or not
(it's native if it ends with "-native").

The warnings are emitted because a few (native) recipes in meta-java (such as
cacao-initial, classpath-initial and more) are incorrectly being classified as
non-native by autotools.bbclass, which makes it look for the manifest in the
wrong place and finally gives up with the warning:

WARNING: /home/oe/tmp-glibc/sstate-control/manifest-mymachine-libecj-bootstrap.populate_sysroot not found

This happens for cacao-initial, classpath-initial, ecj-initial, libecj-boostrap,
jamvm-initial and jikes-initial since they are all native and rely on autotools.

This patch renames the recipes so they end with -native, e.g ecj-initial-native.
It also updates the recipes so they DEPEND on the corresponding new name. This
helps autotools.bbclass to properly classify the recipes are native and silence
the warnings.

Signed-off-by: Magnus Olsson <magnus@minimum.se>
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

1 files changed, 50 insertions, 0 deletions

diff --git a/recipes-core/classpath/classpath-initial-native_0.93.bb b/recipes-core/classpath/classpath-initial-native_0.93.bb
new file mode 100644
index 0000000..0cfa693
--- /dev/null
+++ b/recipes-core/classpath/classpath-initial-native_0.93.bb
@@ -0,0 +1,50 @@
+# No later version of Classpath may be used because this is the latest that can be compiled
+# by jikes!
+
+require classpath-native.inc
+
+DESCRIPTION="Java1.4-compatible GNU Classpath variant that is used as bootclasspath for jikes-native."
+LIC_FILES_CHKSUM = "file://COPYING;md5=af0004801732bc4b20d90f351cf80510"
+DEPENDS += "jikes-native"
+
+PR = "${INC_PR}.2"
+
+SRC_URI += " \
+            file://autotools.patch \
+            file://miscompilation.patch \
+           "
+
+EXTRA_OECONF = " \
+                --with-jikes=jikes \
+                --with-fastjar=fastjar \
+                --with-glibj \
+                --disable-Werror \
+                --disable-local-sockets \
+                --disable-alsa \
+                --disable-gconf-peer \
+                --disable-gtk-peer \
+                --disable-plugin \
+                --disable-dssi \
+                --disable-examples \
+                --with-glibj-dir=${STAGING_DATADIR_NATIVE}/classpath-initial \
+                --with-native-libdir=${STAGING_LIBDIR_NATIVE}/classpath-initial \
+                --includedir=${STAGING_INCDIR_NATIVE}/classpath-initial \
+                --with-vm=java \
+              "
+
+# Ensure tools.zip is not installed at same path as classpath-native
+EXTRA_OEMAKE += "pkgdatadir=${STAGING_DATADIR_NATIVE}/classpath-initial"
+
+# remove files clashing with classpath-native in sysroot
+do_install_append() {
+
+        for i in gappletviewer gjarsigner gkeytool gjar gnative2ascii gserialver grmiregistry gtnameserv gorbd grmid
+        do
+                rm ${D}${bindir}/${i}
+        done
+        rm ${D}${libdir}/logging.properties
+        rm ${D}${libdir}/security/classpath.security
+}
+SRC_URI[md5sum] = "ffa9e9cac31c5acbf0ea9eff9efa923d"
+SRC_URI[sha256sum] = "df2d093612abd23fe67e9409d89bb2a8e79b1664fe2b2da40e1c8ed693e32945"
+