python3-maturin: upgrade 1.6.0 -> 1.7.0

Changelog:
============
- Initial iOS support
- Remove old import hook in #2105, use maturin-import-hook instead
- Bump MSRV to 1.74.0
- Add support for overriding wheel tag with _PYTHON_HOST_PLATFORM
- Don't add files to an archive more than once
- Only use base python executable when MATURIN_PEP517_USE_BASE_PYTHON is set

(From OE-Core rev: d0c4ce388721a47608abc4d908e266ea969a0161)

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/meta/recipes-devtools/python/python3-maturin_1.7.0.bb b/meta/recipes-devtools/python/python3-maturin_1.7.0.bb
new file mode 100644
index 0000000000..779a66840e
--- /dev/null
+++ b/meta/recipes-devtools/python/python3-maturin_1.7.0.bb
@@ -0,0 +1,42 @@
+SUMMARY = "Build and publish crates with pyo3, rust-cpython, cffi bindings and rust binaries as python packages"
+HOMEPAGE = "https://github.com/pyo3/maturin"
+SECTION = "devel/python"
+LICENSE = "MIT | Apache-2.0"
+LIC_FILES_CHKSUM = "file://license-apache;md5=1836efb2eb779966696f473ee8540542 \
+                    file://license-mit;md5=85fd3b67069cff784d98ebfc7d5c0797"
+
+SRC_URI[sha256sum] = "1ba5277dd7832dc6181d69a005182b97b3520945825058484ffd9296f2efb59c"
+
+S = "${WORKDIR}/maturin-${PV}"
+
+CFLAGS += "-fdebug-prefix-map=${CARGO_HOME}=${TARGET_DBGSRC_DIR}/cargo_home"
+
+DEPENDS += "\
+    python3-setuptools-rust-native \
+    python3-semantic-version-native \
+    python3-setuptools-rust \
+"
+
+require ${BPN}-crates.inc
+
+inherit pypi cargo-update-recipe-crates python_pyo3 python_setuptools_build_meta
+
+do_configure() {
+    python_pyo3_do_configure
+    cargo_common_do_configure
+    python_pep517_do_configure
+}
+
+RDEPENDS:${PN} += "\
+    cargo \
+    python3-json \
+    rust \
+"
+
+RRECOMMENDS:${PN} += "\
+    python3-ensurepip \
+    python3-pip \
+    python3-venv \
+"
+
+BBCLASSEXTEND = "native nativesdk"