eudev: Upgrade 3.2.12 -> 3.2.14

Drop merged patches:

  0001-Export-dummies-for.patch
  0002-Bump-udev-version-to-251.patch

Boian Bonev (13):
      Update as per IRC discussion
      Bump udev version to 251
      Export dummies for
      bump version to 3.2.14
      Fix := not preventing further assignments to RUN
      Add /usr/local/lib/udev/rules.d
      Move the changes from udev.7 to udev.xml
      Regenerate according to 0cf14fb and e5e4013
      Improve wording and restore lines lost in merges
      Improve wording
      Tabs to spaces
      Ensure that standard file descriptors are open
      Commit the generated man page

NaofumiHonda (1):
      Clear sysattr cache if a null pointer is passed (#255)

Vivien Kraus (6):
      Let libudev find hwdb.bin under UDEV_HWDB_BIN
      Add a generic --output argument to udevadm hwdb
      Dynamically get the udevadm hwdb files with a path variable
      fixup! Dynamically get the udevadm hwdb files with a path variable
      Remove references to /run/udev/hwdb.d
      Clarify the /etc/udev/hwdb.d file override with respect to UDEV_HWDB_PATH

(From OE-Core rev: 2e0f552cac05c2b9f5a80ac396374a7987238a34)

Signed-off-by: Alex Kiernan <alex.kiernan@gmail.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 87 insertions, 0 deletions

diff --git a/meta/recipes-core/udev/eudev_3.2.14.bb b/meta/recipes-core/udev/eudev_3.2.14.bb
new file mode 100644
index 0000000000..d0758691bd
--- /dev/null
+++ b/meta/recipes-core/udev/eudev_3.2.14.bb
@@ -0,0 +1,87 @@
+SUMMARY = "eudev is a fork of systemd's udev"
+HOMEPAGE = "https://github.com/eudev-project/eudev"
+DESCRIPTION = "eudev is Gentoo's fork of udev, systemd's device file manager for the Linux kernel. It manages device nodes in /dev and handles all user space actions when adding or removing devices."
+LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later"
+LICENSE:libudev = "LGPL-2.1-or-later"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
+
+DEPENDS = "gperf-native"
+
+PROVIDES = "udev"
+
+SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/${BP}.tar.gz \
+           file://init \
+           file://local.rules \
+           "
+
+SRC_URI[sha256sum] = "8da4319102f24abbf7fff5ce9c416af848df163b29590e666d334cc1927f006f"
+
+GITHUB_BASE_URI = "https://github.com/eudev-project/eudev/releases"
+
+inherit autotools update-rc.d qemu pkgconfig features_check manpages github-releases
+
+CONFLICT_DISTRO_FEATURES = "systemd"
+
+EXTRA_OECONF = " \
+    --sbindir=${base_sbindir} \
+    --with-rootlibdir=${base_libdir} \
+    --with-rootlibexecdir=${nonarch_base_libdir}/udev \
+    --with-rootprefix= \
+"
+
+PACKAGECONFIG ?= "blkid hwdb kmod \
+                  ${@bb.utils.filter('DISTRO_FEATURES', 'selinux', d)} \
+"
+PACKAGECONFIG[blkid] = "--enable-blkid,--disable-blkid,util-linux"
+PACKAGECONFIG[hwdb] = "--enable-hwdb,--disable-hwdb"
+PACKAGECONFIG[kmod] = "--enable-kmod,--disable-kmod,kmod"
+PACKAGECONFIG[manpages] = "--enable-manpages,--disable-manpages"
+PACKAGECONFIG[rule-generator] = "--enable-rule-generator,--disable-rule-generator"
+PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux,libselinux"
+
+do_install:append() {
+        install -d ${D}${sysconfdir}/init.d
+        install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev
+        sed -i s%@UDEVD@%${base_sbindir}/udevd% ${D}${sysconfdir}/init.d/udev
+        sed -i s%@KMOD@%${base_bindir}/kmod% ${D}${sysconfdir}/init.d/udev
+
+        install -d ${D}${sysconfdir}/udev/rules.d
+        install -m 0644 ${WORKDIR}/local.rules ${D}${sysconfdir}/udev/rules.d/local.rules
+
+        # Use classic network interface naming scheme
+        touch ${D}${sysconfdir}/udev/rules.d/80-net-name-slot.rules
+}
+
+do_install:prepend:class-target () {
+        # Remove references to buildmachine
+        sed -i -e 's:${RECIPE_SYSROOT_NATIVE}::g' \
+                ${B}/src/udev/keyboard-keys-from-name.h
+}
+
+INITSCRIPT_NAME = "udev"
+INITSCRIPT_PARAMS = "start 04 S ."
+
+PACKAGE_BEFORE_PN = "libudev ${PN}-hwdb"
+
+FILES:${PN} += "${nonarch_base_libdir}/udev"
+FILES:libudev = "${base_libdir}/libudev.so.*"
+FILES:${PN}-hwdb = "${sysconfdir}/udev/hwdb.d"
+
+RDEPENDS:${PN}-hwdb += "eudev"
+RDEPENDS:${PN} += "kmod"
+
+RPROVIDES:${PN} = "hotplug udev"
+RPROVIDES:${PN}-hwdb += "udev-hwdb"
+
+PACKAGE_WRITE_DEPS += "qemu-native"
+pkg_postinst:${PN}-hwdb () {
+        if test -n "$D"; then
+                $INTERCEPT_DIR/postinst_intercept update_udev_hwdb ${PKG} mlprefix=${MLPREFIX} binprefix=${MLPREFIX}
+        else
+                udevadm hwdb --update
+        fi
+}
+
+pkg_prerm:${PN}-hwdb () {
+        rm -f $D${sysconfdir}/udev/hwdb.bin
+}