meta-xilinx-standalone: recipes-applications: hello-world: Remove dependency on esw_examples class

Hello world recipe doesn't have any dependency on the
do_generate_eglist task, It has dependency only on the linker generation.
So the esw repo linker generation is moved to the liner_gen.py
file, which needs to be called before do_configure.

This patch updates the recipe for the same.

Signed-off-by: Appana Durga Kedareswara rao <appana.durga.rao@xilinx.com>

1 files changed, 32 insertions, 2 deletions

diff --git a/meta-xilinx-standalone/recipes-applications/hello-world/hello-world_git.bb b/meta-xilinx-standalone/recipes-applications/hello-world/hello-world_git.bb
index 9f2d1b66..4e7545db 100644
--- a/meta-xilinx-standalone/recipes-applications/hello-world/hello-world_git.bb
+++ b/meta-xilinx-standalone/recipes-applications/hello-world/hello-world_git.bb
@@ -1,3 +1,33 @@
-inherit esw_examples
+inherit esw deploy
 
-ESW_COMPONENT_SRC = "/lib/sw_apps/hello_world/src"
+ESW_COMPONENT_SRC = "/lib/sw_apps/hello_world/src/"
+
+DEPENDS += "dtc-native libxil xiltimer device-tree"
+
+do_configure_prepend() {
+    cd ${S}
+    nativepython3 ${S}/scripts/linker_gen.py -d ${DTBFILE} -o ${OECMAKE_SOURCEPATH}
+}
+
+do_install() {
+    install -d ${D}/${base_libdir}/firmware
+    # Note that we have to make the ELF executable for it to be stripped
+    install -m 0755  ${B}/hello_world* ${D}/${base_libdir}/firmware
+}
+
+HELLO_WORLD_BASE_NAME ?= "${BPN}-${PKGE}-${PKGV}-${PKGR}-${MACHINE}-${DATETIME}"
+HELLO_WORLD_BASE_NAME[vardepsexclude] = "DATETIME"
+
+do_deploy() {
+
+    # We need to deploy the stripped elf, hence why not doing it from ${D}
+    install -Dm 0644 ${WORKDIR}/package/${base_libdir}/firmware/hello_world.elf ${DEPLOYDIR}/${HELLO_WORLD_BASE_NAME}.elf
+    ln -sf ${HELLO_WORLD_BASE_NAME}.elf ${DEPLOYDIR}/${BPN}-${MACHINE}.elf
+    ${OBJCOPY} -O binary ${WORKDIR}/package/${base_libdir}/firmware/hello_world.elf ${WORKDIR}/package/${base_libdir}/firmware/hello_world.bin
+    install -m 0644 ${WORKDIR}/package/${base_libdir}/firmware/hello_world.bin ${DEPLOYDIR}/${HELLO_WORLD_BASE_NAME}.bin
+    ln -sf ${HELLO_WORLD_BASE_NAME}.bin ${DEPLOYDIR}/${BPN}-${MACHINE}.bin
+}
+
+addtask deploy before do_build after do_package
+
+FILES_${PN} = "${base_libdir}/firmware/hello_world*"