summaryrefslogtreecommitdiffstats
diff options
context:
space:
mode:
Diffstat
-rw-r--r--meta/recipes-kernel/linux/linux-yocto-rt_5.19.bb45
-rw-r--r--meta/recipes-kernel/linux/linux-yocto-tiny_5.19.bb30
-rw-r--r--meta/recipes-kernel/linux/linux-yocto_5.19.bb70
3 files changed, 145 insertions, 0 deletions
diff --git a/meta/recipes-kernel/linux/linux-yocto-rt_5.19.bb b/meta/recipes-kernel/linux/linux-yocto-rt_5.19.bb
new file mode 100644
index 0000000000..54982bc200
--- /dev/null
+++ b/meta/recipes-kernel/linux/linux-yocto-rt_5.19.bb
@@ -0,0 +1,45 @@
1KBRANCH ?= "v5.19/standard/preempt-rt/base"
2
3require recipes-kernel/linux/linux-yocto.inc
4
5# Skip processing of this recipe if it is not explicitly specified as the
6# PREFERRED_PROVIDER for virtual/kernel. This avoids errors when trying
7# to build multiple virtual/kernel providers, e.g. as dependency of
8# core-image-rt-sdk, core-image-rt.
9python () {
10 if d.getVar("KERNEL_PACKAGE_NAME") == "kernel" and d.getVar("PREFERRED_PROVIDER_virtual/kernel") != "linux-yocto-rt":
11 raise bb.parse.SkipRecipe("Set PREFERRED_PROVIDER_virtual/kernel to linux-yocto-rt to enable it")
12}
13
14SRCREV_machine ?= "e41cf2ea686c923a56b8fbc52ea998dc7193f099"
15SRCREV_meta ?= "eb7088accaa0347a5b627952e48bb8800ff15cf3"
16
17SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;branch=${KBRANCH};name=machine \
18 git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.19;destsuffix=${KMETA}"
19
20LINUX_VERSION ?= "5.19"
21
22LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
23
24DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
25DEPENDS += "openssl-native util-linux-native"
26
27PV = "${LINUX_VERSION}+git${SRCPV}"
28
29KMETA = "kernel-meta"
30KCONF_BSP_AUDIT_LEVEL = "1"
31
32LINUX_KERNEL_TYPE = "preempt-rt"
33
34COMPATIBLE_MACHINE = "(qemux86|qemux86-64|qemuarm|qemuarmv5|qemuarm64|qemuppc|qemumips)"
35
36KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
37
38# Functionality flags
39KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
40KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
41KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
42KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
43KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
44KERNEL_FEATURES:append = "${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
45KERNEL_FEATURES:append = "${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}"
diff --git a/meta/recipes-kernel/linux/linux-yocto-tiny_5.19.bb b/meta/recipes-kernel/linux/linux-yocto-tiny_5.19.bb
new file mode 100644
index 0000000000..716e5aa652
--- /dev/null
+++ b/meta/recipes-kernel/linux/linux-yocto-tiny_5.19.bb
@@ -0,0 +1,30 @@
1KBRANCH ?= "v5.19/standard/tiny/base"
2
3LINUX_KERNEL_TYPE = "tiny"
4KCONFIG_MODE = "--allnoconfig"
5
6require recipes-kernel/linux/linux-yocto.inc
7
8LINUX_VERSION ?= "5.19"
9LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
10
11DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
12DEPENDS += "openssl-native util-linux-native"
13
14KMETA = "kernel-meta"
15KCONF_BSP_AUDIT_LEVEL = "2"
16
17SRCREV_machine ?= "43e6ab6ed043f4bc8e7cffbb08af86af0bdb5e12"
18SRCREV_meta ?= "eb7088accaa0347a5b627952e48bb8800ff15cf3"
19
20PV = "${LINUX_VERSION}+git${SRCPV}"
21
22SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;branch=${KBRANCH};name=machine \
23 git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.19;destsuffix=${KMETA}"
24
25COMPATIBLE_MACHINE = "qemux86|qemux86-64|qemuarm64|qemuarm|qemuarmv5"
26
27# Functionality flags
28KERNEL_FEATURES = ""
29
30KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
diff --git a/meta/recipes-kernel/linux/linux-yocto_5.19.bb b/meta/recipes-kernel/linux/linux-yocto_5.19.bb
new file mode 100644
index 0000000000..a1a2e72774
--- /dev/null
+++ b/meta/recipes-kernel/linux/linux-yocto_5.19.bb
@@ -0,0 +1,70 @@
1KBRANCH ?= "v5.19/standard/base"
2
3require recipes-kernel/linux/linux-yocto.inc
4
5# board specific branches
6KBRANCH:qemuarm ?= "v5.19/standard/arm-versatile-926ejs"
7KBRANCH:qemuarm64 ?= "v5.19/standard/qemuarm64"
8KBRANCH:qemumips ?= "v5.19/standard/mti-malta32"
9KBRANCH:qemuppc ?= "v5.19/standard/qemuppc"
10KBRANCH:qemuriscv64 ?= "v5.19/standard/base"
11KBRANCH:qemuriscv32 ?= "v5.19/standard/base"
12KBRANCH:qemux86 ?= "v5.19/standard/base"
13KBRANCH:qemux86-64 ?= "v5.19/standard/base"
14KBRANCH:qemumips64 ?= "v5.19/standard/mti-malta64"
15
16SRCREV_machine:qemuarm ?= "fdb9f8c3f9a6762603e4d71e3f678dfae1afced6"
17SRCREV_machine:qemuarm64 ?= "43e6ab6ed043f4bc8e7cffbb08af86af0bdb5e12"
18SRCREV_machine:qemumips ?= "128ff884612b479168e68519bb69d1c7a5180b7d"
19SRCREV_machine:qemuppc ?= "43e6ab6ed043f4bc8e7cffbb08af86af0bdb5e12"
20SRCREV_machine:qemuriscv64 ?= "43e6ab6ed043f4bc8e7cffbb08af86af0bdb5e12"
21SRCREV_machine:qemuriscv32 ?= "43e6ab6ed043f4bc8e7cffbb08af86af0bdb5e12"
22SRCREV_machine:qemux86 ?= "43e6ab6ed043f4bc8e7cffbb08af86af0bdb5e12"
23SRCREV_machine:qemux86-64 ?= "43e6ab6ed043f4bc8e7cffbb08af86af0bdb5e12"
24SRCREV_machine:qemumips64 ?= "a078f75cccc88d26763cab4762ed00418813f2cd"
25SRCREV_machine ?= "43e6ab6ed043f4bc8e7cffbb08af86af0bdb5e12"
26SRCREV_meta ?= "eb7088accaa0347a5b627952e48bb8800ff15cf3"
27
28# set your preferred provider of linux-yocto to 'linux-yocto-upstream', and you'll
29# get the <version>/base branch, which is pure upstream -stable, and the same
30# meta SRCREV as the linux-yocto-standard builds. Select your version using the
31# normal PREFERRED_VERSION settings.
32BBCLASSEXTEND = "devupstream:target"
33SRCREV_machine:class-devupstream ?= "3d7cb6b04c3f3115719235cc6866b10326de34cd"
34PN:class-devupstream = "linux-yocto-upstream"
35KBRANCH:class-devupstream = "v5.19/base"
36
37SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH}; \
38 git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.19;destsuffix=${KMETA}"
39
40LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
41LINUX_VERSION ?= "5.19"
42
43DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
44DEPENDS += "openssl-native util-linux-native"
45DEPENDS += "gmp-native libmpc-native"
46
47PV = "${LINUX_VERSION}+git${SRCPV}"
48
49KMETA = "kernel-meta"
50KCONF_BSP_AUDIT_LEVEL = "1"
51
52KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
53
54COMPATIBLE_MACHINE = "qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32"
55
56# Functionality flags
57KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
58KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
59KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
60KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
61KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
62KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
63KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
64KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}"
65KERNEL_FEATURES:append:powerpc =" arch/powerpc/powerpc-debug.scc"
66KERNEL_FEATURES:append:powerpc64 =" arch/powerpc/powerpc-debug.scc"
67KERNEL_FEATURES:append:powerpc64le =" arch/powerpc/powerpc-debug.scc"
68
69INSANE_SKIP:kernel-vmlinux:qemuppc64 = "textrel"
70
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2026-02-13 13:43:27 +0000