python3-numpy: upgrade 1.24.2 -> 1.24.3

Changelog:
==========
A total of 17 pull requests were merged for this release.

    #23206: BUG: fix for f2py string scalars (#23194)
    #23207: BUG: datetime64/timedelta64 comparisons return NotImplemented
    #23208: MAINT: Pin matplotlib to version 3.6.3 for refguide checks
    #23221: DOC: Fix matplotlib error in documentation
    #23226: CI: Ensure submodules are initialized in gitpod.
    #23341: TYP: Replace duplicate reduce in ufunc type signature with reduceat.
    #23342: TYP: Remove duplicate CLIP/WRAP/RAISE in __init__.pyi.
    #23343: TYP: Mark d argument to fftfreq and rfftfreq as optional...
    #23344: TYP: Add type annotations for comparison operators to MaskedArray.
    #23345: TYP: Remove some stray type-check-only imports of msort
    #23370: BUG: Ensure like is only stripped for like= dispatched functions
    #23543: BUG: fix loading and storing big arrays on s390x
    #23544: MAINT: Bump larsoner/circleci-artifacts-redirector-action
    #23634: BUG: Ignore invalid and overflow warnings in masked setitem
    #23635: BUG: Fix masked array raveling when order="A" or order="K"
    #23636: MAINT: Update conftest for newer hypothesis versions
    #23637: BUG: Fix bug in parsing F77 style string arrays.

(From OE-Core rev: 38192c432204ec498cbdd1005ec2577f84e36018)

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 73 insertions, 0 deletions

diff --git a/meta/recipes-devtools/python/python3-numpy_1.24.3.bb b/meta/recipes-devtools/python/python3-numpy_1.24.3.bb
new file mode 100644
index 0000000000..710af5fe8f
--- /dev/null
+++ b/meta/recipes-devtools/python/python3-numpy_1.24.3.bb
@@ -0,0 +1,73 @@
+SUMMARY = "A sophisticated Numeric Processing Package for Python"
+HOMEPAGE = "https://numpy.org/"
+DESCRIPTION = "NumPy is the fundamental package needed for scientific computing with Python."
+SECTION = "devel/python"
+LICENSE = "BSD-3-Clause & BSD-2-Clause & PSF-2.0 & Apache-2.0 & MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=8026691468924fb6ec155dadfe2a1a7f"
+
+SRCNAME = "numpy"
+
+SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/${SRCNAME}-${PV}.tar.gz \
+           file://0001-Don-t-search-usr-and-so-on-for-libraries-by-default-.patch \
+           file://0001-numpy-core-Define-RISCV-32-support.patch \
+           file://run-ptest \
+           "
+SRC_URI[sha256sum] = "ab344f1bf21f140adab8e47fdbc7c35a477dc01408791f8ba00d018dd0bc5155"
+
+GITHUB_BASE_URI = "https://github.com/numpy/numpy/releases"
+UPSTREAM_CHECK_REGEX = "releases/tag/v?(?P<pver>\d+(\.\d+)+)$"
+
+DEPENDS += "python3-cython-native"
+
+inherit ptest setuptools3 github-releases
+
+S = "${WORKDIR}/numpy-${PV}"
+
+CLEANBROKEN = "1"
+
+do_compile:prepend() {
+    export NPY_DISABLE_SVML=1
+}
+
+# Unfortunately the following pyc files are non-deterministc due to 'frozenset'
+# being written without strict ordering, even with PYTHONHASHSEED = 0
+# Upstream is discussing ways to solve the issue properly, until then let's
+# just not install the problematic files.
+# More info: http://benno.id.au/blog/2013/01/15/python-determinism
+do_install:append() {
+        rm ${D}${PYTHON_SITEPACKAGES_DIR}/numpy/typing/tests/data/pass/__pycache__/literal.cpython*
+}
+
+FILES:${PN}-staticdev += "${PYTHON_SITEPACKAGES_DIR}/numpy/core/lib/*.a ${PYTHON_SITEPACKAGES_DIR}/numpy/random/lib/*.a"
+
+# install what is needed for numpy.test()
+RDEPENDS:${PN} = "${PYTHON_PN}-unittest \
+                  ${PYTHON_PN}-difflib \
+                  ${PYTHON_PN}-pprint \
+                  ${PYTHON_PN}-pickle \
+                  ${PYTHON_PN}-shell \
+                  ${PYTHON_PN}-doctest \
+                  ${PYTHON_PN}-datetime \
+                  ${PYTHON_PN}-distutils \
+                  ${PYTHON_PN}-misc \
+                  ${PYTHON_PN}-mmap \
+                  ${PYTHON_PN}-netclient \
+                  ${PYTHON_PN}-numbers \
+                  ${PYTHON_PN}-pydoc \
+                  ${PYTHON_PN}-pkgutil \
+                  ${PYTHON_PN}-email \
+                  ${PYTHON_PN}-compression \
+                  ${PYTHON_PN}-ctypes \
+                  ${PYTHON_PN}-threading \
+                  ${PYTHON_PN}-multiprocessing \
+                  ${PYTHON_PN}-json \
+"
+RDEPENDS:${PN}-ptest += "${PYTHON_PN}-pytest \
+                         ${PYTHON_PN}-hypothesis \
+                         ${PYTHON_PN}-sortedcontainers \
+                         ${PYTHON_PN}-resource \
+                         ${PYTHON_PN}-typing-extensions \
+                         ldd \
+"
+
+BBCLASSEXTEND = "native nativesdk"