2 files changed, 80 insertions, 0 deletions

diff --git a/dynamic-layers/openembedded-layer/recipes-bsp/thermald/files/0001-Makefile-Fix-build-Issue.patch b/dynamic-layers/openembedded-layer/recipes-bsp/thermald/files/0001-Makefile-Fix-build-Issue.patch
new file mode 100644
index 00000000..ea86bc31
--- /dev/null
+++ b/dynamic-layers/openembedded-layer/recipes-bsp/thermald/files/0001-Makefile-Fix-build-Issue.patch
@@ -0,0 +1,35 @@
+From 1f6f4e29769adb9d49a3c4831dd2ba61f6ccbdce Mon Sep 17 00:00:00 2001
+From: Yogesh Tyagi <yogesh.tyagi@intel.com>
+Date: Mon, 11 Mar 2024 13:13:32 +0800
+Subject: [PATCH] Makefile: Fix build Issue
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+In case build directory is different from source, make sure make is able to find the correct input files.
+
+Fixes:
+| dbus-binding-tool --prefix=thd_dbus_interface --mode=glib-server --output=thd_dbus_interface.h ../git/src/thd_dbus_interface.xml
+| glib-compile-resources --generate-source thermald-resource.gresource.xml
+| Failed to open file “thermald-resource.gresource.xml”: No such file or directory
+
+Upstream-Status: Submitted
+https://github.com/intel/thermal_daemon/pull/436
+
+Signed-off-by: Yogesh Tyagi <yogesh.tyagi@intel.com>
+---
+ Makefile.am | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/Makefile.am b/Makefile.am
+index dd2ef10..cb19e17 100644
+--- a/Makefile.am
++++ b/Makefile.am
+@@ -97,6 +97,6 @@ thd_dbus_interface.h: $(top_srcdir)/src/thd_dbus_interface.xml
+        $(AM_V_GEN) dbus-binding-tool --prefix=thd_dbus_interface --mode=glib-server --output=$@ $<
+ 
+ thermald-resource.c: $(top_srcdir)/thermald-resource.gresource.xml
+-       $(AM_V_GEN) glib-compile-resources --generate-source thermald-resource.gresource.xml
++       $(AM_V_GEN) glib-compile-resources --generate-source --sourcedir=${top_srcdir} $<
+ 
+ CLEANFILES = $(BUILT_SOURCES)
diff --git a/dynamic-layers/openembedded-layer/recipes-bsp/thermald/thermald_2.5.7.bb b/dynamic-layers/openembedded-layer/recipes-bsp/thermald/thermald_2.5.7.bb
new file mode 100644
index 00000000..66765e56
--- /dev/null
+++ b/dynamic-layers/openembedded-layer/recipes-bsp/thermald/thermald_2.5.7.bb
@@ -0,0 +1,45 @@
+SUMMARY = "Linux thermal daemon"
+
+DESCRIPTION = "Thermal Daemon is a Linux daemon used to prevent the \
+overheating of platforms. This daemon monitors temperature and applies \
+compensation using available cooling methods."
+
+HOMEPAGE = "https://github.com/01org/thermal_daemon"
+
+DEPENDS = "dbus dbus-glib dbus-glib-native libxml2 glib-2.0 glib-2.0-native upower libevdev"
+DEPENDS += "autoconf-archive-native"
+
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=ea8831610e926e2e469075b52bf08848"
+
+SRC_URI = "git://github.com/intel/thermal_daemon/;branch=master;protocol=https \
+           file://0001-Makefile-Fix-build-Issue.patch \
+           "
+
+SRCREV = "ea8b773f76641a7a49d6584669e17371c22ad03e"
+S = "${WORKDIR}/git"
+
+inherit pkgconfig autotools systemd gtk-doc
+
+# gtkdocsize runs before autotools do_configure and it copies gtk-doc.m4 and fails
+# to copy becuase there is no m4 dir yet.
+do_configure:prepend () {
+        mkdir -p ${S}/m4
+}
+
+EXTRA_OECONF = " \
+                 --with-systemdsystemunitdir=${systemd_system_unitdir} \
+                 "
+
+FILES:${PN} += "${datadir}/dbus-1"
+
+SYSTEMD_SERVICE:${PN} = "thermald.service"
+
+COMPATIBLE_HOST = '(i.86|x86_64).*-linux'
+
+CONFFILES:${PN} = " \
+                   ${sysconfdir}/thermald/thermal-conf.xml \
+                   ${sysconfdir}/thermald/thermal-cpu-cdev-order.xml \
+                  "
+
+UPSTREAM_CHECK_URI = "https://github.com/01org/thermal_daemon/releases"