u-boot-fslc: Upgrade to 2018.09-based fork

This updates the fork to current 2018.09 release and apply following
changes on top:

62f2841dc4 pico-imx6ul: Add instructions for booting in Falcon mode
a803c01c03 pico-imx6ul: Add Falcon mode support
3e5f58a2a4 wandboard: README: Include the mx6qp variant in the list
28b8458749 imx: imx6ull: fix pinmux input_val for uart5 rx pin
1bc802f9cc pico-imx6ul: Remove CONFIG_FSL_USDHC from .h
cc97092f7c pico-imx6ul: Add new pico-hobbit config
11aaa94cd8 pico-imx6ul: Sync README with pico-imx7d
52723c960f pico-imx6ul: Improve default DFU settings
c90fa9c1a2 pico-imx6ul: Add bootmenu to choose the baseboard
2141bc7952 pico-imx6ul: Sync defconfig with new changes
9ff1d5305d pico-imx6ul: Update the README file
2b0e81461c pico-imx6ul: Add support for the 512MB module
e45ab0b309 pico-imx6ul: Add bmode support
ad3c1b13d8 pico-imx6ul: Add fastboot support
fa2c10bbac pico-imx6ul: Convert to SPL
b143e3f027 pico-imx6ul: Convert to distro config
a9c45f15b2 mx6sabre_common: Allow the videoargs to be passed to bootargs
b584b845b1 mx25pdk: Change root to use a single partition layout
146e490814 mx6sabre_common: Dynamically change the video output
a278950282 mx6sabresd: Enable video interfaces in bootargs
77cac8a16e mx6sabresd: Use LDO dtb file until LDO bypass support is added
be4d1c4100 mx6slevk: Use LDO dtb file until LDO bypass support is added

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

1 files changed, 30 insertions, 0 deletions

diff --git a/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2018.09.bb b/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2018.09.bb
new file mode 100644
index 00000000..ed32a274
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2018.09.bb
@@ -0,0 +1,30 @@
+require u-boot-fslc-common_${PV}.inc
+
+DESCRIPTION = "U-boot bootloader mxsboot tool"
+SECTION = "bootloader"
+
+DEPENDS = "dtc openssl"
+
+PROVIDES = "u-boot-mxsboot"
+
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE="${TARGET_PREFIX}" CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1 CONFIG_MX28=y'
+EXTRA_OEMAKE_class-native = 'CC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1 CONFIG_MX28=y'
+EXTRA_OEMAKE_class-nativesdk = 'CROSS_COMPILE="${HOST_PREFIX}" CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1 CONFIG_MX28=y'
+
+do_compile () {
+    oe_runmake sandbox_defconfig
+
+    # Disable CONFIG_CMD_LICENSE, license.h is not used by tools and
+    # generating it requires bin2header tool, which for target build
+    # is built with target tools and thus cannot be executed on host.
+    sed -i "s/CONFIG_CMD_LICENSE=.*/# CONFIG_CMD_LICENSE is not set/" .config
+
+    oe_runmake cross_tools NO_SDL=1
+}
+
+do_install () {
+    install -Dm 0755 tools/mxsboot ${D}${bindir}/uboot-mxsboot
+    ln -sf uboot-mxsboot ${D}${bindir}/mxsboot
+}
+
+BBCLASSEXTEND = "native nativesdk"