blob: 8ee43a3dc8f61eeb6f1c03dbd5a68585fa471424 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
SUMMARY = "A minimal seat management daemon, and a universal seat management library."
DESCRIPTION = "Seat management takes care of mediating access to shared devices (graphics, input), without requiring the applications needing access to be root."
HOMEPAGE = "https://git.sr.ht/~kennylevinsen/seatd"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://LICENSE;md5=715a99d2dd552e6188e74d4ed2914d5a"
SRC_URI = "git://git.sr.ht/~kennylevinsen/seatd;protocol=https;branch=master \
file://init"
SRCREV = "566ffeb032af42865dc1210e48cec08368059bb9"
S = "${WORKDIR}/git"
inherit meson pkgconfig systemd update-rc.d useradd
# https://www.openwall.com/lists/musl/2020/01/20/3
CFLAGS:append:libc-musl:powerpc64le = " -Wno-error=overflow"
PACKAGECONFIG ?= " \
${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
libseat-builtin \
"
PACKAGECONFIG[libseat-builtin] = "-Dlibseat-builtin=enabled,-Dlibseat-builtin=disabled"
PACKAGECONFIG[systemd] = "-Dlibseat-logind=systemd,,systemd"
do_install:append() {
if [ "${VIRTUAL-RUNTIME_init_manager}" != "systemd" ]; then
install -Dm755 ${UNPACKDIR}/init ${D}/${sysconfdir}/init.d/seatd
else
install -Dm644 ${S}/contrib/systemd/seatd.service ${D}${systemd_unitdir}/system/seatd.service
fi
}
USERADD_PACKAGES = "${PN}"
GROUPADD_PARAM:${PN} = "-r seat"
INITSCRIPT_NAME = "seatd"
INITSCRIPT_PARAMS = "start 9 5 2 . stop 20 0 1 6 ."
INHIBIT_UPDATERCD_BBCLASS = "${@oe.utils.conditional('VIRTUAL-RUNTIME_init_manager', 'systemd', '1', '', d)}"
SYSTEMD_SERVICE:${PN} = "seatd.service"
|
