python3-cython: update 0.29.36 -> 3.0.7

pep517 build backends require cython 3.x when
python is at 3.12, so we can't hold this update any
longer. There are only a few things in meta-oe
and meta that break anymore, and fixes for them
are provided at the same time as this patch.

License-update: http -> https

(From OE-Core rev: 21507a3be23a604259a6a903a7083db54d29487f)

Signed-off-by: Alexander Kanavin <alex@linutronix.de>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 37 insertions, 0 deletions

diff --git a/meta/recipes-devtools/python/python3-cython_3.0.7.bb b/meta/recipes-devtools/python/python3-cython_3.0.7.bb
new file mode 100644
index 0000000000..07638d7ad7
--- /dev/null
+++ b/meta/recipes-devtools/python/python3-cython_3.0.7.bb
@@ -0,0 +1,37 @@
+inherit setuptools3
+require python-cython.inc
+
+RDEPENDS:${PN} += "\
+    python3-setuptools \
+"
+
+# running build_ext a second time during install fails, because Python
+# would then attempt to import cythonized modules built for the target
+# architecture.
+SETUPTOOLS_INSTALL_ARGS += "--skip-build"
+
+do_install:append() {
+    # rename scripts that would conflict with the Python 2 build of Cython
+    mv ${D}${bindir}/cython ${D}${bindir}/cython3
+    mv ${D}${bindir}/cythonize ${D}${bindir}/cythonize3
+    mv ${D}${bindir}/cygdb ${D}${bindir}/cygdb3
+}
+
+PACKAGESPLITFUNCS =+ "cython_fix_sources"
+
+cython_fix_sources () {
+        for f in ${PKGD}${TARGET_DBGSRC_DIR}/Cython/Compiler/FlowControl.c \
+                ${PKGD}${TARGET_DBGSRC_DIR}/Cython/Compiler/FusedNode.c \
+                ${PKGD}${TARGET_DBGSRC_DIR}/Cython/Compiler/Scanning.c \
+                ${PKGD}${TARGET_DBGSRC_DIR}/Cython/Compiler/Visitor.c \
+                ${PKGD}${TARGET_DBGSRC_DIR}/Cython/Plex/Actions.c \
+                ${PKGD}${TARGET_DBGSRC_DIR}/Cython/Plex/Scanners.c \
+                ${PKGD}${TARGET_DBGSRC_DIR}/Cython/Runtime/refnanny.c \
+                ${PKGD}${TARGET_DBGSRC_DIR}/Cython/Tempita/_tempita.c \
+                ${PKGD}${libdir}/${PYTHON_DIR}/site-packages/Cython*/SOURCES.txt; do
+                if [ -e $f ]; then
+                        sed -i -e 's#${WORKDIR}/Cython-${PV}#${TARGET_DBGSRC_DIR}#g' $f
+                fi
+        done
+}
+