summaryrefslogtreecommitdiffstats
path: root/meta/recipes-core/systemd/systemd_250.1.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-core/systemd/systemd_250.1.bb')
-rw-r--r--meta/recipes-core/systemd/systemd_250.1.bb792
1 files changed, 792 insertions, 0 deletions
diff --git a/meta/recipes-core/systemd/systemd_250.1.bb b/meta/recipes-core/systemd/systemd_250.1.bb
new file mode 100644
index 0000000000..b05905b764
--- /dev/null
+++ b/meta/recipes-core/systemd/systemd_250.1.bb
@@ -0,0 +1,792 @@
1require systemd.inc
2
3PROVIDES = "udev"
4
5PE = "1"
6
7DEPENDS = "intltool-native gperf-native libcap util-linux python3-jinja2-native"
8
9SECTION = "base/shell"
10
11inherit useradd pkgconfig meson perlnative update-rc.d update-alternatives qemu systemd gettext bash-completion manpages features_check
12
13# As this recipe builds udev, respect systemd being in DISTRO_FEATURES so
14# that we don't build both udev and systemd in world builds.
15REQUIRED_DISTRO_FEATURES = "systemd"
16
17SRC_URI += "file://touchscreen.rules \
18 file://00-create-volatile.conf \
19 ${@bb.utils.contains('PACKAGECONFIG', 'polkit_hostnamed_fallback', 'file://org.freedesktop.hostname1_no_polkit.conf', '', d)} \
20 ${@bb.utils.contains('PACKAGECONFIG', 'polkit_hostnamed_fallback', 'file://00-hostnamed-network-user.conf', '', d)} \
21 file://init \
22 file://99-default.preset \
23 file://systemd-pager.sh \
24 file://0001-binfmt-Don-t-install-dependency-links-at-install-tim.patch \
25 file://0003-implment-systemd-sysv-install-for-OE.patch \
26 file://0001-systemd.pc.in-use-ROOTPREFIX-without-suffixed-slash.patch \
27 file://0001-test-parse-argument-Include-signal.h.patch \
28 "
29
30# patches needed by musl
31SRC_URI:append:libc-musl = " ${SRC_URI_MUSL}"
32SRC_URI_MUSL = "\
33 file://0002-don-t-use-glibc-specific-qsort_r.patch \
34 file://0003-missing_type.h-add-__compare_fn_t-and-comparison_fn_.patch \
35 file://0004-add-fallback-parse_printf_format-implementation.patch \
36 file://0005-src-basic-missing.h-check-for-missing-strndupa.patch \
37 file://0006-Include-netinet-if_ether.h.patch \
38 file://0007-don-t-fail-if-GLOB_BRACE-and-GLOB_ALTDIRFUNC-is-not-.patch \
39 file://0008-add-missing-FTW_-macros-for-musl.patch \
40 file://0009-fix-missing-of-__register_atfork-for-non-glibc-build.patch \
41 file://0010-Use-uintmax_t-for-handling-rlim_t.patch \
42 file://0011-test-sizeof.c-Disable-tests-for-missing-typedefs-in-.patch \
43 file://0012-don-t-pass-AT_SYMLINK_NOFOLLOW-flag-to-faccessat.patch \
44 file://0013-Define-glibc-compatible-basename-for-non-glibc-syste.patch \
45 file://0014-Do-not-disable-buffering-when-writing-to-oom_score_a.patch \
46 file://0015-distinguish-XSI-compliant-strerror_r-from-GNU-specif.patch \
47 file://0016-Hide-__start_BUS_ERROR_MAP-and-__stop_BUS_ERROR_MAP.patch \
48 file://0017-missing_type.h-add-__compar_d_fn_t-definition.patch \
49 file://0018-avoid-redefinition-of-prctl_mm_map-structure.patch \
50 file://0019-Handle-missing-LOCK_EX.patch \
51 file://0020-Fix-incompatible-pointer-type-struct-sockaddr_un.patch \
52 file://0021-test-json.c-define-M_PIl.patch \
53 file://0022-do-not-disable-buffer-in-writing-files.patch \
54 file://0025-Handle-__cpu_mask-usage.patch \
55 file://0026-Handle-missing-gshadow.patch \
56 file://0028-missing_syscall.h-Define-MIPS-ABI-defines-for-musl.patch \
57 "
58
59PAM_PLUGINS = " \
60 pam-plugin-unix \
61 pam-plugin-loginuid \
62 pam-plugin-keyinit \
63"
64
65PACKAGECONFIG ??= " \
66 ${@bb.utils.filter('DISTRO_FEATURES', 'acl audit efi ldconfig pam selinux smack usrmerge polkit seccomp', d)} \
67 ${@bb.utils.contains('DISTRO_FEATURES', 'wifi', 'rfkill', '', d)} \
68 ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'xkbcommon', '', d)} \
69 backlight \
70 binfmt \
71 gshadow \
72 hibernate \
73 hostnamed \
74 idn \
75 ima \
76 kmod \
77 localed \
78 logind \
79 machined \
80 myhostname \
81 networkd \
82 nss \
83 nss-mymachines \
84 nss-resolve \
85 quotacheck \
86 randomseed \
87 resolved \
88 set-time-epoch \
89 sysusers \
90 sysvinit \
91 timedated \
92 timesyncd \
93 userdb \
94 utmp \
95 vconsole \
96 wheel-group \
97 zstd \
98"
99
100PACKAGECONFIG:remove:libc-musl = " \
101 gshadow \
102 idn \
103 localed \
104 myhostname \
105 nss \
106 nss-mymachines \
107 nss-resolve \
108 sysusers \
109 userdb \
110 utmp \
111"
112
113# https://github.com/seccomp/libseccomp/issues/347
114PACKAGECONFIG:remove:mipsarch = "seccomp"
115
116CFLAGS:append:libc-musl = " -D__UAPI_DEF_ETHHDR=0 "
117
118# Some of the dependencies are weak-style recommends - if not available at runtime,
119# systemd won't fail but the library-related feature will be skipped with a warning.
120
121# Use the upstream systemd serial-getty@.service and rely on
122# systemd-getty-generator instead of using the OE-core specific
123# systemd-serialgetty.bb - not enabled by default.
124PACKAGECONFIG[serial-getty-generator] = ""
125
126PACKAGECONFIG[acl] = "-Dacl=true,-Dacl=false,acl"
127PACKAGECONFIG[audit] = "-Daudit=true,-Daudit=false,audit"
128PACKAGECONFIG[backlight] = "-Dbacklight=true,-Dbacklight=false"
129PACKAGECONFIG[binfmt] = "-Dbinfmt=true,-Dbinfmt=false"
130PACKAGECONFIG[bzip2] = "-Dbzip2=true,-Dbzip2=false,bzip2"
131PACKAGECONFIG[cgroupv2] = "-Ddefault-hierarchy=unified,-Ddefault-hierarchy=hybrid"
132PACKAGECONFIG[coredump] = "-Dcoredump=true,-Dcoredump=false"
133PACKAGECONFIG[cryptsetup] = "-Dlibcryptsetup=true,-Dlibcryptsetup=false,cryptsetup,,cryptsetup"
134PACKAGECONFIG[tpm2] = "-Dtpm2=true,-Dtpm2=false,tpm2-tss,tpm2-tss libtss2 libtss2-tcti-device"
135PACKAGECONFIG[dbus] = "-Ddbus=true,-Ddbus=false,dbus"
136PACKAGECONFIG[efi] = "-Defi=true,-Defi=false"
137PACKAGECONFIG[gnu-efi] = "-Dgnu-efi=true -Defi-libdir=${STAGING_LIBDIR} -Defi-includedir=${STAGING_INCDIR}/efi,-Dgnu-efi=false,gnu-efi"
138PACKAGECONFIG[elfutils] = "-Delfutils=true,-Delfutils=false,elfutils"
139PACKAGECONFIG[firstboot] = "-Dfirstboot=true,-Dfirstboot=false"
140PACKAGECONFIG[repart] = "-Drepart=true,-Drepart=false"
141PACKAGECONFIG[homed] = "-Dhomed=true,-Dhomed=false"
142# Sign the journal for anti-tampering
143PACKAGECONFIG[gcrypt] = "-Dgcrypt=true,-Dgcrypt=false,libgcrypt"
144PACKAGECONFIG[gnutls] = "-Dgnutls=true,-Dgnutls=false,gnutls"
145PACKAGECONFIG[gshadow] = "-Dgshadow=true,-Dgshadow=false"
146PACKAGECONFIG[hibernate] = "-Dhibernate=true,-Dhibernate=false"
147PACKAGECONFIG[hostnamed] = "-Dhostnamed=true,-Dhostnamed=false"
148PACKAGECONFIG[idn] = "-Didn=true,-Didn=false"
149PACKAGECONFIG[ima] = "-Dima=true,-Dima=false"
150# importd requires journal-upload/xz/zlib/bzip2/gcrypt
151PACKAGECONFIG[importd] = "-Dimportd=true,-Dimportd=false"
152# Update NAT firewall rules
153PACKAGECONFIG[iptc] = "-Dlibiptc=true,-Dlibiptc=false,iptables"
154PACKAGECONFIG[journal-upload] = "-Dlibcurl=true,-Dlibcurl=false,curl"
155PACKAGECONFIG[kmod] = "-Dkmod=true,-Dkmod=false,kmod"
156PACKAGECONFIG[ldconfig] = "-Dldconfig=true,-Dldconfig=false,,ldconfig"
157PACKAGECONFIG[libidn] = "-Dlibidn=true,-Dlibidn=false,libidn,,libidn"
158PACKAGECONFIG[libidn2] = "-Dlibidn2=true,-Dlibidn2=false,libidn2,,libidn2"
159PACKAGECONFIG[localed] = "-Dlocaled=true,-Dlocaled=false"
160PACKAGECONFIG[logind] = "-Dlogind=true,-Dlogind=false"
161PACKAGECONFIG[lz4] = "-Dlz4=true,-Dlz4=false,lz4"
162PACKAGECONFIG[machined] = "-Dmachined=true,-Dmachined=false"
163PACKAGECONFIG[manpages] = "-Dman=true,-Dman=false,libxslt-native xmlto-native docbook-xml-dtd4-native docbook-xsl-stylesheets-native"
164PACKAGECONFIG[microhttpd] = "-Dmicrohttpd=true,-Dmicrohttpd=false,libmicrohttpd"
165PACKAGECONFIG[myhostname] = "-Dnss-myhostname=true,-Dnss-myhostname=false,,libnss-myhostname"
166PACKAGECONFIG[networkd] = "-Dnetworkd=true,-Dnetworkd=false"
167PACKAGECONFIG[nss] = "-Dnss-systemd=true,-Dnss-systemd=false"
168PACKAGECONFIG[nss-mymachines] = "-Dnss-mymachines=true,-Dnss-mymachines=false"
169PACKAGECONFIG[nss-resolve] = "-Dnss-resolve=true,-Dnss-resolve=false"
170PACKAGECONFIG[oomd] = "-Doomd=true,-Doomd=false"
171PACKAGECONFIG[openssl] = "-Dopenssl=true,-Dopenssl=false,openssl"
172PACKAGECONFIG[pam] = "-Dpam=true,-Dpam=false,libpam,${PAM_PLUGINS}"
173PACKAGECONFIG[pcre2] = "-Dpcre2=true,-Dpcre2=false,libpcre2"
174PACKAGECONFIG[polkit] = "-Dpolkit=true,-Dpolkit=false"
175# If polkit is disabled and networkd+hostnamed are in use, enabling this option and
176# using dbus-broker will allow networkd to be authorized to change the
177# hostname without acquiring additional privileges
178PACKAGECONFIG[polkit_hostnamed_fallback] = ",,,,dbus-broker,polkit"
179PACKAGECONFIG[portabled] = "-Dportabled=true,-Dportabled=false"
180PACKAGECONFIG[qrencode] = "-Dqrencode=true,-Dqrencode=false,qrencode,,qrencode"
181PACKAGECONFIG[quotacheck] = "-Dquotacheck=true,-Dquotacheck=false"
182PACKAGECONFIG[randomseed] = "-Drandomseed=true,-Drandomseed=false"
183PACKAGECONFIG[resolved] = "-Dresolve=true,-Dresolve=false"
184PACKAGECONFIG[rfkill] = "-Drfkill=true,-Drfkill=false"
185PACKAGECONFIG[seccomp] = "-Dseccomp=true,-Dseccomp=false,libseccomp"
186PACKAGECONFIG[selinux] = "-Dselinux=true,-Dselinux=false,libselinux,initscripts-sushell"
187PACKAGECONFIG[smack] = "-Dsmack=true,-Dsmack=false"
188PACKAGECONFIG[sysusers] = "-Dsysusers=true,-Dsysusers=false"
189PACKAGECONFIG[sysvinit] = "-Dsysvinit-path=${sysconfdir}/init.d -Dsysvrcnd-path=${sysconfdir},-Dsysvinit-path= -Dsysvrcnd-path=,,systemd-compat-units update-rc.d"
190# When enabled use reproducble build timestamp if set as time epoch,
191# or build time if not. When disabled, time epoch is unset.
192def build_epoch(d):
193 epoch = d.getVar('SOURCE_DATE_EPOCH') or "-1"
194 return '-Dtime-epoch=%d' % int(epoch)
195PACKAGECONFIG[set-time-epoch] = "${@build_epoch(d)},-Dtime-epoch=0"
196PACKAGECONFIG[timedated] = "-Dtimedated=true,-Dtimedated=false"
197PACKAGECONFIG[timesyncd] = "-Dtimesyncd=true,-Dtimesyncd=false"
198PACKAGECONFIG[usrmerge] = "-Dsplit-usr=false,-Dsplit-usr=true"
199PACKAGECONFIG[sbinmerge] = "-Dsplit-bin=false,-Dsplit-bin=true"
200PACKAGECONFIG[userdb] = "-Duserdb=true,-Duserdb=false"
201PACKAGECONFIG[utmp] = "-Dutmp=true,-Dutmp=false"
202PACKAGECONFIG[valgrind] = "-DVALGRIND=1,,valgrind"
203PACKAGECONFIG[vconsole] = "-Dvconsole=true,-Dvconsole=false,,${PN}-vconsole-setup"
204PACKAGECONFIG[wheel-group] = "-Dwheel-group=true, -Dwheel-group=false"
205PACKAGECONFIG[xdg-autostart] = "-Dxdg-autostart=true,-Dxdg-autostart=false"
206# Verify keymaps on locale change
207PACKAGECONFIG[xkbcommon] = "-Dxkbcommon=true,-Dxkbcommon=false,libxkbcommon"
208PACKAGECONFIG[xz] = "-Dxz=true,-Dxz=false,xz"
209PACKAGECONFIG[zlib] = "-Dzlib=true,-Dzlib=false,zlib"
210PACKAGECONFIG[zstd] = "-Dzstd=true,-Dzstd=false,zstd"
211
212# Helper variables to clarify locations. This mirrors the logic in systemd's
213# build system.
214rootprefix ?= "${root_prefix}"
215rootlibdir ?= "${base_libdir}"
216rootlibexecdir = "${rootprefix}/lib"
217
218# This links udev statically with systemd helper library.
219# Otherwise udev package would depend on systemd package (which has the needed shared library),
220# and always pull it into images.
221EXTRA_OEMESON += "-Dlink-udev-shared=false"
222
223EXTRA_OEMESON += "-Dnobody-user=nobody \
224 -Dnobody-group=nobody \
225 -Drootlibdir=${rootlibdir} \
226 -Drootprefix=${rootprefix} \
227 -Ddefault-locale=C \
228 -Dmode=release \
229 -Dsystem-alloc-uid-min=101 \
230 -Dsystem-uid-max=999 \
231 -Dsystem-alloc-gid-min=101 \
232 -Dsystem-gid-max=999 \
233 "
234
235# Hardcode target binary paths to avoid using paths from sysroot
236EXTRA_OEMESON += "-Dkexec-path=${sbindir}/kexec \
237 -Dkmod-path=${base_bindir}/kmod \
238 -Dmount-path=${base_bindir}/mount \
239 -Dquotacheck-path=${sbindir}/quotacheck \
240 -Dquotaon-path=${sbindir}/quotaon \
241 -Dsulogin-path=${base_sbindir}/sulogin \
242 -Dnologin-path=${base_sbindir}/nologin \
243 -Dumount-path=${base_bindir}/umount"
244
245do_install() {
246 meson_do_install
247 install -d ${D}/${base_sbindir}
248 if ${@bb.utils.contains('PACKAGECONFIG', 'serial-getty-generator', 'false', 'true', d)}; then
249 # Provided by a separate recipe
250 rm ${D}${systemd_system_unitdir}/serial-getty* -f
251 fi
252
253 # Provide support for initramfs
254 [ ! -e ${D}/init ] && ln -s ${rootlibexecdir}/systemd/systemd ${D}/init
255 [ ! -e ${D}/${base_sbindir}/udevd ] && ln -s ${rootlibexecdir}/systemd/systemd-udevd ${D}/${base_sbindir}/udevd
256
257 install -d ${D}${sysconfdir}/udev/rules.d/
258 install -d ${D}${sysconfdir}/tmpfiles.d
259 for rule in $(find ${WORKDIR} -maxdepth 1 -type f -name "*.rules"); do
260 install -m 0644 $rule ${D}${sysconfdir}/udev/rules.d/
261 done
262
263 install -m 0644 ${WORKDIR}/00-create-volatile.conf ${D}${sysconfdir}/tmpfiles.d/
264
265 if ${@bb.utils.contains('DISTRO_FEATURES','sysvinit','true','false',d)}; then
266 install -d ${D}${sysconfdir}/init.d
267 install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/systemd-udevd
268 sed -i s%@UDEVD@%${rootlibexecdir}/systemd/systemd-udevd% ${D}${sysconfdir}/init.d/systemd-udevd
269 install -Dm 0755 ${S}/src/systemctl/systemd-sysv-install.SKELETON ${D}${systemd_unitdir}/systemd-sysv-install
270 fi
271
272 if "${@'true' if oe.types.boolean(d.getVar('VOLATILE_LOG_DIR')) else 'false'}"; then
273 # /var/log is typically a symbolic link to inside /var/volatile,
274 # which is expected to be empty.
275 rm -rf ${D}${localstatedir}/log
276 else
277 chown root:systemd-journal ${D}${localstatedir}/log/journal
278
279 # journal-remote creates this at start
280 rm -rf ${D}${localstatedir}/log/journal/remote
281 fi
282
283 install -d ${D}${systemd_system_unitdir}/graphical.target.wants
284 install -d ${D}${systemd_system_unitdir}/multi-user.target.wants
285 install -d ${D}${systemd_system_unitdir}/poweroff.target.wants
286 install -d ${D}${systemd_system_unitdir}/reboot.target.wants
287 install -d ${D}${systemd_system_unitdir}/rescue.target.wants
288
289 # Create symlinks for systemd-update-utmp-runlevel.service
290 if ${@bb.utils.contains('PACKAGECONFIG', 'utmp', 'true', 'false', d)}; then
291 ln -sf ../systemd-update-utmp-runlevel.service ${D}${systemd_system_unitdir}/graphical.target.wants/systemd-update-utmp-runlevel.service
292 ln -sf ../systemd-update-utmp-runlevel.service ${D}${systemd_system_unitdir}/multi-user.target.wants/systemd-update-utmp-runlevel.service
293 ln -sf ../systemd-update-utmp-runlevel.service ${D}${systemd_system_unitdir}/poweroff.target.wants/systemd-update-utmp-runlevel.service
294 ln -sf ../systemd-update-utmp-runlevel.service ${D}${systemd_system_unitdir}/reboot.target.wants/systemd-update-utmp-runlevel.service
295 ln -sf ../systemd-update-utmp-runlevel.service ${D}${systemd_system_unitdir}/rescue.target.wants/systemd-update-utmp-runlevel.service
296 fi
297
298 # this file is needed to exist if networkd is disabled but timesyncd is still in use since timesyncd checks it
299 # for existence else it fails
300 if [ -s ${D}${exec_prefix}/lib/tmpfiles.d/systemd.conf ]; then
301 ${@bb.utils.contains('PACKAGECONFIG', 'networkd', ':', 'sed -i -e "\$ad /run/systemd/netif/links 0755 root root -" ${D}${exec_prefix}/lib/tmpfiles.d/systemd.conf', d)}
302 fi
303 if ! ${@bb.utils.contains('PACKAGECONFIG', 'resolved', 'true', 'false', d)}; then
304 echo 'L! ${sysconfdir}/resolv.conf - - - - ../run/systemd/resolve/resolv.conf' >>${D}${exec_prefix}/lib/tmpfiles.d/etc.conf
305 echo 'd /run/systemd/resolve 0755 root root -' >>${D}${exec_prefix}/lib/tmpfiles.d/systemd.conf
306 echo 'f /run/systemd/resolve/resolv.conf 0644 root root' >>${D}${exec_prefix}/lib/tmpfiles.d/systemd.conf
307 ln -s ../run/systemd/resolve/resolv.conf ${D}${sysconfdir}/resolv-conf.systemd
308 else
309 sed -i -e "s%^L! /etc/resolv.conf.*$%L! /etc/resolv.conf - - - - ../run/systemd/resolve/resolv.conf%g" ${D}${exec_prefix}/lib/tmpfiles.d/etc.conf
310 ln -s ../run/systemd/resolve/resolv.conf ${D}${sysconfdir}/resolv-conf.systemd
311 fi
312 if ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'false', 'true', d)}; then
313 rm ${D}${exec_prefix}/lib/tmpfiles.d/x11.conf
314 rm -r ${D}${sysconfdir}/X11
315 fi
316
317 # If polkit is setup fixup permissions and ownership
318 if ${@bb.utils.contains('PACKAGECONFIG', 'polkit', 'true', 'false', d)}; then
319 if [ -d ${D}${datadir}/polkit-1/rules.d ]; then
320 chmod 700 ${D}${datadir}/polkit-1/rules.d
321 chown polkitd:root ${D}${datadir}/polkit-1/rules.d
322 fi
323 fi
324
325 # If polkit is not available and a fallback was requested, install a drop-in that allows networkd to
326 # request hostname changes via DBUS without elevating its privileges
327 if ${@bb.utils.contains('PACKAGECONFIG', 'polkit_hostnamed_fallback', 'true', 'false', d)}; then
328 install -d ${D}${systemd_system_unitdir}/systemd-hostnamed.service.d/
329 install -m 0644 ${WORKDIR}/00-hostnamed-network-user.conf ${D}${systemd_system_unitdir}/systemd-hostnamed.service.d/
330 install -d ${D}${datadir}/dbus-1/system.d/
331 install -m 0644 ${WORKDIR}/org.freedesktop.hostname1_no_polkit.conf ${D}${datadir}/dbus-1/system.d/
332 fi
333
334 # create link for existing udev rules
335 ln -s ${base_bindir}/udevadm ${D}${base_sbindir}/udevadm
336
337 # duplicate udevadm for postinst script
338 install -d ${D}${libexecdir}
339 ln ${D}${base_bindir}/udevadm ${D}${libexecdir}/${MLPREFIX}udevadm
340
341 # install default policy for presets
342 # https://www.freedesktop.org/wiki/Software/systemd/Preset/#howto
343 install -Dm 0644 ${WORKDIR}/99-default.preset ${D}${systemd_unitdir}/system-preset/99-default.preset
344
345 # add a profile fragment to disable systemd pager with busybox less
346 install -Dm 0644 ${WORKDIR}/systemd-pager.sh ${D}${sysconfdir}/profile.d/systemd-pager.sh
347}
348
349python populate_packages:prepend (){
350 systemdlibdir = d.getVar("rootlibdir")
351 do_split_packages(d, systemdlibdir, '^lib(.*)\.so\.*', 'lib%s', 'Systemd %s library', extra_depends='', allow_links=True)
352}
353PACKAGES_DYNAMIC += "^lib(udev|systemd|nss).*"
354
355PACKAGE_BEFORE_PN = "\
356 ${PN}-gui \
357 ${PN}-vconsole-setup \
358 ${PN}-initramfs \
359 ${PN}-analyze \
360 ${PN}-kernel-install \
361 ${PN}-rpm-macros \
362 ${PN}-binfmt \
363 ${PN}-zsh-completion \
364 ${PN}-container \
365 ${PN}-journal-gatewayd \
366 ${PN}-journal-upload \
367 ${PN}-journal-remote \
368 ${PN}-extra-utils \
369 ${PN}-udev-rules \
370 udev \
371 udev-hwdb \
372"
373
374SUMMARY:${PN}-container = "Tools for containers and VMs"
375DESCRIPTION:${PN}-container = "Systemd tools to spawn and manage containers and virtual machines."
376
377SUMMARY:${PN}-journal-gatewayd = "HTTP server for journal events"
378DESCRIPTION:${PN}-journal-gatewayd = "systemd-journal-gatewayd serves journal events over the network. Clients must connect using HTTP. The server listens on port 19531 by default."
379
380SUMMARY:${PN}-journal-upload = "Send journal messages over the network"
381DESCRIPTION:${PN}-journal-upload = "systemd-journal-upload uploads journal entries to a specified URL."
382
383SUMMARY:${PN}-journal-remote = "Receive journal messages over the network"
384DESCRIPTION:${PN}-journal-remote = "systemd-journal-remote is a command to receive serialized journal events and store them to journal files."
385
386SYSTEMD_PACKAGES = "${@bb.utils.contains('PACKAGECONFIG', 'binfmt', '${PN}-binfmt', '', d)} \
387 ${@bb.utils.contains('PACKAGECONFIG', 'microhttpd', '${PN}-journal-gatewayd', '', d)} \
388 ${@bb.utils.contains('PACKAGECONFIG', 'microhttpd', '${PN}-journal-remote', '', d)} \
389 ${@bb.utils.contains('PACKAGECONFIG', 'journal-upload', '${PN}-journal-upload', '', d)} \
390"
391SYSTEMD_SERVICE:${PN}-binfmt = "systemd-binfmt.service"
392
393USERADD_PACKAGES = "${PN} ${PN}-extra-utils \
394 ${@bb.utils.contains('PACKAGECONFIG', 'microhttpd', '${PN}-journal-gatewayd', '', d)} \
395 ${@bb.utils.contains('PACKAGECONFIG', 'microhttpd', '${PN}-journal-remote', '', d)} \
396 ${@bb.utils.contains('PACKAGECONFIG', 'journal-upload', '${PN}-journal-upload', '', d)} \
397"
398GROUPADD_PARAM:${PN} = "-r systemd-journal;"
399GROUPADD_PARAM:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'polkit_hostnamed_fallback', '-r systemd-hostname;', '', d)}"
400USERADD_PARAM:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'coredump', '--system -d / -M --shell /sbin/nologin systemd-coredump;', '', d)}"
401USERADD_PARAM:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'networkd', '--system -d / -M --shell /sbin/nologin systemd-network;', '', d)}"
402USERADD_PARAM:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'polkit', '--system --no-create-home --user-group --home-dir ${sysconfdir}/polkit-1 polkitd;', '', d)}"
403USERADD_PARAM:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'resolved', '--system -d / -M --shell /sbin/nologin systemd-resolve;', '', d)}"
404USERADD_PARAM:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'timesyncd', '--system -d / -M --shell /sbin/nologin systemd-timesync;', '', d)}"
405USERADD_PARAM:${PN}-extra-utils = "--system -d / -M --shell /sbin/nologin systemd-bus-proxy"
406USERADD_PARAM:${PN}-journal-gatewayd = "--system -d / -M --shell /sbin/nologin systemd-journal-gateway"
407USERADD_PARAM:${PN}-journal-remote = "--system -d / -M --shell /sbin/nologin systemd-journal-remote"
408USERADD_PARAM:${PN}-journal-upload = "--system -d / -M --shell /sbin/nologin systemd-journal-upload"
409
410FILES:${PN}-analyze = "${bindir}/systemd-analyze"
411
412FILES:${PN}-initramfs = "/init"
413RDEPENDS:${PN}-initramfs = "${PN}"
414
415FILES:${PN}-gui = "${bindir}/systemadm"
416
417FILES:${PN}-vconsole-setup = "${rootlibexecdir}/systemd/systemd-vconsole-setup \
418 ${systemd_system_unitdir}/systemd-vconsole-setup.service \
419 ${systemd_system_unitdir}/sysinit.target.wants/systemd-vconsole-setup.service"
420
421RDEPENDS:${PN}-kernel-install += "bash"
422FILES:${PN}-kernel-install = "${bindir}/kernel-install \
423 ${sysconfdir}/kernel/ \
424 ${exec_prefix}/lib/kernel \
425 "
426FILES:${PN}-rpm-macros = "${exec_prefix}/lib/rpm \
427 "
428
429FILES:${PN}-zsh-completion = "${datadir}/zsh/site-functions"
430
431FILES:${PN}-binfmt = "${sysconfdir}/binfmt.d/ \
432 ${exec_prefix}/lib/binfmt.d \
433 ${rootlibexecdir}/systemd/systemd-binfmt \
434 ${systemd_system_unitdir}/proc-sys-fs-binfmt_misc.* \
435 ${systemd_system_unitdir}/systemd-binfmt.service"
436RRECOMMENDS:${PN}-binfmt = "kernel-module-binfmt-misc"
437
438RRECOMMENDS:${PN}-vconsole-setup = "kbd kbd-consolefonts kbd-keymaps"
439
440
441FILES:${PN}-journal-gatewayd = "${rootlibexecdir}/systemd/systemd-journal-gatewayd \
442 ${systemd_system_unitdir}/systemd-journal-gatewayd.service \
443 ${systemd_system_unitdir}/systemd-journal-gatewayd.socket \
444 ${systemd_system_unitdir}/sockets.target.wants/systemd-journal-gatewayd.socket \
445 ${datadir}/systemd/gatewayd/browse.html \
446 "
447SYSTEMD_SERVICE:${PN}-journal-gatewayd = "systemd-journal-gatewayd.socket"
448
449FILES:${PN}-journal-upload = "${rootlibexecdir}/systemd/systemd-journal-upload \
450 ${systemd_system_unitdir}/systemd-journal-upload.service \
451 ${sysconfdir}/systemd/journal-upload.conf \
452 "
453SYSTEMD_SERVICE:${PN}-journal-upload = "systemd-journal-upload.service"
454
455FILES:${PN}-journal-remote = "${rootlibexecdir}/systemd/systemd-journal-remote \
456 ${sysconfdir}/systemd/journal-remote.conf \
457 ${systemd_system_unitdir}/systemd-journal-remote.service \
458 ${systemd_system_unitdir}/systemd-journal-remote.socket \
459 "
460SYSTEMD_SERVICE:${PN}-journal-remote = "systemd-journal-remote.socket"
461
462
463FILES:${PN}-container = "${sysconfdir}/dbus-1/system.d/org.freedesktop.import1.conf \
464 ${sysconfdir}/dbus-1/system.d/org.freedesktop.machine1.conf \
465 ${sysconfdir}/systemd/system/multi-user.target.wants/machines.target \
466 ${base_bindir}/machinectl \
467 ${bindir}/systemd-nspawn \
468 ${nonarch_libdir}/systemd/import-pubring.gpg \
469 ${systemd_system_unitdir}/busnames.target.wants/org.freedesktop.import1.busname \
470 ${systemd_system_unitdir}/busnames.target.wants/org.freedesktop.machine1.busname \
471 ${systemd_system_unitdir}/local-fs.target.wants/var-lib-machines.mount \
472 ${systemd_system_unitdir}/machines.target.wants/var-lib-machines.mount \
473 ${systemd_system_unitdir}/remote-fs.target.wants/var-lib-machines.mount \
474 ${systemd_system_unitdir}/machine.slice \
475 ${systemd_system_unitdir}/machines.target \
476 ${systemd_system_unitdir}/org.freedesktop.import1.busname \
477 ${systemd_system_unitdir}/org.freedesktop.machine1.busname \
478 ${systemd_system_unitdir}/systemd-importd.service \
479 ${systemd_system_unitdir}/systemd-machined.service \
480 ${systemd_system_unitdir}/dbus-org.freedesktop.machine1.service \
481 ${systemd_system_unitdir}/var-lib-machines.mount \
482 ${rootlibexecdir}/systemd/systemd-import \
483 ${rootlibexecdir}/systemd/systemd-importd \
484 ${rootlibexecdir}/systemd/systemd-machined \
485 ${rootlibexecdir}/systemd/systemd-pull \
486 ${exec_prefix}/lib/tmpfiles.d/systemd-nspawn.conf \
487 ${exec_prefix}/lib/tmpfiles.d/README \
488 ${systemd_system_unitdir}/systemd-nspawn@.service \
489 ${libdir}/libnss_mymachines.so.2 \
490 ${datadir}/dbus-1/system-services/org.freedesktop.import1.service \
491 ${datadir}/dbus-1/system-services/org.freedesktop.machine1.service \
492 ${datadir}/dbus-1/system.d/org.freedesktop.import1.conf \
493 ${datadir}/dbus-1/system.d/org.freedesktop.machine1.conf \
494 ${datadir}/polkit-1/actions/org.freedesktop.import1.policy \
495 ${datadir}/polkit-1/actions/org.freedesktop.machine1.policy \
496 "
497
498# "machinectl import-tar" uses "tar --numeric-owner", not supported by busybox.
499RRECOMMENDS:${PN}-container += "\
500 ${PN}-journal-gatewayd \
501 ${PN}-journal-remote \
502 ${PN}-journal-upload \
503 kernel-module-dm-mod \
504 kernel-module-loop \
505 kernel-module-tun \
506 tar \
507 "
508
509FILES:${PN}-extra-utils = "\
510 ${base_bindir}/systemd-escape \
511 ${base_bindir}/systemd-inhibit \
512 ${bindir}/systemd-detect-virt \
513 ${bindir}/systemd-dissect \
514 ${bindir}/systemd-path \
515 ${bindir}/systemd-run \
516 ${bindir}/systemd-cat \
517 ${bindir}/systemd-delta \
518 ${bindir}/systemd-cgls \
519 ${bindir}/systemd-cgtop \
520 ${bindir}/systemd-stdio-bridge \
521 ${bindir}/systemd-sysext \
522 ${base_bindir}/systemd-ask-password \
523 ${base_bindir}/systemd-tty-ask-password-agent \
524 ${systemd_system_unitdir}/systemd-ask-password-console.path \
525 ${systemd_system_unitdir}/systemd-ask-password-console.service \
526 ${systemd_system_unitdir}/systemd-ask-password-wall.path \
527 ${systemd_system_unitdir}/systemd-ask-password-wall.service \
528 ${systemd_system_unitdir}/sysinit.target.wants/systemd-ask-password-console.path \
529 ${systemd_system_unitdir}/sysinit.target.wants/systemd-ask-password-wall.path \
530 ${systemd_system_unitdir}/multi-user.target.wants/systemd-ask-password-wall.path \
531 ${rootlibexecdir}/systemd/systemd-resolve-host \
532 ${rootlibexecdir}/systemd/systemd-ac-power \
533 ${rootlibexecdir}/systemd/systemd-activate \
534 ${rootlibexecdir}/systemd/systemd-bus-proxyd \
535 ${systemd_system_unitdir}/systemd-bus-proxyd.service \
536 ${systemd_system_unitdir}/systemd-bus-proxyd.socket \
537 ${rootlibexecdir}/systemd/systemd-socket-proxyd \
538 ${rootlibexecdir}/systemd/systemd-reply-password \
539 ${rootlibexecdir}/systemd/systemd-sleep \
540 ${rootlibexecdir}/systemd/system-sleep \
541 ${systemd_system_unitdir}/systemd-hibernate.service \
542 ${systemd_system_unitdir}/systemd-hybrid-sleep.service \
543 ${systemd_system_unitdir}/systemd-suspend.service \
544 ${systemd_system_unitdir}/sleep.target \
545 ${rootlibexecdir}/systemd/systemd-initctl \
546 ${systemd_system_unitdir}/systemd-initctl.service \
547 ${systemd_system_unitdir}/systemd-initctl.socket \
548 ${systemd_system_unitdir}/sockets.target.wants/systemd-initctl.socket \
549 ${rootlibexecdir}/systemd/system-generators/systemd-gpt-auto-generator \
550 ${rootlibexecdir}/systemd/systemd-cgroups-agent \
551"
552
553FILES:${PN}-udev-rules = "\
554 ${rootlibexecdir}/udev/rules.d/70-uaccess.rules \
555 ${rootlibexecdir}/udev/rules.d/71-seat.rules \
556 ${rootlibexecdir}/udev/rules.d/73-seat-late.rules \
557 ${rootlibexecdir}/udev/rules.d/99-systemd.rules \
558"
559
560CONFFILES:${PN} = "${sysconfdir}/systemd/coredump.conf \
561 ${sysconfdir}/systemd/journald.conf \
562 ${sysconfdir}/systemd/logind.conf \
563 ${sysconfdir}/systemd/networkd.conf \
564 ${sysconfdir}/systemd/pstore.conf \
565 ${sysconfdir}/systemd/resolved.conf \
566 ${sysconfdir}/systemd/sleep.conf \
567 ${sysconfdir}/systemd/system.conf \
568 ${sysconfdir}/systemd/timesyncd.conf \
569 ${sysconfdir}/systemd/user.conf \
570"
571
572FILES:${PN} = " ${base_bindir}/* \
573 ${base_sbindir}/shutdown \
574 ${base_sbindir}/halt \
575 ${base_sbindir}/poweroff \
576 ${base_sbindir}/runlevel \
577 ${base_sbindir}/telinit \
578 ${base_sbindir}/resolvconf \
579 ${base_sbindir}/reboot \
580 ${base_sbindir}/init \
581 ${datadir}/dbus-1/services \
582 ${datadir}/dbus-1/system-services \
583 ${datadir}/polkit-1 \
584 ${datadir}/${BPN} \
585 ${datadir}/factory \
586 ${sysconfdir}/dbus-1/ \
587 ${sysconfdir}/modules-load.d/ \
588 ${sysconfdir}/pam.d/ \
589 ${sysconfdir}/profile.d/ \
590 ${sysconfdir}/sysctl.d/ \
591 ${sysconfdir}/systemd/ \
592 ${sysconfdir}/tmpfiles.d/ \
593 ${sysconfdir}/xdg/ \
594 ${sysconfdir}/init.d/README \
595 ${sysconfdir}/resolv-conf.systemd \
596 ${sysconfdir}/X11/xinit/xinitrc.d/* \
597 ${rootlibexecdir}/systemd/* \
598 ${libdir}/pam.d \
599 ${nonarch_libdir}/pam.d \
600 ${systemd_unitdir}/* \
601 ${base_libdir}/security/*.so \
602 /cgroup \
603 ${bindir}/systemd* \
604 ${bindir}/busctl \
605 ${bindir}/coredumpctl \
606 ${bindir}/localectl \
607 ${bindir}/hostnamectl \
608 ${bindir}/resolvectl \
609 ${bindir}/timedatectl \
610 ${bindir}/bootctl \
611 ${bindir}/oomctl \
612 ${exec_prefix}/lib/tmpfiles.d/*.conf \
613 ${exec_prefix}/lib/systemd \
614 ${exec_prefix}/lib/modules-load.d \
615 ${exec_prefix}/lib/sysctl.d \
616 ${exec_prefix}/lib/sysusers.d \
617 ${exec_prefix}/lib/environment.d \
618 ${localstatedir} \
619 ${rootlibexecdir}/modprobe.d/systemd.conf \
620 ${rootlibexecdir}/modprobe.d/README \
621 ${datadir}/dbus-1/system.d/org.freedesktop.timedate1.conf \
622 ${datadir}/dbus-1/system.d/org.freedesktop.locale1.conf \
623 ${datadir}/dbus-1/system.d/org.freedesktop.network1.conf \
624 ${datadir}/dbus-1/system.d/org.freedesktop.resolve1.conf \
625 ${datadir}/dbus-1/system.d/org.freedesktop.systemd1.conf \
626 ${@bb.utils.contains('PACKAGECONFIG', 'polkit_hostnamed_fallback', '${datadir}/dbus-1/system.d/org.freedesktop.hostname1_no_polkit.conf', '', d)} \
627 ${datadir}/dbus-1/system.d/org.freedesktop.hostname1.conf \
628 ${datadir}/dbus-1/system.d/org.freedesktop.login1.conf \
629 ${datadir}/dbus-1/system.d/org.freedesktop.timesync1.conf \
630 ${datadir}/dbus-1/system.d/org.freedesktop.portable1.conf \
631 ${datadir}/dbus-1/system.d/org.freedesktop.oom1.conf \
632 ${datadir}/dbus-1/system.d/org.freedesktop.home1.conf \
633 "
634
635FILES:${PN}-dev += "${base_libdir}/security/*.la ${datadir}/dbus-1/interfaces/ ${sysconfdir}/rpm/macros.systemd"
636
637RDEPENDS:${PN} += "kmod dbus util-linux-mount util-linux-umount udev (= ${EXTENDPKGV}) systemd-udev-rules util-linux-agetty util-linux-fsck"
638RDEPENDS:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'serial-getty-generator', '', 'systemd-serialgetty', d)}"
639RDEPENDS:${PN} += "volatile-binds"
640
641RRECOMMENDS:${PN} += "systemd-extra-utils \
642 udev-hwdb \
643 e2fsprogs-e2fsck \
644 kernel-module-autofs4 kernel-module-unix kernel-module-ipv6 kernel-module-sch-fq-codel \
645 os-release \
646 systemd-conf \
647"
648
649INSANE_SKIP:${PN} += "dev-so libdir"
650INSANE_SKIP:${PN}-dbg += "libdir"
651INSANE_SKIP:${PN}-doc += " libdir"
652
653RPROVIDES:udev = "hotplug"
654
655RDEPENDS:udev-hwdb += "udev"
656
657FILES:udev += "${base_sbindir}/udevd \
658 ${rootlibexecdir}/systemd/network/99-default.link \
659 ${rootlibexecdir}/systemd/systemd-udevd \
660 ${rootlibexecdir}/udev/accelerometer \
661 ${rootlibexecdir}/udev/ata_id \
662 ${rootlibexecdir}/udev/cdrom_id \
663 ${rootlibexecdir}/udev/collect \
664 ${rootlibexecdir}/udev/dmi_memory_id \
665 ${rootlibexecdir}/udev/fido_id \
666 ${rootlibexecdir}/udev/findkeyboards \
667 ${rootlibexecdir}/udev/keyboard-force-release.sh \
668 ${rootlibexecdir}/udev/keymap \
669 ${rootlibexecdir}/udev/mtd_probe \
670 ${rootlibexecdir}/udev/scsi_id \
671 ${rootlibexecdir}/udev/v4l_id \
672 ${rootlibexecdir}/udev/keymaps \
673 ${rootlibexecdir}/udev/rules.d/50-udev-default.rules \
674 ${rootlibexecdir}/udev/rules.d/60-autosuspend.rules \
675 ${rootlibexecdir}/udev/rules.d/60-autosuspend-chromiumos.rules \
676 ${rootlibexecdir}/udev/rules.d/60-block.rules \
677 ${rootlibexecdir}/udev/rules.d/60-cdrom_id.rules \
678 ${rootlibexecdir}/udev/rules.d/60-drm.rules \
679 ${rootlibexecdir}/udev/rules.d/60-evdev.rules \
680 ${rootlibexecdir}/udev/rules.d/60-fido-id.rules \
681 ${rootlibexecdir}/udev/rules.d/60-input-id.rules \
682 ${rootlibexecdir}/udev/rules.d/60-persistent-alsa.rules \
683 ${rootlibexecdir}/udev/rules.d/60-persistent-input.rules \
684 ${rootlibexecdir}/udev/rules.d/60-persistent-storage.rules \
685 ${rootlibexecdir}/udev/rules.d/60-persistent-storage-tape.rules \
686 ${rootlibexecdir}/udev/rules.d/60-persistent-v4l.rules \
687 ${rootlibexecdir}/udev/rules.d/60-sensor.rules \
688 ${rootlibexecdir}/udev/rules.d/60-serial.rules \
689 ${rootlibexecdir}/udev/rules.d/61-autosuspend-manual.rules \
690 ${rootlibexecdir}/udev/rules.d/64-btrfs.rules \
691 ${rootlibexecdir}/udev/rules.d/70-camera.rules \
692 ${rootlibexecdir}/udev/rules.d/70-joystick.rules \
693 ${rootlibexecdir}/udev/rules.d/70-memory.rules \
694 ${rootlibexecdir}/udev/rules.d/70-mouse.rules \
695 ${rootlibexecdir}/udev/rules.d/70-power-switch.rules \
696 ${rootlibexecdir}/udev/rules.d/70-touchpad.rules \
697 ${rootlibexecdir}/udev/rules.d/75-net-description.rules \
698 ${rootlibexecdir}/udev/rules.d/75-probe_mtd.rules \
699 ${rootlibexecdir}/udev/rules.d/78-sound-card.rules \
700 ${rootlibexecdir}/udev/rules.d/80-drivers.rules \
701 ${rootlibexecdir}/udev/rules.d/80-net-setup-link.rules \
702 ${rootlibexecdir}/udev/rules.d/81-net-dhcp.rules \
703 ${rootlibexecdir}/udev/rules.d/90-vconsole.rules \
704 ${rootlibexecdir}/udev/rules.d/README \
705 ${sysconfdir}/udev \
706 ${sysconfdir}/init.d/systemd-udevd \
707 ${systemd_system_unitdir}/*udev* \
708 ${systemd_system_unitdir}/*.wants/*udev* \
709 ${base_bindir}/systemd-hwdb \
710 ${base_bindir}/udevadm \
711 ${base_sbindir}/udevadm \
712 ${libexecdir}/${MLPREFIX}udevadm \
713 ${datadir}/bash-completion/completions/udevadm \
714 ${systemd_system_unitdir}/systemd-hwdb-update.service \
715 "
716
717FILES:udev-hwdb = "${rootlibexecdir}/udev/hwdb.d \
718 "
719
720RCONFLICTS:${PN} = "tiny-init ${@bb.utils.contains('PACKAGECONFIG', 'resolved', 'resolvconf', '', d)}"
721
722INITSCRIPT_PACKAGES = "udev"
723INITSCRIPT_NAME:udev = "systemd-udevd"
724INITSCRIPT_PARAMS:udev = "start 03 S ."
725
726python __anonymous() {
727 if not bb.utils.contains('DISTRO_FEATURES', 'sysvinit', True, False, d):
728 d.setVar("INHIBIT_UPDATERCD_BBCLASS", "1")
729
730 if bb.utils.contains('PACKAGECONFIG', 'repart', True, False, d) and not bb.utils.contains('PACKAGECONFIG', 'openssl', True, False, d):
731 bb.error("PACKAGECONFIG[repart] requires PACKAGECONFIG[openssl]")
732
733 if bb.utils.contains('PACKAGECONFIG', 'homed', True, False, d) and not bb.utils.contains('PACKAGECONFIG', 'userdb openssl cryptsetup', True, False, d):
734 bb.error("PACKAGECONFIG[homed] requires PACKAGECONFIG[userdb], PACKAGECONFIG[openssl] and PACKAGECONFIG[cryptsetup]")
735}
736
737python do_warn_musl() {
738 if d.getVar('TCLIBC') == "musl":
739 bb.warn("Using systemd with musl is not recommended since it is not supported upstream and some patches are known to be problematic.")
740}
741addtask warn_musl before do_configure
742
743ALTERNATIVE:${PN} = "halt reboot shutdown poweroff runlevel ${@bb.utils.contains('PACKAGECONFIG', 'resolved', 'resolv-conf', '', d)}"
744
745ALTERNATIVE_TARGET[resolv-conf] = "${sysconfdir}/resolv-conf.systemd"
746ALTERNATIVE_LINK_NAME[resolv-conf] = "${sysconfdir}/resolv.conf"
747ALTERNATIVE_PRIORITY[resolv-conf] ?= "50"
748
749ALTERNATIVE_TARGET[halt] = "${base_bindir}/systemctl"
750ALTERNATIVE_LINK_NAME[halt] = "${base_sbindir}/halt"
751ALTERNATIVE_PRIORITY[halt] ?= "300"
752
753ALTERNATIVE_TARGET[reboot] = "${base_bindir}/systemctl"
754ALTERNATIVE_LINK_NAME[reboot] = "${base_sbindir}/reboot"
755ALTERNATIVE_PRIORITY[reboot] ?= "300"
756
757ALTERNATIVE_TARGET[shutdown] = "${base_bindir}/systemctl"
758ALTERNATIVE_LINK_NAME[shutdown] = "${base_sbindir}/shutdown"
759ALTERNATIVE_PRIORITY[shutdown] ?= "300"
760
761ALTERNATIVE_TARGET[poweroff] = "${base_bindir}/systemctl"
762ALTERNATIVE_LINK_NAME[poweroff] = "${base_sbindir}/poweroff"
763ALTERNATIVE_PRIORITY[poweroff] ?= "300"
764
765ALTERNATIVE_TARGET[runlevel] = "${base_bindir}/systemctl"
766ALTERNATIVE_LINK_NAME[runlevel] = "${base_sbindir}/runlevel"
767ALTERNATIVE_PRIORITY[runlevel] ?= "300"
768
769pkg_postinst:${PN}:libc-glibc () {
770 sed -e '/^hosts:/s/\s*\<myhostname\>//' \
771 -e 's/\(^hosts:.*\)\(\<files\>\)\(.*\)\(\<dns\>\)\(.*\)/\1\2 myhostname \3\4\5/' \
772 -i $D${sysconfdir}/nsswitch.conf
773}
774
775pkg_prerm:${PN}:libc-glibc () {
776 sed -e '/^hosts:/s/\s*\<myhostname\>//' \
777 -e '/^hosts:/s/\s*myhostname//' \
778 -i $D${sysconfdir}/nsswitch.conf
779}
780
781PACKAGE_WRITE_DEPS += "qemu-native"
782pkg_postinst:udev-hwdb () {
783 if test -n "$D"; then
784 $INTERCEPT_DIR/postinst_intercept update_udev_hwdb ${PKG} mlprefix=${MLPREFIX} binprefix=${MLPREFIX} rootlibexecdir="${rootlibexecdir}" PREFERRED_PROVIDER_udev="${PREFERRED_PROVIDER_udev}"
785 else
786 udevadm hwdb --update
787 fi
788}
789
790pkg_prerm:udev-hwdb () {
791 rm -f $D${sysconfdir}/udev/hwdb.bin
792}
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2026-02-12 08:41:02 +0000