Added VDU bb files for 2024.2 and updated SRCREV

Signed-off-by: Mark Hatle <mark.hatle@amd.com>

4 files changed, 171 insertions, 0 deletions

diff --git a/meta-xilinx-multimedia/recipes-multimedia/vdu/kernel-module-vdu_2024.2.bb b/meta-xilinx-multimedia/recipes-multimedia/vdu/kernel-module-vdu_2024.2.bb
new file mode 100644
index 00000000..f3c79a0c
--- /dev/null
+++ b/meta-xilinx-multimedia/recipes-multimedia/vdu/kernel-module-vdu_2024.2.bb
@@ -0,0 +1,34 @@
+SUMMARY = "Linux kernel module for Video Decode Unit"
+DESCRIPTION = "Out-of-tree VDU decoder common kernel modules"
+SECTION = "kernel/modules"
+LICENSE = "GPL-2.0-or-later"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=eb723b61539feef013de476e68b5c50a"
+
+PV .= "+git"
+
+S = "${WORKDIR}/git"
+FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+
+BRANCH ?= "master"
+REPO ?= "git://github.com/Xilinx/vdu-modules.git;protocol=https"
+SRCREV ?= "25773344ce1e539e7136c5a30cdee98a6cf490a8"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = "${REPO};${BRANCHARG} \
+    file://99-vdu-enc-dec.rules \
+"
+
+inherit module features_check
+
+REQUIRED_MACHINE_FEATURES = "vdu"
+
+EXTRA_OEMAKE += "O=${STAGING_KERNEL_BUILDDIR}"
+
+RDEPENDS:${PN} = "vdu-firmware"
+
+do_install:append() {
+    install -d ${D}${sysconfdir}/udev/rules.d
+    install -m 0644 ${WORKDIR}/99-vdu-enc-dec.rules ${D}${sysconfdir}/udev/rules.d/
+}
+
+FILES:${PN} = "${sysconfdir}/udev/rules.d/*"
diff --git a/meta-xilinx-multimedia/recipes-multimedia/vdu/libvdu-omxil_1.1.2-xilinx-v2024.2.bb b/meta-xilinx-multimedia/recipes-multimedia/vdu/libvdu-omxil_1.1.2-xilinx-v2024.2.bb
new file mode 100644
index 00000000..c2a93ce8
--- /dev/null
+++ b/meta-xilinx-multimedia/recipes-multimedia/vdu/libvdu-omxil_1.1.2-xilinx-v2024.2.bb
@@ -0,0 +1,49 @@
+SUMMARY = "OpenMAX Integration layer for VDU"
+DESCRIPTION = "OMX IL Libraries,test application and headers for VDU"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=002a0a92906100955ea6ed02dcd2c2cd"
+
+PV .= "+git"
+
+BRANCH ?= "master"
+REPO   ?= "git://github.com/Xilinx/vdu-omx-il.git;protocol=https"
+SRCREV ?= "af9c6e8935799f4dcd579b0164dd05eb039b569d"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = "${REPO};${BRANCHARG}"
+
+S = "${WORKDIR}/git"
+B = "${WORKDIR}/git"
+
+inherit autotools features_check
+
+REQUIRED_MACHINE_FEATURES = "vdu"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+DEPENDS = "vdu-ctrlsw"
+RDEPENDS:${PN} = "libvdu-ctrlsw"
+
+EXTERNAL_INCLUDE="${STAGING_INCDIR}/vdu-ctrl-sw/include"
+
+do_compile[dirs] = "${S}"
+do_install[dirs] = "${S}"
+
+EXTRA_OEMAKE = " \
+    CC='${CC}' CXX='${CXX} ${CXXFLAGS}' \
+    EXTERNAL_INCLUDE='${EXTERNAL_INCLUDE}' \
+    INSTALL_PATH=${D}${bindir} \
+    INCLUDE_INST_PATH=${D}${includedir} \
+    "
+
+do_install:append() {
+    install -d ${D}${libdir}
+
+    oe_libinstall -C ${S}/bin/ -so libOMX.allegro.core ${D}/${libdir}/
+    oe_libinstall -C ${S}/bin/ -so libOMX.allegro.video_decoder ${D}/${libdir}/
+}
+
+# These libraries shouldn't get installed in world builds unless something
+# explicitly depends upon them.
+
+EXCLUDE_FROM_WORLD = "1"
diff --git a/meta-xilinx-multimedia/recipes-multimedia/vdu/vdu-ctrlsw_1.0.79-xilinx-v2024.2.bb b/meta-xilinx-multimedia/recipes-multimedia/vdu/vdu-ctrlsw_1.0.79-xilinx-v2024.2.bb
new file mode 100644
index 00000000..d29def6c
--- /dev/null
+++ b/meta-xilinx-multimedia/recipes-multimedia/vdu/vdu-ctrlsw_1.0.79-xilinx-v2024.2.bb
@@ -0,0 +1,50 @@
+SUMMARY = "Control Software for VDU"
+DESCRIPTION = "Control software libraries, test applications and headers provider for VDU deconder software API"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=002a0a92906100955ea6ed02dcd2c2cd"
+
+# Recipe has been renamed
+PROVIDES += "libvdu-ctrlsw"
+
+PV .= "+git"
+
+BRANCH ?= "master"
+REPO   ?= "git://github.com/Xilinx/vdu-ctrl-sw.git;protocol=https"
+SRCREV ?= "361a822a223dc430ca44641be148fe1cbc13dd10"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = "${REPO};${BRANCHARG}"
+
+S = "${WORKDIR}/git"
+B = "${S}"
+
+inherit autotools features_check
+
+REQUIRED_MACHINE_FEATURES = "vdu"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+RDEPENDS:${PN} = "kernel-module-vdu"
+RDEPENDS:libvdu-ctrlsw = "kernel-module-vdu"
+
+do_compile[dirs] = "${S}"
+do_install[dirs] = "${S}"
+
+EXTRA_OEMAKE = "CC='${CC}' CXX='${CXX} ${CXXFLAGS}'"
+EXTRA_OEMAKE +=" INSTALL_HDR_PATH=${D}${includedir}/vdu-ctrl-sw/include INSTALL_PATH=${D}${bindir}"
+
+do_install:append() {
+
+    oe_libinstall -C ${S}/bin/ -so liballegro_decode ${D}/${libdir}/
+}
+
+PACKAGES =+ "libvdu-ctrlsw"
+FILES:libvdu-ctrlsw += "${libdir}/liballegro*.so.*"
+
+# These libraries shouldn't get installed in world builds unless something
+# explicitly depends upon them.
+
+EXCLUDE_FROM_WORLD = "1"
+
+# Disable buildpaths QA check warnings.
+INSANE_SKIP:${PN} += "buildpaths"
diff --git a/meta-xilinx-multimedia/recipes-multimedia/vdu/vdu-firmware_20240216-xilinx-v2024.2.bb b/meta-xilinx-multimedia/recipes-multimedia/vdu/vdu-firmware_20240216-xilinx-v2024.2.bb
new file mode 100644
index 00000000..247524f8
--- /dev/null
+++ b/meta-xilinx-multimedia/recipes-multimedia/vdu/vdu-firmware_20240216-xilinx-v2024.2.bb
@@ -0,0 +1,38 @@
+SUMMARY = "Firmware for VDU"
+DESCRIPTION = "Firmware binaries provider for VDU"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=722a9d20bf58ac06585a6d91ee36e60e"
+
+PV .= "+git"
+
+S = "${WORKDIR}/git"
+B = "${S}"
+
+BRANCH ?= "master"
+REPO ?= "git://github.com/Xilinx/vdu-firmware.git;protocol=https"
+SRCREV ?= "724de80630edcb87d865d69f1a6c0dc61c3f9f12"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI   = "${REPO};${BRANCHARG}"
+
+inherit autotools features_check
+
+REQUIRED_MACHINE_FEATURES = "vdu"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+EXTRA_OEMAKE +="INSTALL_PATH=${D}/${nonarch_base_libdir}/firmware"
+
+do_compile[noexec] = "1"
+do_install[dirs] = "${S}"
+
+# Inhibit warnings about files being stripped
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INHIBIT_PACKAGE_STRIP = "1"
+FILES:${PN} = "${nonarch_base_libdir}/firmware/*"
+
+# These libraries shouldn't get installed in world builds unless something
+# explicitly depends upon them.
+EXCLUDE_FROM_WORLD = "1"
+
+INSANE_SKIP:${PN} = "ldflags"