recipes-bsp: Add lib prefix for rf and dfe recipes

Add lib prefix for rf and dfe recipes as these recipes names conflicts
with multiconfig rf and dfe baremetal drive recipes. Since these are
linux libraries add lib prefix to recipes.

Signed-off-by: Sandeep Gundlupet Raju <sandeep.gundlupet-raju@amd.com>
Signed-off-by: Mark Hatle <mark.hatle@amd.com>

1 files changed, 37 insertions, 0 deletions

diff --git a/meta-xilinx-standalone/recipes-bsp/libdfeofdm/libdfeofdm_2023.1.bb b/meta-xilinx-standalone/recipes-bsp/libdfeofdm/libdfeofdm_2023.1.bb
new file mode 100644
index 00000000..e183b853
--- /dev/null
+++ b/meta-xilinx-standalone/recipes-bsp/libdfeofdm/libdfeofdm_2023.1.bb
@@ -0,0 +1,37 @@
+SUMMARY = "Linux dfeofdm library"
+SECTION = "libdfeofdm"
+LICENSE = "BSD-3-Clause"
+
+inherit pkgconfig xlnx-embeddedsw features_check
+
+REQUIRED_MACHINE_FEATURES = "rfsoc"
+
+FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+
+S = "${WORKDIR}/git"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+DEPENDS = "libmetal"
+
+PROVIDES = "libdfeofdm"
+
+DFEOFDM_SUBDIR = "XilinxProcessorIPLib/drivers/dfeofdm/src"
+
+do_compile:prepend() {
+    cd ${S}/${DFEOFDM_SUBDIR}
+    cp Makefile.Linux Makefile
+}
+
+do_install() {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+
+    cd ${S}/${DFEOFDM_SUBDIR}
+    oe_libinstall -so libdfeofdm ${D}${libdir}
+    install -m 0644 xdfeofdm_hw.h ${D}${includedir}/xdfeofdm_hw.h
+    install -m 0644 xdfeofdm.h ${D}${includedir}/xdfeofdm.h
+}
+
+FILES:${PN} = "${libdir}/*.so.*"
+FILES:${PN}-dev = "${libdir}/*.so  ${includedir}/*"