xlnx-compatible-os.bbclass: Class to allow recipes to list OS compatibility

Following the example of base.bbclass in OE-Core, a new COMPATIBLE_OS
variable is defined.  Similar to COMPATIBLE_MACHINE, it is a regex that
can be used to declare TARGET_OS string compatibility on a per-recipe
basis.  Either the distro configuration or the recipes themselves will
need to inherit this class.

By default the class assumes we're building a Linux based system, and
thus any recipe who has not declared compatibility is compatible with
Linux.  The default compatible field was copied from bitbake.conf to
ensure there are no surprised.

Additionally, enable the usage of this class throughout
meta-xilinx-standalone layer.

Signed-off-by: Mark Hatle <mark.hatle@xilinx.com>

2 files changed, 20 insertions, 1 deletions

diff --git a/meta-xilinx-standalone/classes/esw.bbclass b/meta-xilinx-standalone/classes/esw.bbclass
index 65817825..4a815eb6 100644
--- a/meta-xilinx-standalone/classes/esw.bbclass
+++ b/meta-xilinx-standalone/classes/esw.bbclass
@@ -1,4 +1,4 @@
-inherit pkgconfig cmake yocto-cmake-translation
+inherit pkgconfig cmake
 
 LICENSE = "Proprietary"
 LICFILENAME = "license.txt"
@@ -37,6 +37,9 @@ COMPATIBLE_MACHINE_cortexr5-zynqmp = "cortexr5-zynqmp"
 COMPATIBLE_HOST_cortexa72-versal = "aarch64.*-elf"
 COMPATIBLE_MACHINE_cortexa72-versal = "cortexa72-versal"
 
+COMPATIBLE_OS = "elf"
+COMPATIBLE_OS_arm = "eabi"
+
 DTBFILE_microblaze-pmu ?= "${RECIPE_SYSROOT}/boot/devicetree/system-top.dtb"
 DTBFILE_microblaze-plm ?= "${RECIPE_SYSROOT}/boot/devicetree/system-top.dtb"
 DTBFILE_cortexa53-zynqmp ?= "${RECIPE_SYSROOT}/boot/devicetree/system-top.dtb"
diff --git a/meta-xilinx-standalone/classes/xlnx-compatible-os.bbclass b/meta-xilinx-standalone/classes/xlnx-compatible-os.bbclass
new file mode 100644
index 00000000..4b06ddd8
--- /dev/null
+++ b/meta-xilinx-standalone/classes/xlnx-compatible-os.bbclass
@@ -0,0 +1,16 @@
+# We assume everything is Linux compatible, deviations to this
+# must define their own compatible OS
+COMPATIBLE_OS ?= "linux${LIBCEXTENSION}${ABIEXTENSION}"
+
+python() {
+    # Only do this check for target recipes
+    if d.getVar('CLASSOVERRIDE') != "class-target":
+        return
+
+    need_os = d.getVar('COMPATIBLE_OS')
+    if need_os:
+        import re
+        target_os = d.getVar('TARGET_OS')
+        if not re.match(need_os, target_os):
+            raise bb.parse.SkipRecipe("incompatible with os %s (not in COMPATIBLE_OS '%s')" % (target_os, need_os))
+}