syslinux.bbclass, syslinux: Update to syslinux 6.01

A newer version of syslinux is required for an EFI enabled isohybrid.
This is used for the the capability to generate 3 types of ISO images,
all of which can be booted off a USB device or HDD if copied with dd.

1) PC BIOS only ISO
2) EFI only ISO
3) EFI + PC BIOS ISO

The syslinux.bbclass required a minor tweak because a few .c32
libraries require dynamic loading from the created media as of
syslinux 5 and up.  This was a good time to also fix the
duplication of the AUTO_SYSLINUXMENU block.

[YOCTO #4100]

(From OE-Core rev: 17d74fbd09e377e100423e1a73b9d4ce761a21d7)

Signed-off-by: Jason Wessel <jason.wessel@windriver.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 68 insertions, 0 deletions

diff --git a/meta/recipes-devtools/syslinux/syslinux_6.01.bb b/meta/recipes-devtools/syslinux/syslinux_6.01.bb
new file mode 100644
index 0000000000..4438ea8330
--- /dev/null
+++ b/meta/recipes-devtools/syslinux/syslinux_6.01.bb
@@ -0,0 +1,68 @@
+DESCRIPTION = "A multi-purpose linux bootloader"
+HOMEPAGE = "http://syslinux.zytor.com/"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
+                    file://README;beginline=35;endline=41;md5=558f2c71cb1fb9ba511ccd4858e48e8a"
+
+# If you really want to run syslinux, you need mtools.  We just want the
+# ldlinux.* stuff for now, so skip mtools-native
+DEPENDS = "nasm-native util-linux"
+
+SRC_URI = "${KERNELORG_MIRROR}/linux/utils/boot/syslinux/6.xx/syslinux-${PV}.tar.bz2"
+
+SRC_URI[md5sum] = "6945ee89e29119d459baed4937bbc534"
+SRC_URI[sha256sum] = "83a04cf81e6a46b80ee5a321926eea095af3498b04317e3674b46c125c7a5b43"
+
+COMPATIBLE_HOST = '(x86_64|i.86).*-(linux|freebsd.*)'
+# Don't let the sanity checker trip on the 32 bit real mode BIOS binaries
+INSANE_SKIP_${PN}-misc = "arch"
+INSANE_SKIP_${PN}-chain = "arch"
+
+EXTRA_OEMAKE = " \
+        BINDIR=${bindir} SBINDIR=${sbindir} LIBDIR=${libdir} \
+        DATADIR=${datadir} MANDIR=${mandir} INCDIR=${includedir} \
+"
+# syslinux uses $LD for linking, strip `-Wl,' so it can work
+export LDFLAGS = "`echo $LDFLAGS | sed 's/-Wl,//g'`"
+
+do_configure() {
+        # drop win32 targets or build fails
+        sed -e 's,win32/\S*,,g' -i Makefile
+
+        # clean installer executables included in source tarball
+        oe_runmake clean firmware="efi32" EFIINC="${includedir}"
+        # NOTE: There is a temporary work around above to specify
+        #       the efi32 as the firmware else the pre-built bios
+        #       files get erased contrary to the doc/distib.txt
+        #       In the future this should be "bios" and not "efi32".
+}
+
+do_compile() {
+        # Rebuild only the installer; keep precompiled bootloaders
+        # as per author's request (doc/distrib.txt)
+        oe_runmake CC="${CC} ${CFLAGS}" LDFLAGS="${LDFLAGS}" firmware="bios" installer
+}
+
+do_install() {
+        oe_runmake install INSTALLROOT="${D}" firmware="bios"
+
+        install -d ${D}${datadir}/syslinux/
+        install -m 644 ${S}/bios/core/ldlinux.sys ${D}${datadir}/syslinux/
+        install -m 644 ${S}/bios/core/ldlinux.bss ${D}${datadir}/syslinux/
+}
+
+PACKAGES += "${PN}-extlinux ${PN}-mbr ${PN}-chain ${PN}-pxelinux ${PN}-isolinux ${PN}-misc"
+
+RDEPENDS_${PN} += "mtools"
+
+FILES_${PN} = "${bindir}/syslinux"
+FILES_${PN}-extlinux = "${sbindir}/extlinux"
+FILES_${PN}-mbr = "${datadir}/${BPN}/mbr.bin"
+FILES_${PN}-chain = "${datadir}/${BPN}/chain.c32"
+FILES_${PN}-isolinux = "${datadir}/${BPN}/isolinux.bin"
+FILES_${PN}-pxelinux = "${datadir}/${BPN}/pxelinux.0"
+FILES_${PN}-dev += "${datadir}/${BPN}/com32/lib*${SOLIBS} ${datadir}/${BPN}/com32/include ${datadir}/${BPN}/com32/com32.ld"
+FILES_${PN}-staticdev += "${datadir}/${BPN}/com32/lib*.a ${libdir}/${BPN}/com32/lib*.a"
+FILES_${PN}-misc = "${datadir}/${BPN}/* ${libdir}/${BPN}/* ${bindir}/*"
+
+BBCLASSEXTEND = "native"