2 files changed, 89 insertions, 0 deletions

diff --git a/meta-xilinx-core/recipes-bsp/dfx-mgr/dfx-mgr_1.0.bb b/meta-xilinx-core/recipes-bsp/dfx-mgr/dfx-mgr_1.0.bb
new file mode 100644
index 00000000..7f77fd38
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/dfx-mgr/dfx-mgr_1.0.bb
@@ -0,0 +1,55 @@
+SUMMARY  = "Xilinx dfx-mgr libraries"
+DESCRIPTION = "Xilinx Runtime User Space Libraries and Binaries"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=d67bcef754e935bf77b6d7051bd62b5e"
+
+REPO ?= "git://github.com/Xilinx/dfx-mgr.git;protocol=https"
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = "${REPO};${BRANCHARG}"
+
+BRANCH = "master"
+SRCREV = "4e6eef210db4dc0399a70688f17413850012f3a1"
+SOMAJOR = "1"
+SOMINOR = "0"
+SOVERSION = "${SOMAJOR}.${SOMINOR}"
+
+S = "${WORKDIR}/git"
+
+inherit cmake update-rc.d
+
+#DEPENDS += " libwebsockets inotify-tools libdfx xrt zocl libdrm"
+DEPENDS += " libwebsockets inotify-tools libdfx xrt libdrm"
+EXTRA_OECMAKE += " \
+               -DCMAKE_SYSROOT:PATH=${RECIPE_SYSROOT} \
+                "
+INITSCRIPT_NAME = "dfx-mgr.sh"
+INITSCRIPT_PARAMS = "start 99 S ."
+
+do_install(){
+        install -d ${D}${bindir}
+        install -d ${D}${libdir}
+        install -d ${D}${includedir}
+        install -d ${D}${sysconfdir}/init.d/
+        install -d ${D}${base_libdir}/firmware/xilinx
+        install -d ${D}${sysconfdir}/dfx-mgrd
+
+        cp ${B}/example/sys/linux/dfx-mgrd-static ${D}${bindir}/dfx-mgrd
+        cp ${B}/example/sys/linux/dfx-mgr-client-static ${D}${bindir}/dfx-mgr-client
+        chrpath -d ${D}${bindir}/dfx-mgrd
+        chrpath -d ${D}${bindir}/dfx-mgr-client
+        install -m 0755 ${S}/src/dfx-mgr.sh ${D}${sysconfdir}/init.d/
+        install -m 0755 ${S}/src/daemon.conf ${D}${sysconfdir}/dfx-mgrd/
+        install -m 0644 ${S}/src/dfxmgr_client.h ${D}${includedir}
+
+        oe_soinstall ${B}/src/libdfx-mgr.so.${SOVERSION} ${D}${libdir}
+
+        install -m 0644 ${S}/opendfx-graph/include/graph_api.h ${D}${includedir}
+        oe_soinstall ${B}/opendfx-graph/libdfxgraph.so.${SOVERSION} ${D}${libdir}
+}
+
+PACKAGES =+ "libdfx-mgr libdfxgraph"
+
+FILES:${PN} += "${base_libdir}/firmware/xilinx"
+FILES:libdfx-mgr = "${libdir}/libdfx-mgr.so.${SOVERSION} ${libdir}/libdfx-mgr.so.${SOMAJOR}"
+FILES:libdfxgraph = "${libdir}/libdfxgraph.so.${SOVERSION} ${libdir}/libdfxgraph.so.${SOMAJOR}"
diff --git a/meta-xilinx-core/recipes-bsp/libdfx/libdfx_1.0.bb b/meta-xilinx-core/recipes-bsp/libdfx/libdfx_1.0.bb
new file mode 100644
index 00000000..1731c630
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/libdfx/libdfx_1.0.bb
@@ -0,0 +1,34 @@
+SUMMARY = "Xilinx libdfx library"
+DESCRIPTION = "Xilinx libdfx Library and headers"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=94aba86aec117f003b958a52f019f1a7"
+
+BRANCH ?= "xlnx_rel_v2021.2"
+REPO ?= "git://github.com/Xilinx/libdfx.git;protocol=https"
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = "${REPO};${BRANCHARG}"
+SRCREV = "f79ff436edc620e1933592822a25561ccb5bd6ec"
+
+COMPATIBLE_MACHINE = "^$"
+COMPATIBLE_MACHINE:zynqmp = "zynqmp"
+COMPATIBLE_MACHINE:versal = "versal"
+
+S = "${WORKDIR}/git"
+
+inherit cmake
+
+RDEPENDS:${PN} = "${PN}-staticdev"
+PACKAGES =+ "${PN}-examples"
+
+do_install () {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+    install -d ${D}${bindir}
+    install -m 0644 ${B}/src/libdfx.a ${D}${libdir}
+    install -m 0644 ${B}/include/libdfx.h ${D}${includedir}
+    install -m 0755 ${B}/apps/dfx_app ${D}${bindir}
+}
+
+ALLOW_EMPTY:${PN} = "1"
+ALLOW_EMPTY:${PN}-examples = "1"