blob: 23a4b228a90da9a465f3514982f2d5cf47f2d0e0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
SUMMARY = "Xlib: C Language X Interface library"
DESCRIPTION = "This package provides a client interface to the X Window \
System, otherwise known as 'Xlib'. It provides a complete API for the \
basic functions of the window system."
require xorg-lib-common.inc
LICENSE = "MIT & BSD-1-Clause & HPND & HPND-sell-variant & ISC"
LIC_FILES_CHKSUM = "file://COPYING;md5=1d49cdd2b386c5db11ec636d680b7116"
DEPENDS += "xorgproto \
xtrans \
libxcb \
xorgproto-native \
"
PROVIDES = "virtual/libx11"
PE = "1"
XORG_PN = "libX11"
SRC_URI += "file://disable_tests.patch \
file://99_x11"
SRC_URI[sha256sum] = "fa026f9bb0124f4d6c808f9aef4057aad65e7b35d8ff43951cef0abe06bb9a9a"
inherit gettext
EXTRA_OECONF += "--with-keysymdefdir=${STAGING_INCDIR}/X11/ --disable-xf86bigfont"
EXTRA_OEMAKE += 'CWARNFLAGS=""'
PACKAGECONFIG ??= "xcms"
PACKAGECONFIG[xcms] = "--enable-xcms,--disable-xcms"
PACKAGES =+ "${PN}-xcb"
do_install:append() {
# temporary directory required for x11 domain sockets
# systemd provides their own definition using tmpfiles.d
if ${@oe.utils.conditional('VIRTUAL-RUNTIME_init_manager', 'systemd', 'false', 'true', d)}; then
install -d ${D}${sysconfdir}/default/volatiles
install -m 0644 ${UNPACKDIR}/99_x11 ${D}${sysconfdir}/default/volatiles/99_x11
fi
}
FILES:${PN} += "${datadir}/X11/XKeysymDB ${datadir}/X11/XErrorDB ${datadir}/X11/Xcms.txt \
${libdir}/tmpfiles.d/x11.conf ${sysconfdir}/default/volatiles/99_x11"
FILES:${PN}-xcb += "${libdir}/libX11-xcb.so.*"
FILES:${PN}-locale += "${datadir}/X11/locale ${libdir}/X11/locale"
BBCLASSEXTEND = "native nativesdk"
|
