gcr: upgrade 4.3.1 -> 4.4.0.1

Due to a version number that has 4 sections, the recipe needs to override
gnome_gverdir function from gnomebase.bbclass to construct a valid download url.

Changelog:
gcr 4.4.0.1:
- meson: Fix gck vesion

gcr 4.4.0:
- gcr: Add OID for Extended Key Usage
- gcr: Avoid g_strv_builder_unref_to_strv()
- gck: Disable parallel tests using gck-mock module
- meson: Do a stricter check on GLib version
- gcr: Support parsing ed25519 SSH public keys
- Updated translations

gcr 4.3.90.3:
- ci: Another tarball publish fix

gcr 4.3.90.2:
- meson: fix library version

gcr 4.3.90.1:
- ci: Tarball publish fix

gcr 4.3.90:
- gcr: Add new GcrCertificateExtension API
- gcr: Vala override for CertificateField.get_value
- Fix meson test failures in FIPS mode
- doap: Remove invalid maintainer entry
- tests: Replace echo -n by printf
- build: Avoid redundant libegg linking into gck tests
- build: Fix some GLib/GTK deprecation warnings
- ssh-agent: Request rsa-sha2-256 signature in tests
- Updated translations

gcr 4.3.91:
- Several updates to the CI
- gcr: Implement Certificate Policies extension
- gcr: Implement Authority Information Access (AIA) extension
- gcr: Implement Authority Key Identifier extension
- gcr: Implement CRL Distribution Points extension
- gcr: Add GcrGeneralNames helper object
- gck: Add missing finish-func annotation to gck_slot_open_session_full_async
- Migrate away from g_assert() in some unit tests
- Updated translations

(From OE-Core rev: 32e9d178c114bd315cbbd5f00c00ec064ead5102)

Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com>
Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 66 insertions, 0 deletions

diff --git a/meta/recipes-gnome/gcr/gcr_4.4.0.1.bb b/meta/recipes-gnome/gcr/gcr_4.4.0.1.bb
new file mode 100644
index 0000000000..25c394c9d0
--- /dev/null
+++ b/meta/recipes-gnome/gcr/gcr_4.4.0.1.bb
@@ -0,0 +1,66 @@
+SUMMARY = "A library for bits of crypto UI and parsing etc"
+DESCRIPTION = "GCR is a library for displaying certificates, and crypto UI, \
+accessing key stores. It also provides the viewer for crypto files on the \
+GNOME desktop."
+HOMEPAGE = "https://gitlab.gnome.org/GNOME/gcr"
+BUGTRACKER = "https://gitlab.gnome.org/GNOME/gcr/issues"
+
+LICENSE = "LGPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=55ca817ccb7d5b5b66355690e9abc605"
+
+DEPENDS = "p11-kit glib-2.0 libgcrypt gnupg-native \
+           ${@bb.utils.contains('GI_DATA_ENABLED', 'True', 'libxslt-native', '', d)}"
+
+CFLAGS += "-D_GNU_SOURCE"
+
+GTKDOC_MESON_OPTION = "gtk_doc"
+inherit gnomebase gtk-icon-cache gi-docgen features_check vala gobject-introspection gettext mime mime-xdg
+UPSTREAM_CHECK_REGEX = "gcr-(?P<pver>\d+\.\d+\.(?!9\d+)\d+)"
+
+REQUIRED_DISTRO_FEATURES = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'opengl', '', d)}"
+
+SRC_URI[archive.sha256sum] = "0c3c341e49f9f4f2532a4884509804190a0c2663e6120360bb298c5d174a8098"
+
+PACKAGECONFIG ??= " \
+        ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
+        ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'gtk', '', d)} \
+        ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'gtk', '', d)} \
+        ${@bb.utils.contains('GI_DATA_ENABLED', 'True', 'vapi', '', d)} \
+"
+PACKAGECONFIG[gtk] = "-Dgtk4=true,-Dgtk4=false,gtk4"
+PACKAGECONFIG[ssh_agent] = "-Dssh_agent=true,-Dssh_agent=false,libsecret,openssh"
+#'Use systemd socket activation for server programs'
+PACKAGECONFIG[systemd] = "-Dsystemd=enabled,-Dsystemd=disabled,systemd"
+PACKAGECONFIG[vapi] = "-Dvapi=true,-Dvapi=false,"
+
+FILES:${PN} += " \
+    ${datadir}/dbus-1 \
+    ${datadir}/gcr-4 \
+    ${systemd_user_unitdir}/gcr-ssh-agent.socket \
+    ${systemd_user_unitdir}/gcr-ssh-agent.service \
+"
+
+# http://errors.yoctoproject.org/Errors/Details/20229/
+ARM_INSTRUCTION_SET:armv4 = "arm"
+ARM_INSTRUCTION_SET:armv5 = "arm"
+ARM_INSTRUCTION_SET:armv6 = "arm"
+
+EXTRA_OEMESON += "--cross-file=${WORKDIR}/meson-${PN}.cross"
+
+do_write_config:append() {
+    cat >${WORKDIR}/meson-${PN}.cross <<EOF
+[binaries]
+gpg = '${bindir}/gpg'
+ssh-add = '${bindir}/ssh-add'
+ssh-agent = '${bindir}/ssh-agent'
+EOF
+}
+
+# gnome_verdir is coming from gnomebase.bbclass, which seems to work
+# with gcr as long as its version has 3 sections (x.y.z).
+# This version is 4.4.0.1 - add a custom version parser, otherwise the
+# original parser constructs invalid download URL.
+# It can be removed with the next update, when/if the version has only
+# 3 sections again.
+def gnome_verdir(v):
+    return ".".join(v.split(".")[:2]) or v