igt-gpu-tools: upgrade 1.29 -> 1.30

Changelog:
===========
General changes:
- New meson options xe_eudebug and vmtb.

Library changes:
- Added PantherLake (PTL) support, unified PCI IDs into one
  common header pciids.h
- Added BMG support for OA (Observability Architecture) for Xe driver.
- Added support for Xe3 platforms in GPGPU shader.
- Added 6k resolution support for a single CRTC.
- Added support for MTL platform in GPGPU compute.

Runner changes:
- Set option PRUNE_KEEP_ALL as default.
- Allow to dynamically ignore dmesg warn messages when generating
  results, usefull when driver is using kernel fault injection.

Test changes:
- Added sanity checks for KMS properties.
- Improved GPGPU tests for i915 and Xe.
- New SRIOV test for Functional Level Reset (FLR) for Xe.
- Added test that draws triangle without using 3d commands for vmwgfx.
- Added subtest for fallback for DP connector.
- Added async flips suspend resume subtest.
- New test for error handling of Xe at probe time.
- Added testing SIZE_HINTS property in KMS cursor test.
- Added KMS testing for ultrajoiner.
- New test for TLB invalidation in Xe.
- New test for timeslice duration in Xe.
- Display brightness test during DPMS on and off.
- New tests for EU debugging for Xe.

Tools changes:
- New power tool for power/energy measurement.
- New VM Testbench (VMTB) - SR-IOV Virtual Machine testing tool.
- Fixes in amd_hdmi_compliance.
- Fixes in intel_reg.

(From OE-Core rev: dbec508d17f7ab18efe757cbfc30b81ad5bca7b0)

Signed-off-by: Wang Mingyu <wangmy@cn.fujitsu.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/meta/recipes-graphics/igt-gpu-tools/igt-gpu-tools_1.30.bb b/meta/recipes-graphics/igt-gpu-tools/igt-gpu-tools_1.30.bb
new file mode 100644
index 0000000000..a302e1877f
--- /dev/null
+++ b/meta/recipes-graphics/igt-gpu-tools/igt-gpu-tools_1.30.bb
@@ -0,0 +1,50 @@
+SUMMARY = "IGT GPU Tools"
+DESCRIPTION = "IGT GPU Tools is a collection of tools for development and testing of the DRM drivers"
+HOMEPAGE = "https://gitlab.freedesktop.org/drm/igt-gpu-tools"
+BUGTRACKER = "https://gitlab.freedesktop.org/drm/igt-gpu-tools/-/issues"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=67bfee4df38fa6ecbe3a675c552d4c08"
+
+LICENSE = "MIT"
+
+inherit meson pkgconfig
+
+SRCREV = "edf352a96646c8d793f0c1eb11795112f9bde725"
+
+SRC_URI = "git://gitlab.freedesktop.org/drm/igt-gpu-tools.git;protocol=https;branch=master"
+
+S = "${WORKDIR}/git"
+
+DEPENDS += "libdrm libpciaccess cairo udev glib-2.0 procps libunwind kmod openssl elfutils alsa-lib json-c bison-native"
+RDEPENDS:${PN} += "bash perl"
+RDEPENDS:${PN}-tests += "bash"
+
+PACKAGE_BEFORE_PN = "${PN}-benchmarks ${PN}-tests"
+
+PACKAGECONFIG[chamelium] = "-Dchamelium=enabled,-Dchamelium=disabled,gsl xmlrpc-c"
+
+EXTRA_OEMESON = "-Ddocs=disabled -Drunner=enabled -Dsrcdir=${TARGET_DBGSRC_DIR}/git/ -Dversion_hash=${PV}"
+COMPATIBLE_HOST = "(x86_64.*|i.86.*|arm.*|aarch64).*-linux"
+COMPATIBLE_HOST:libc-musl:class-target = "null"
+SECURITY_LDFLAGS = "${SECURITY_X_LDFLAGS}"
+
+gputools_sysroot_preprocess() {
+        rm -f ${SYSROOT_DESTDIR}${libdir}/pkgconfig/intel-gen4asm.pc
+}
+SYSROOT_PREPROCESS_FUNCS += "gputools_sysroot_preprocess"
+
+do_install:append() {
+    install -d ${D}/usr/share/${BPN}/scripts
+    install ${S}/scripts/run-tests.sh ${D}/usr/share/${BPN}/scripts
+    install -d ${D}/usr/share/${BPN}/runner
+    install -D ${B}/runner/igt_runner ${D}/usr/share/${BPN}/runner
+    install -D ${B}/runner/igt_resume ${D}/usr/share/${BPN}/runner
+}
+
+FILES:${PN}-benchmarks += "${libexecdir}/${BPN}/benchmarks"
+FILES:${PN}-tests += "\
+        ${libexecdir}/${BPN}/*\
+        ${datadir}/${BPN}/1080p-right.png\
+        ${datadir}/${BPN}/1080p-left.png\
+        ${datadir}/${BPN}/pass.png\
+        ${datadir}/${BPN}/test-list.txt"