python3-flit-core: upgrade 3.10.1 -> 3.11.0

This update is required for latest versions of packages such as sphinx
to build with flit, otherwise you encounter errors like:

|   File "/home/tgamblin/workspace/yocto/poky/build/tmp/work/core2-64-poky-linux/python3-sphinx/8.2.1/recipe-sysroot-native/usr/lib/python3.13/site-packages/flit_core/config.py", line 444, in _check_type
|     raise ConfigError(
|         "{} field should be {}, not {}".format(field_name, cls, type(d[field_name]))
|     )
| flit_core.config.ConfigError: license field should be <class 'dict'>, not <class 'str'>
|
| ERROR Backend subprocess exited when trying to invoke get_requires_for_build_wheel

Changelog (https://github.com/pypa/flit/blob/main/doc/history.rst#version-311):

- Support for SPDX license expressions and multiple license files, as
  detailed in PEP 639:

    license = "BSD-3-Clause"
    license-files = ["LICENSE"]

  For now, only a single license identifier is allowed. More complex
  expressions describing multiple licenses & expressions may be
  supported in a future version.

- The metadata format in produced packages is now version 2.4, to
  support the expanded license information.

(From OE-Core rev: 268f1c96c70334d6a882d00e895e1f0c72cfa36f)

Signed-off-by: Trevor Gamblin <tgamblin@baylibre.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 31 insertions, 0 deletions

diff --git a/meta/recipes-devtools/python/python3-flit-core_3.11.0.bb b/meta/recipes-devtools/python/python3-flit-core_3.11.0.bb
new file mode 100644
index 0000000000..1d44b58830
--- /dev/null
+++ b/meta/recipes-devtools/python/python3-flit-core_3.11.0.bb
@@ -0,0 +1,31 @@
+SUMMARY = "This provides a PEP 517 build backend for packages using Flit."
+DESCRIPTION = "This provides a PEP 517 build backend for packages using \
+Flit. The only public interface is the API specified by PEP 517, at \
+flit_core.buildapi."
+HOMEPAGE = "https://github.com/pypa/flit"
+BUGTRACKER = "https://github.com/pypa/flit/issues"
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=41eb78fa8a872983a882c694a8305f08"
+
+SRC_URI[sha256sum] = "58d0a07f684c315700c9c54a661a1130995798c3e495db0db53ce6e7d0121825"
+
+inherit pypi python_flit_core
+
+# Need to install by hand as there's a dependency loop
+DEPENDS:remove:class-native = " python3-build-native python3-installer-native"
+DEPENDS:append:class-native = " unzip-native"
+
+# We need the full flit tarball
+PYPI_PACKAGE = "flit"
+PEP517_SOURCE_PATH = "${S}/flit_core"
+
+do_compile:class-native () {
+    python_flit_core_do_manual_build
+}
+
+do_install:class-native () {
+    python_pep517_do_bootstrap_install
+}
+
+BBCLASSEXTEND = "native nativesdk"