summaryrefslogtreecommitdiffstats
path: root/meta/recipes-core/dbus/dbus_1.16.2.bb
diff options
context:
space:
mode:
authorRichard Purdie <richard.purdie@linuxfoundation.org>2025-11-07 13:31:53 +0000
committerRichard Purdie <richard.purdie@linuxfoundation.org>2025-11-07 13:31:53 +0000
commit8c22ff0d8b70d9b12f0487ef696a7e915b9e3173 (patch)
treeefdc32587159d0050a69009bdf2330a531727d95 /meta/recipes-core/dbus/dbus_1.16.2.bb
parentd412d2747595c1cc4a5e3ca975e3adc31b2f7891 (diff)
downloadpoky-8c22ff0d8b70d9b12f0487ef696a7e915b9e3173.tar.gz
The poky repository master branch is no longer being updated.
You can either: a) switch to individual clones of bitbake, openembedded-core, meta-yocto and yocto-docs b) use the new bitbake-setup You can find information about either approach in our documentation: https://docs.yoctoproject.org/ Note that "poky" the distro setting is still available in meta-yocto as before and we continue to use and maintain that. Long live Poky! Some further information on the background of this change can be found in: https://lists.openembedded.org/g/openembedded-architecture/message/2179 Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-core/dbus/dbus_1.16.2.bb')
-rw-r--r--meta/recipes-core/dbus/dbus_1.16.2.bb157
1 files changed, 0 insertions, 157 deletions
diff --git a/meta/recipes-core/dbus/dbus_1.16.2.bb b/meta/recipes-core/dbus/dbus_1.16.2.bb
deleted file mode 100644
index abe4196d9a..0000000000
--- a/meta/recipes-core/dbus/dbus_1.16.2.bb
+++ /dev/null
@@ -1,157 +0,0 @@
1SUMMARY = "D-Bus message bus"
2DESCRIPTION = "D-Bus is a message bus system, a simple way for applications to talk to one another. In addition to interprocess communication, D-Bus helps coordinate process lifecycle; it makes it simple and reliable to code a \"single instance\" application or daemon, and to launch applications and daemons on demand when their services are needed."
3HOMEPAGE = "https://dbus.freedesktop.org"
4SECTION = "base"
5
6inherit meson pkgconfig gettext upstream-version-is-even ptest-gnome
7
8LICENSE = "AFL-2.1 | GPL-2.0-or-later"
9LIC_FILES_CHKSUM = "file://COPYING;md5=eb0ffc69a965797a3d6686baa153ef05 \
10 file://dbus/dbus.h;beginline=6;endline=22;md5=df4251a6c6e15e6a9e3c77b2ac30065d \
11 "
12
13SRC_URI = "https://dbus.freedesktop.org/releases/dbus/dbus-${PV}.tar.xz \
14 file://run-ptest \
15 file://dbus-1.init \
16 "
17
18SRC_URI[sha256sum] = "0ba2a1a4b16afe7bceb2c07e9ce99a8c2c3508e5dec290dbb643384bd6beb7e2"
19
20EXTRA_OEMESON = "-Dxml_docs=disabled \
21 -Ddoxygen_docs=disabled \
22 -Dsystem_socket=/run/dbus/system_bus_socket \
23 -Dchecks=true \
24 -Druntime_dir=${runtimedir} \
25 -Dtest_socket_dir=/tmp \
26 -Dsession_socket_dir=/tmp \
27 "
28
29PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd x11', d)} \
30 message-bus traditional-activation user-session \
31 ${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)} \
32 "
33PACKAGECONFIG:class-native = ""
34PACKAGECONFIG:class-nativesdk = ""
35
36PACKAGECONFIG[message-bus] = "-Dmessage_bus=true,-Dmessage_bus=false,expat"
37PACKAGECONFIG[systemd] = "-Dsystemd=enabled -Dsystemd_system_unitdir=${systemd_system_unitdir},-Dsystemd=disabled,systemd"
38PACKAGECONFIG[x11] = "-Dx11_autolaunch=enabled,-Dx11_autolaunch=disabled, virtual/libx11 libsm"
39PACKAGECONFIG[traditional-activation] = "-Dtraditional_activation=true,-Dtraditional_activation=false"
40PACKAGECONFIG[user-session] = "-Duser_session=true -Dsystemd_user_unitdir=${systemd_user_unitdir},-Duser_session=false"
41PACKAGECONFIG[verbose-mode] = "-Dverbose_mode=true,-Dverbose_mode=false,,"
42PACKAGECONFIG[audit] = "-Dlibaudit=enabled,-Dlibaudit=disabled,audit"
43PACKAGECONFIG[selinux] = "-Dselinux=enabled,-Dselinux=disabled,libselinux"
44PACKAGECONFIG[tests] = "-Dmodular_tests=enabled -Dinstalled_tests=true,-Dmodular_tests=disabled -Dinstalled_tests=false,glib-2.0"
45
46DEPENDS = "virtual/libintl"
47RDEPENDS:${PN} += "${PN}-common ${PN}-tools"
48RDEPENDS:${PN}:class-native = ""
49
50inherit systemd useradd update-rc.d
51
52INITSCRIPT_NAME = "dbus-1"
53INITSCRIPT_PARAMS = "start 02 5 3 2 . stop 20 0 1 6 ."
54
55PACKAGES =+ "${PN}-lib ${PN}-common ${PN}-tools"
56
57USERADD_PACKAGES = "dbus-common"
58USERADD_PARAM:dbus-common = "--system --home ${localstatedir}/lib/dbus \
59 --no-create-home --shell /bin/false \
60 --user-group messagebus"
61
62CONFFILES:${PN} = "${sysconfdir}/dbus-1/system.conf ${sysconfdir}/dbus-1/session.conf"
63
64DEBIANNAME:${PN} = "dbus-1"
65
66FILES:${PN} = "${bindir}/dbus-daemon* \
67 ${bindir}/dbus-cleanup-sockets \
68 ${bindir}/dbus-launch \
69 ${bindir}/dbus-run-session \
70 ${libexecdir}/dbus* \
71 ${sysconfdir} \
72 ${localstatedir} \
73 ${systemd_system_unitdir} \
74 ${systemd_user_unitdir} \
75 ${nonarch_libdir}/tmpfiles.d/dbus.conf \
76"
77FILES:${PN}-common = "${sysconfdir}/dbus-1 \
78 ${datadir}/dbus-1/services \
79 ${datadir}/dbus-1/system-services \
80 ${datadir}/dbus-1/session.d \
81 ${datadir}/dbus-1/session.conf \
82 ${datadir}/dbus-1/system.d \
83 ${datadir}/dbus-1/system.conf \
84 ${systemd_system_unitdir}/dbus.socket \
85 ${systemd_system_unitdir}/sockets.target.wants \
86 ${systemd_user_unitdir}/dbus.socket \
87 ${systemd_user_unitdir}/sockets.target.wants \
88 ${nonarch_libdir}/sysusers.d/dbus.conf \
89"
90FILES:${PN}-tools = "${bindir}/dbus-uuidgen \
91 ${bindir}/dbus-send \
92 ${bindir}/dbus-monitor \
93 ${bindir}/dbus-update-activation-environment \
94"
95FILES:${PN}-lib = "${libdir}/lib*.so.*"
96RRECOMMENDS:${PN}-lib = "${PN}"
97RRECOMMENDS:${PN}-lib:class-target = "${VIRTUAL-RUNTIME_dbus}"
98FILES:${PN}-dev += "${libdir}/dbus-1.0/include ${bindir}/dbus-test-tool ${datadir}/xml/dbus-1"
99
100RDEPENDS:${PN}-ptest += "bash make dbus"
101
102pkg_postinst:dbus() {
103 if [ -z "$D" ] && [ -e /etc/init.d/populate-volatile.sh ] ; then
104 /etc/init.d/populate-volatile.sh update
105 fi
106}
107
108# dbus uses find_program() to find systemctl, which results in a build path in the
109# user dbus.socket
110EXTRA_OEMESON:append:class-target = " --cross-file=${WORKDIR}/dbus.cross"
111
112do_configure:prepend:class-target() {
113 cat >${WORKDIR}/dbus.cross <<EOF
114[binaries]
115systemctl = '${bindir}/systemctl'
116EOF
117}
118
119do_install:append() {
120 if ${@bb.utils.contains('PACKAGECONFIG', 'message-bus', 'true', 'false', d)}; then
121 if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
122 install -d ${D}${sysconfdir}/init.d
123 sed 's:@bindir@:${bindir}:' < ${UNPACKDIR}/dbus-1.init > ${S}/dbus-1.init.sh
124 install -m 0755 ${S}/dbus-1.init.sh ${D}${sysconfdir}/init.d/dbus-1
125
126 install -d ${D}${sysconfdir}/default/volatiles
127 echo "d messagebus messagebus 0755 /run/dbus none" \
128 > ${D}${sysconfdir}/default/volatiles/99_dbus
129
130 if ${@bb.utils.contains('PACKAGECONFIG', 'systemd', 'true', 'false', d)}; then
131 # symlink dbus-1.service to /dev/null to "mask" the service, This ensures
132 # that if systemd and sysv init systems are both enabled, systemd doesn't
133 # start two system buses (one from init.d/dbus-1, one from dbus.service).
134 ln -s /dev/null ${D}${systemd_system_unitdir}/dbus-1.service
135 fi
136 fi
137
138 mkdir -p ${D}${localstatedir}/lib/dbus
139 chown messagebus:messagebus ${D}${localstatedir}/lib/dbus
140 else
141 # This gets installed even if the bus is disabled
142 rm -rf ${D}${localstatedir}
143 fi
144
145 if [ "${@bb.utils.contains('PACKAGECONFIG', 'traditional-activation', '1', '0', d)}" = "1" ]
146 then
147 chown root:messagebus ${D}${libexecdir}/dbus-daemon-launch-helper
148 chmod 4755 ${D}${libexecdir}/dbus-daemon-launch-helper
149 fi
150
151 # Remove /run as it is created on startup
152 rm -rf ${D}${runtimedir}
153}
154
155BBCLASSEXTEND = "native nativesdk"
156
157CVE_PRODUCT += "d-bus_project:d-bus freedesktop:dbus freedesktop:libdbus"
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2026-04-23 01:29:08 +0000