1 files changed, 32 insertions, 0 deletions

diff --git a/meta/classes/module.bbclass b/meta/classes/module.bbclass
new file mode 100644
index 0000000000..ad6f7af1bb
--- /dev/null
+++ b/meta/classes/module.bbclass
@@ -0,0 +1,32 @@
+DEPENDS += "virtual/kernel"
+
+inherit module-base kernel-module-split
+
+addtask make_scripts after do_patch before do_compile
+do_make_scripts[lockfiles] = "${TMPDIR}/kernel-scripts.lock"
+do_make_scripts[deptask] = "do_populate_sysroot"
+
+module_do_compile() {
+        unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
+        oe_runmake KERNEL_PATH=${STAGING_KERNEL_DIR}   \
+                   KERNEL_SRC=${STAGING_KERNEL_DIR}    \
+                   KERNEL_VERSION=${KERNEL_VERSION}    \
+                   CC="${KERNEL_CC}" LD="${KERNEL_LD}" \
+                   AR="${KERNEL_AR}" \
+                   ${MAKE_TARGETS}
+}
+
+module_do_install() {
+        unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
+        oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" \
+                   KERNEL_SRC=${STAGING_KERNEL_DIR} \
+                   CC="${KERNEL_CC}" LD="${KERNEL_LD}" \
+                   modules_install
+}
+
+EXPORT_FUNCTIONS do_compile do_install
+
+# add all splitted modules to PN RDEPENDS, PN can be empty now
+KERNEL_MODULES_META_PACKAGE = "${PN}"
+FILES_${PN} = ""
+ALLOW_EMPTY_${PN} = "1"