python3-numpy: upgrade 1.25.0 -> 1.25.1

A total of 14 pull requests were merged for this release.
========================================================
 #23968: MAINT: prepare 1.25.x for further development
 #24036: BLD: Port long double identification to C for meson
 #24037: BUG: Fix reduction return NULL to be goto fail
 #24038: BUG: Avoid undefined behavior in array.astype()
 #24039: BUG: Ensure __array_ufunc__ works without any kwargs passed
 #24117: MAINT: Pin urllib3 to avoid anaconda-client bug.
 #24118: TST: Pin pydantic<2 in Pyodide workflow
 #24119: MAINT: Bump pypa/cibuildwheel from 2.13.0 to 2.13.1
 #24120: MAINT: Bump actions/checkout from 3.5.2 to 3.5.3
 #24122: BUG: Multiply or Divides using SIMD without a full vector can...
 #24127: MAINT: testing for IS_MUSL closes #24074
 #24128: BUG: Only replace dtype temporarily if dimensions changed
 #24129: MAINT: Bump actions/setup-node from 3.6.0 to 3.7.0
 #24134: BUG: Fix private procedures in f2py modules

(From OE-Core rev: 7371f2513d30bf6a17620271df8abbdaeafaae6b)

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 73 insertions, 0 deletions

diff --git a/meta/recipes-devtools/python/python3-numpy_1.25.1.bb b/meta/recipes-devtools/python/python3-numpy_1.25.1.bb
new file mode 100644
index 0000000000..3632ab71ee
--- /dev/null
+++ b/meta/recipes-devtools/python/python3-numpy_1.25.1.bb
@@ -0,0 +1,73 @@
+SUMMARY = "A sophisticated Numeric Processing Package for Python"
+HOMEPAGE = "https://numpy.org/"
+DESCRIPTION = "NumPy is the fundamental package needed for scientific computing with Python."
+SECTION = "devel/python"
+LICENSE = "BSD-3-Clause & BSD-2-Clause & PSF-2.0 & Apache-2.0 & MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=7614a5b0073688df53773ec6ec7fe81d"
+
+SRCNAME = "numpy"
+
+SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/${SRCNAME}-${PV}.tar.gz \
+           file://0001-Don-t-search-usr-and-so-on-for-libraries-by-default-.patch \
+           file://0001-numpy-core-Define-RISCV-32-support.patch \
+           file://run-ptest \
+           "
+SRC_URI[sha256sum] = "9a3a9f3a61480cc086117b426a8bd86869c213fc4072e606f01c4e4b66eb92bf"
+
+GITHUB_BASE_URI = "https://github.com/numpy/numpy/releases"
+UPSTREAM_CHECK_REGEX = "releases/tag/v?(?P<pver>\d+(\.\d+)+)$"
+
+DEPENDS += "python3-cython-native"
+
+inherit ptest setuptools3 github-releases
+
+S = "${WORKDIR}/numpy-${PV}"
+
+CLEANBROKEN = "1"
+
+do_compile:prepend() {
+    export NPY_DISABLE_SVML=1
+}
+
+# Unfortunately the following pyc files are non-deterministc due to 'frozenset'
+# being written without strict ordering, even with PYTHONHASHSEED = 0
+# Upstream is discussing ways to solve the issue properly, until then let's
+# just not install the problematic files.
+# More info: http://benno.id.au/blog/2013/01/15/python-determinism
+do_install:append() {
+        rm ${D}${PYTHON_SITEPACKAGES_DIR}/numpy/typing/tests/data/pass/__pycache__/literal.cpython*
+}
+
+FILES:${PN}-staticdev += "${PYTHON_SITEPACKAGES_DIR}/numpy/core/lib/*.a ${PYTHON_SITEPACKAGES_DIR}/numpy/random/lib/*.a"
+
+# install what is needed for numpy.test()
+RDEPENDS:${PN} = "${PYTHON_PN}-unittest \
+                  ${PYTHON_PN}-difflib \
+                  ${PYTHON_PN}-pprint \
+                  ${PYTHON_PN}-pickle \
+                  ${PYTHON_PN}-shell \
+                  ${PYTHON_PN}-doctest \
+                  ${PYTHON_PN}-datetime \
+                  ${PYTHON_PN}-distutils \
+                  ${PYTHON_PN}-misc \
+                  ${PYTHON_PN}-mmap \
+                  ${PYTHON_PN}-netclient \
+                  ${PYTHON_PN}-numbers \
+                  ${PYTHON_PN}-pydoc \
+                  ${PYTHON_PN}-pkgutil \
+                  ${PYTHON_PN}-email \
+                  ${PYTHON_PN}-compression \
+                  ${PYTHON_PN}-ctypes \
+                  ${PYTHON_PN}-threading \
+                  ${PYTHON_PN}-multiprocessing \
+                  ${PYTHON_PN}-json \
+"
+RDEPENDS:${PN}-ptest += "${PYTHON_PN}-pytest \
+                         ${PYTHON_PN}-hypothesis \
+                         ${PYTHON_PN}-sortedcontainers \
+                         ${PYTHON_PN}-resource \
+                         ${PYTHON_PN}-typing-extensions \
+                         ldd \
+"
+
+BBCLASSEXTEND = "native nativesdk"