vcu2: Move to new meta-xilinx-multimedia

Signed-off-by: Mark Hatle <mark.hatle@amd.com>

6 files changed, 218 insertions, 0 deletions

diff --git a/meta-xilinx-multimedia/recipes-multimedia/vcu2/files/99-vcu2-codec.rules b/meta-xilinx-multimedia/recipes-multimedia/vcu2/files/99-vcu2-codec.rules
new file mode 100644
index 00000000..54ae765d
--- /dev/null
+++ b/meta-xilinx-multimedia/recipes-multimedia/vcu2/files/99-vcu2-codec.rules
@@ -0,0 +1,4 @@
+# Allegro VCU2 Encode, Decoder module drivers
+SUBSYSTEM=="allegro_encode_class", KERNEL=="al_e2xx", MODE="0660", GROUP="video"
+SUBSYSTEM=="allegro_decode_class", KERNEL=="al_d3xx", MODE="0660", GROUP="video"
+
diff --git a/meta-xilinx-multimedia/recipes-multimedia/vcu2/kernel-module-vcu2_2024.1.bb b/meta-xilinx-multimedia/recipes-multimedia/vcu2/kernel-module-vcu2_2024.1.bb
new file mode 100644
index 00000000..c6ce6e11
--- /dev/null
+++ b/meta-xilinx-multimedia/recipes-multimedia/vcu2/kernel-module-vcu2_2024.1.bb
@@ -0,0 +1,36 @@
+SUMMARY = "Linux kernel module for Video Code Unit"
+DESCRIPTION = "Out-of-tree VCU decoder, encoder and common kernel modules provider for MPSoC EV devices"
+SECTION = "kernel/modules"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=eb723b61539feef013de476e68b5c50a"
+
+PV .= "+git"
+
+S = "${WORKDIR}/git"
+
+FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+
+BRANCH = "xlnx_rel_v2024.1"
+REPO = "git://github.com/Xilinx/vcu2-modules.git;protocol=https"
+SRCREV = "28a8d32f22224f8c344b1d73b2f9e30db228b4fc"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = " \
+    ${REPO};${BRANCHARG} \
+    file://99-vcu2-codec.rules \
+    "
+
+inherit module features_check
+
+REQUIRED_MACHINE_FEATURES = "vcu2"
+
+EXTRA_OEMAKE += "O=${STAGING_KERNEL_BUILDDIR} KDIR=${STAGING_KERNEL_BUILDDIR}"
+
+RDEPENDS:${PN} = "vcu2-firmware"
+
+do_install:append() {
+    install -d ${D}${sysconfdir}/udev/rules.d
+    install -m 0644 ${WORKDIR}/99-vcu2-codec.rules ${D}${sysconfdir}/udev/rules.d/
+}
+
+FILES:${PN} = "${sysconfdir}/udev/rules.d/*"
diff --git a/meta-xilinx-multimedia/recipes-multimedia/vcu2/libvcu2-ctrlsw_1.0.62-xilinx-v2024.1.bb b/meta-xilinx-multimedia/recipes-multimedia/vcu2/libvcu2-ctrlsw_1.0.62-xilinx-v2024.1.bb
new file mode 100644
index 00000000..343b72c9
--- /dev/null
+++ b/meta-xilinx-multimedia/recipes-multimedia/vcu2/libvcu2-ctrlsw_1.0.62-xilinx-v2024.1.bb
@@ -0,0 +1,43 @@
+SUMMARY = "VCU2 decoder/encoder API Includes"
+DESCRIPTION = "Include directory for VCU2 encoder/decoder software API"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=003bf8ee942bb6256905b58e9b1b19c2"
+
+PV .= "+git"
+
+BRANCH ?= "xlnx_rel_v2024.1"
+REPO   ?= "git://github.com/Xilinx/vcu2-ctrl-sw.git;protocol=https"
+SRCREV = "c696fa059781a7a21e8bbf7d9073ce5080155c8a"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = "${REPO};${BRANCHARG}"
+
+S  = "${WORKDIR}/git"
+
+inherit features_check
+
+REQUIRED_MACHINE_FEATURES = "vcu2"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+#RDEPENDS:${PN} = "kernel-module-vcu2"
+
+EXTRA_OEMAKE = "CC='${CC}' CXX='${CXX} ${CXXFLAGS}'"
+
+# skip compile (compiled as part of vcu2-app recipe)
+do_compile[noexec] = '1'
+
+do_install() {
+    install -d ${D}${includedir}/vcu2-ctrl-sw/
+    oe_runmake install_headers INSTALL_HDR_PATH=${D}${includedir}/vcu2-ctrl-sw/
+}
+
+FILES:${PN} = "usr/include/vcu2-ctrl-sw/*"
+
+# These libraries shouldn't get installed in world builds unless something
+# explicitly depends upon them.
+
+EXCLUDE_FROM_WORLD = "1"
+
+# Disable buildpaths QA check warnings.
+INSANE_SKIP:${PN} += "buildpaths"
diff --git a/meta-xilinx-multimedia/recipes-multimedia/vcu2/libvcu2-omxil_1.1.2-xilinx-v2024.1.bb b/meta-xilinx-multimedia/recipes-multimedia/vcu2/libvcu2-omxil_1.1.2-xilinx-v2024.1.bb
new file mode 100644
index 00000000..281044a7
--- /dev/null
+++ b/meta-xilinx-multimedia/recipes-multimedia/vcu2/libvcu2-omxil_1.1.2-xilinx-v2024.1.bb
@@ -0,0 +1,51 @@
+SUMMARY = "OpenMAX Integration layer for VCU2"
+DESCRIPTION = "OMX IL Libraries,test applications and headers for VCU2"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=002a0a92906100955ea6ed02dcd2c2cd"
+
+# Version from core/core_version.mk
+PV .= "+git"
+
+BRANCH ?= "xlnx_rel_v2024.1"
+REPO   ?= "git://github.com/Xilinx/vcu2-omx-il.git;protocol=https"
+SRCREV = "da9554a071f20d5376bb1e2ef8dfd4551efccf60"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = "${REPO};${BRANCHARG}"
+
+S  = "${WORKDIR}/git"
+
+inherit features_check
+
+REQUIRED_MACHINE_FEATURES = "vcu2"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+DEPENDS = "libvcu2-ctrlsw vcu2-app"
+RDEPENDS:${PN} = "vcu2-app"
+
+EXTERNAL_INCLUDE="${STAGING_INCDIR}/vcu2-ctrl-sw/"
+
+EXTRA_OEMAKE = " \
+    CC='${CC}' CXX='${CXX} ${CXXFLAGS}' \
+    EXTERNAL_INCLUDE='${EXTERNAL_INCLUDE}' \
+    "
+
+do_install() {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}/vcu2-omx-il
+
+    install -m 0644 ${S}/omx_header/*.h ${D}${includedir}/vcu2-omx-il
+
+    install -Dm 0755 ${S}/bin/omx_decoder.exe ${D}/${bindir}/omx_decoder
+    install -Dm 0755 ${S}/bin/omx_encoder.exe ${D}/${bindir}/omx_encoder
+
+    oe_libinstall -C ${S}/bin/ -so libOMX.allegro.core ${D}/${libdir}/
+    oe_libinstall -C ${S}/bin/ -so libOMX.allegro.video_decoder ${D}/${libdir}/
+    oe_libinstall -C ${S}/bin/ -so libOMX.allegro.video_encoder ${D}/${libdir}/
+}
+
+# These libraries shouldn't get installed in world builds unless something
+# explicitly depends upon them.
+
+EXCLUDE_FROM_WORLD = "1"
diff --git a/meta-xilinx-multimedia/recipes-multimedia/vcu2/vcu2-app_1.0.62-xilinx-v2024.1.bb b/meta-xilinx-multimedia/recipes-multimedia/vcu2/vcu2-app_1.0.62-xilinx-v2024.1.bb
new file mode 100644
index 00000000..8352da3d
--- /dev/null
+++ b/meta-xilinx-multimedia/recipes-multimedia/vcu2/vcu2-app_1.0.62-xilinx-v2024.1.bb
@@ -0,0 +1,45 @@
+SUMMARY = "VCU2 decoder/encoder API Includes"
+DESCRIPTION = "Include directory for VCU2 encoder/decoder software API"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=003bf8ee942bb6256905b58e9b1b19c2"
+
+PV .= "+git"
+
+BRANCH ?= "xlnx_rel_v2024.1"
+# vcu2-app has not been populated yet: get sources from vcu2-ctrlsw instead
+#REPO ?= "git://github.com/Xilinx/vcu2-app.git;protocol=https"
+#SRCREV = "59c6beb262f09f8e368826a39612844642777924"
+REPO   ?= "git://github.com/Xilinx/vcu2-ctrl-sw.git;protocol=https"
+SRCREV = "c696fa059781a7a21e8bbf7d9073ce5080155c8a"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = "${REPO};${BRANCHARG}"
+
+S  = "${WORKDIR}/git"
+
+inherit features_check
+
+REQUIRED_MACHINE_FEATURES = "vcu2"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+#RDEPENDS:${PN} = "kernel-module-vcu2"
+
+EXTRA_OEMAKE = "V=1 CC='${CC}' CXX='${CXX} ${CXXFLAGS}'"
+
+do_install() {
+    install -Dm 0755 ${S}/bin/AL_Encoder.exe ${D}/${bindir}/ctrlsw_encoder
+    install -Dm 0755 ${S}/bin/AL_Decoder.exe ${D}/${bindir}/ctrlsw_decoder
+    oe_libinstall -C ${S}/bin/ -so liballegro_decode ${D}/${libdir}/
+    oe_libinstall -C ${S}/bin/ -so liballegro_encode ${D}/${libdir}/
+    oe_libinstall -C ${S}/bin/ -so liballegro_app ${D}/${libdir}/
+    oe_libinstall -C ${S}/bin/ -so liballegro_conv_yuv ${D}/${libdir}/
+}
+
+# These libraries shouldn't get installed in world builds unless something
+# explicitly depends upon them.
+
+EXCLUDE_FROM_WORLD = "1"
+
+# Disable buildpaths QA check warnings.
+INSANE_SKIP:${PN} += "buildpaths"
diff --git a/meta-xilinx-multimedia/recipes-multimedia/vcu2/vcu2-firmware_20240329-xilinx-v2024.1.bb b/meta-xilinx-multimedia/recipes-multimedia/vcu2/vcu2-firmware_20240329-xilinx-v2024.1.bb
new file mode 100644
index 00000000..25029829
--- /dev/null
+++ b/meta-xilinx-multimedia/recipes-multimedia/vcu2/vcu2-firmware_20240329-xilinx-v2024.1.bb
@@ -0,0 +1,39 @@
+SUMMARY = "Firmware for VCU2"
+DESCRIPTION = "Firmware binaries provider for VCU2"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=323caf712b1e8006fbec07506fe71db0"
+
+PV .= "+git"
+
+S  = "${WORKDIR}/git"
+
+BRANCH ?="xlnx_rel_v2024.1"
+REPO ?= "git://github.com/Xilinx/vcu2-firmware.git;protocol=https"
+SRCREV = "79e8d90a22eb38de9dc9725bffda57a29bd75f10"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI   = "${REPO};${BRANCHARG}"
+
+inherit features_check
+
+REQUIRED_MACHINE_FEATURES = "vcu2"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+do_compile[noexec] = "1"
+
+do_install() {
+    install -Dm 0644 ${S}/decoder_firmware.bin ${D}${nonarch_base_libdir}/firmware/ald3xx.fw
+    install -Dm 0644 ${S}/encoder_firmware.bin ${D}${nonarch_base_libdir}/firmware/ale2xx.fw
+}
+
+# Inhibit warnings about files being stripped
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INHIBIT_PACKAGE_STRIP = "1"
+FILES:${PN} = "${nonarch_base_libdir}/firmware/*"
+
+# These libraries shouldn't get installed in world builds unless something
+# explicitly depends upon them.
+EXCLUDE_FROM_WORLD = "1"
+
+INSANE_SKIP:${PN} = "ldflags"