ninja: upgrade 1.12.0 -> 1.12.1

Changelog:
===========
- Screen updates extremely slow on Windows
- Dry run error if the build directory does not exist
- New critical path scheduler performance improvements

(From OE-Core rev: ac98c4850b8bf3eb6c87fbace1f038a52a6162e9)

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 33 insertions, 0 deletions

diff --git a/meta/recipes-devtools/ninja/ninja_1.12.1.bb b/meta/recipes-devtools/ninja/ninja_1.12.1.bb
new file mode 100644
index 0000000000..9f5c014b9b
--- /dev/null
+++ b/meta/recipes-devtools/ninja/ninja_1.12.1.bb
@@ -0,0 +1,33 @@
+SUMMARY = "Ninja is a small build system with a focus on speed."
+HOMEPAGE = "https://ninja-build.org/"
+DESCRIPTION = "Ninja is a small build system with a focus on speed. It differs from other build systems in two major respects: it is designed to have its input files generated by a higher-level build system, and it is designed to run builds as fast as possible."
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://COPYING;md5=a81586a64ad4e476c791cda7e2f2c52e"
+
+DEPENDS = "re2c-native ninja-native"
+
+SRCREV = "2daa09ba270b0a43e1929d29b073348aa985dfaa"
+
+SRC_URI = "git://github.com/ninja-build/ninja.git;branch=release;protocol=https"
+UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>.*)"
+
+S = "${WORKDIR}/git"
+
+do_configure[noexec] = "1"
+
+do_compile:class-native() {
+        python3 ./configure.py --bootstrap
+}
+
+do_compile() {
+        python3 ./configure.py
+        ninja
+}
+
+do_install() {
+        install -D -m 0755  ${S}/ninja ${D}${bindir}/ninja
+}
+
+BBCLASSEXTEND = "native nativesdk"
+
+CVE_STATUS[CVE-2021-4336] = "cpe-incorrect: This is a different Ninja"