python3-pygobject: Upgrade 3.52.3 -> 3.54.5

Changes in the upstream COPYING file were only replacements of \f by \n

3.54.5 - 2025-10-18
-------------------
* Backport: GLib 2.86/GioUnix compatibility :mr:`461`

3.54.3 - 2025-09-21
-------------------
* Do not skip symbols both in Gio and in platform specific :mr:`452`

3.54.2 - 2025-09-13
-------------------
* Prefix platform specific symbols with platform name :mr:`451`

3.54.1 - 2025-09-12
-------------------
* Excempt GioPlatform namespaces from required version check :mr:`450`

3.54.0 - 2025-09-06
-------------------
* Fix compatibility with Python 3.14 :mr:`433`
* Add platform specific symbols back to Gio module :mr:`445`
* Include docs from old GNOME wiki :mr:`441`
* Add override for `GLib.MainContext.query()` :mr:`446`
* Fix optional inout parameter marshalling :mr:`447`

3.53.0 - 2025-08-27
-------------------
* Drop Python upper limit :mr:`418`
* Add `__enum|flags_values__` back to GEnum and GFlags :mr:`420`
* Fix asyncio event loop selector with Python 3.13 :mr:`421`
* Support `Gtk.Template` on sub-classed Python classes :mr:`199`
* Use GI Repository singleton if GLib >= 2.85 :mr:`427`
* Expose finish_func on function info to determine if a function can be used as awaitable :mr:`428`
* Documentation updates :mr:`424` :mr:`426` :mr:`429` :mr:`430`
* `ParamSpec` objects now return the expected enum type :mr:`432`
* Fix `Gio.ActionMap` override for `Gio.Application` :mr:`435`
* Fix regression for functions with multiple callbacks :mr:`436` :mr:`437`
* Cleanup: callable argument cache :mr:`438`
* Format Python and C code :mr:`386`
* Fix compatibility with GLib 2.84 :mr:`443`
* (chore) clean up array cache code :mr:`440`

(From OE-Core rev: 37d57c9d1773f5a9d1665484bd43ad10a0e175a5)

Signed-off-by: Jörg Sommer <joerg.sommer@navimatix.de>
Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 41 insertions, 0 deletions

diff --git a/meta/recipes-devtools/python/python3-pygobject_3.54.5.bb b/meta/recipes-devtools/python/python3-pygobject_3.54.5.bb
new file mode 100644
index 0000000000..f6ed3ff5fb
--- /dev/null
+++ b/meta/recipes-devtools/python/python3-pygobject_3.54.5.bb
@@ -0,0 +1,41 @@
+SUMMARY = "Python GObject bindings"
+HOMEPAGE = "https://gitlab.gnome.org/GNOME/pygobject"
+DESCRIPTION = "PyGObject is a Python package which provides bindings for GObject based libraries such as GTK, GStreamer, WebKitGTK, GLib, GIO and many more."
+SECTION = "devel/python"
+LICENSE = "LGPL-2.1-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=91db794c3adc9d824d4eddabb341e816"
+
+GIR_MESON_OPTION = ""
+
+inherit gnomebase setuptools3-base gobject-introspection upstream-version-is-even
+
+python() {
+    if d.getVar('CLASSOVERRIDE') == "class-target" and not bb.utils.to_boolean(d.getVar("GI_DATA_ENABLED")):
+        raise bb.parse.SkipRecipe("GI not available")
+}
+
+DEPENDS += "python3 glib-2.0"
+
+GNOME_COMPRESS_TYPE = "gz"
+GNOMEBN = "pygobject"
+
+SRC_URI[archive.sha256sum] = "b6656f6348f5245606cf15ea48c384c7f05156c75ead206c1b246c80a22fb585"
+
+S = "${UNPACKDIR}/${GNOMEBN}-${PV}"
+
+PACKAGECONFIG ??= "${@bb.utils.contains_any('DISTRO_FEATURES', [ 'directfb', 'wayland', 'x11' ], 'cairo', '', d)}"
+
+RDEPENDS:${PN} += " \
+    python3-asyncio \
+    python3-io \
+    python3-pkgutil \
+    gobject-introspection \
+"
+
+# python3-pycairo is checked on configuration -> DEPENDS
+# we don't link against python3-pycairo -> RDEPENDS
+PACKAGECONFIG[cairo] = "-Dpycairo=enabled,-Dpycairo=disabled, cairo python3-pycairo, python3-pycairo"
+PACKAGECONFIG[tests] = "-Dtests=true,-Dtests=false,"
+
+BBCLASSEXTEND = "native"
+PACKAGECONFIG:class-native = ""