image-selector: Add SDT image selector recipe

Also add imgsel wrapper allowing for the correct image-selector recipe
to be built depending if the XSCT or SDT flow is in use

Signed-off-by: John Toomey <john.toomey@amd.com>
Signed-off-by: Mark Hatle <mark.hatle@amd.com>

1 files changed, 45 insertions, 0 deletions

diff --git a/meta-xilinx-standalone-sdt/recipes-bsp/image-selector/image-selector_2024.2.bb b/meta-xilinx-standalone-sdt/recipes-bsp/image-selector/image-selector_2024.2.bb
new file mode 100644
index 00000000..eee73fcb
--- /dev/null
+++ b/meta-xilinx-standalone-sdt/recipes-bsp/image-selector/image-selector_2024.2.bb
@@ -0,0 +1,45 @@
+inherit esw python3native esw_apps_common deploy
+
+DEPENDS += "libxil xiltimer bootgen-native"
+
+PROVIDES = "virtual/imgsel"
+RCONFLICTS:${PN} = "imgsel"
+
+ESW_COMPONENT_SRC = "/src/"
+ESW_EXECUTABLE_NAME = "imgsel"
+
+SRC_URI:append = " git://github.com/Xilinx/image-selector.git;protocol=https;branch=main;destsuffix=image-selector;name=image-selector"
+SRCREV_image-selector = "809441712855a64a35496192c180e31328a78b7b"
+
+do_configure:prepend() {
+    (
+    cd ${S}
+    lopper ${DTS_FILE} -- baremetallinker_xlnx.py ${ESW_MACHINE} ${WORKDIR}/${BPN}/${ESW_COMPONENT_SRC}
+    install -m 0644 *.cmake ${WORKDIR}/${BPN}/${ESW_COMPONENT_SRC}/
+    install -m 0644 ${S}/cmake/UserConfig.cmake ${WORKDIR}/${BPN}/${ESW_COMPONENT_SRC}
+    )
+}
+
+OECMAKE_SOURCEPATH = "${WORKDIR}/${BPN}/${ESW_COMPONENT_SRC}"
+
+do_compile:append () {
+cat > ${WORKDIR}/${PN}.bif << EOF
+    the_ROM_image:
+    {
+            [bootloader,destination_cpu=a53-0] ${B}/${ESW_EXECUTABLE_NAME}.elf
+    }
+EOF
+
+    bootgen -image ${WORKDIR}/${PN}.bif -arch ${SOC_FAMILY} -w -o ${B}/${PN}.bin
+}
+
+do_install[noexec] = "1"
+
+do_deploy() {
+    install -Dm 0644 ${B}/${ESW_EXECUTABLE_NAME}.elf ${DEPLOYDIR}/${PN}.elf
+    ln -sf ${PN}.elf ${DEPLOYDIR}/${PN}-${MACHINE}.elf
+    install -Dm 0644 ${B}/${PN}.bin ${DEPLOYDIR}/${PN}.bin
+    ln -sf ${PN}.bin ${DEPLOYDIR}/${PN}-${MACHINE}.bin
+}
+
+addtask deploy before do_build after do_install