initials: silence "populate_sysroot manifest not found" warnings

A number of recipes in meta-java use autotools.bbclass for building; internally
it uses the sstate-control populate_sysroot manifests to locate and copy
aslocals for configure dependencies as part of the do_configure step.
The manifest path differs depending on if it's a native package or not so
autotools.bbclass looks at the package name to determine if its native or not
(it's native if it ends with "-native").

The warnings are emitted because a few (native) recipes in meta-java (such as
cacao-initial, classpath-initial and more) are incorrectly being classified as
non-native by autotools.bbclass, which makes it look for the manifest in the
wrong place and finally gives up with the warning:

WARNING: /home/oe/tmp-glibc/sstate-control/manifest-mymachine-libecj-bootstrap.populate_sysroot not found

This happens for cacao-initial, classpath-initial, ecj-initial, libecj-boostrap,
jamvm-initial and jikes-initial since they are all native and rely on autotools.

This patch renames the recipes so they end with -native, e.g ecj-initial-native.
It also updates the recipes so they DEPEND on the corresponding new name. This
helps autotools.bbclass to properly classify the recipes are native and silence
the warnings.

Signed-off-by: Magnus Olsson <magnus@minimum.se>
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

1 files changed, 42 insertions, 0 deletions

diff --git a/recipes-core/cacao/cacao-initial-native_0.98.bb b/recipes-core/cacao/cacao-initial-native_0.98.bb
new file mode 100644
index 0000000..181faca
--- /dev/null
+++ b/recipes-core/cacao/cacao-initial-native_0.98.bb
@@ -0,0 +1,42 @@
+DESCRIPTION = "CacaoVM for use as OpenEmbedded's Java VM"
+HOMEPAGE = "http://www.cacaojvm.org/"
+LICENSE  = "GPL-2.0"
+LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552"
+SECTION  = "interpreters"
+
+PROVIDES = "virtual/java-initial"
+
+inherit native autotools-brokensep
+
+DEPENDS = "zlib-native libtool-native fastjar-native classpath-initial-native jikes-initial-native"
+
+SRC_URI = "\
+        http://www.complang.tuwien.ac.at/cacaojvm/download/cacao-${PV}/cacao-${PV}.tar.bz2; \
+        file://cacao-0.98-initial.patch \
+        file://disable_hw_exceptions.patch \
+        "
+
+# libjvm disabled - it would conflict with cacao-native installations
+EXTRA_OECONF = "\
+    --enable-debug \
+    --with-classpath-libdir=${libdir} \
+    --with-classpath-includedir=${includedir}/classpath-initial \
+    --with-classpath-classes=${datadir}/classpath-initial/glibj.zip \
+    --with-vm-zip=${datadir}/cacao-initial/vm.zip \
+    --program-suffix=-initial \
+    --disable-libjvm \
+    "
+
+# enforces the usage of jikes-initial
+export JAVAC="jikes-initial"
+
+# enforces the usage of fastjar
+export JAR="fastjar"
+
+do_configure_append() {
+  # Fix the executable name in the wrapper script.
+  sed -i -e "s|exec cacao|exec cacao-initial|" src/scripts/java.in
+}
+
+SRC_URI[md5sum] = "8b8907c8b925761c9410bcadb9705346"
+SRC_URI[sha256sum] = "cb9363add825cedf77764fc49a223aaf43f0a9f485b711ba8c92f16b13fff188"