u-boot: Upgrade to 2018.03 release

This upgrades the U-Boot from 2018.01 to 2018.03 release and drops
patches accepted upstream, getting the patch count to zero.

(From OE-Core rev: c1d680326cabd10d0940827e8dfdc884f67b1e9a)

Signed-off-by: Marek Vasut <marex@denx.de>
Cc: Otavio Salvador <otavio@ossystems.com.br>
Cc: Ross Burton <ross.burton@intel.com>
Cc: Richard Purdie <richard.purdie@linuxfoundation.org>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 29 insertions, 0 deletions

diff --git a/meta/recipes-bsp/u-boot/u-boot-mkimage_2018.03.bb b/meta/recipes-bsp/u-boot/u-boot-mkimage_2018.03.bb
new file mode 100644
index 0000000000..1c008be96e
--- /dev/null
+++ b/meta/recipes-bsp/u-boot/u-boot-mkimage_2018.03.bb
@@ -0,0 +1,29 @@
+require u-boot-common_${PV}.inc
+
+SUMMARY = "U-Boot bootloader image creation tool"
+DEPENDS = "openssl"
+
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE="${TARGET_PREFIX}" CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1'
+EXTRA_OEMAKE_class-native = 'CC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1'
+EXTRA_OEMAKE_class-nativesdk = 'CROSS_COMPILE="${HOST_PREFIX}" CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1'
+
+do_compile () {
+        oe_runmake sandbox_defconfig
+
+        # Disable CONFIG_CMD_LICENSE, license.h is not used by tools and
+        # generating it requires bin2header tool, which for target build
+        # is built with target tools and thus cannot be executed on host.
+        sed -i "s/CONFIG_CMD_LICENSE=.*/# CONFIG_CMD_LICENSE is not set/" .config
+
+        oe_runmake cross_tools NO_SDL=1
+}
+
+do_install () {
+        install -d ${D}${bindir}
+        install -m 0755 tools/mkimage ${D}${bindir}/uboot-mkimage
+        ln -sf uboot-mkimage ${D}${bindir}/mkimage
+}
+
+RDEPENDS_${PN} += "dtc"
+
+BBCLASSEXTEND = "native nativesdk"