libvdu-omxil.bb: Add recipe to integrate vdu OMXIL layer

Add yocto recipe to integrate AllegroDVT2 OpenMax Integration Layer.  The
OpenMax APIs define a standardized media component interface to enable
developers and platform providers to integrate and communicate with multimedia
codecs implemented in hardware or software.

The OpenMAX IL layer is integrated on top of the VDU Control Software.

Signed-off-by: Sai Hari Chandana Kalluri <chandana.kalluri@xilinx.com>
Signed-off-by: Mark Hatle <mark.hatle@amd.com>

1 files changed, 53 insertions, 0 deletions

diff --git a/meta-xilinx-core/recipes-multimedia/vdu/libvdu-omxil.bb b/meta-xilinx-core/recipes-multimedia/vdu/libvdu-omxil.bb
new file mode 100755
index 00000000..d6e219eb
--- /dev/null
+++ b/meta-xilinx-core/recipes-multimedia/vdu/libvdu-omxil.bb
@@ -0,0 +1,53 @@
+SUMMARY = "OpenMAX Integration layer for VDU"
+DESCRIPTION = "OMX IL Libraries,test application and headers for VDU"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=c15ae83ba15c4ab3fa4eb2c22975258f"
+
+XILINX_VDU_VERSION = "1.0.0"
+PV = "${XILINX_VDU_VERSION}-xilinx-${XILINX_RELEASE_VERSION}+git${SRCPV}"
+
+BRANCH ?= "master"
+REPO   ?= "git://github.com/Xilinx/vdu-omx-il.git;protocol=https"
+SRCREV ?= "00f1256366ce367dec0bddb9725325a744a5c764"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = "${REPO};${BRANCHARG} \
+          "
+S  = "${WORKDIR}/git"
+
+inherit autotools features_check
+
+REQUIRED_MACHINE_FEATURES = "vdu"
+
+COMPATIBLE_MACHINE = "^$"
+COMPATIBLE_MACHINE:versal-ai-core = "versal-ai-core"
+COMPATIBLE_MACHINE:versal-ai-edge = "versal-ai-edge"
+
+PACKAGE_ARCH = "${SOC_FAMILY_ARCH}"
+
+DEPENDS = "libvdu-ctrlsw"
+RDEPENDS:${PN} = "kernel-module-vdu libvdu-ctrlsw"
+
+EXTERNAL_INCLUDE="${STAGING_INCDIR}/vdu-ctrl-sw/include"
+
+do_compile[dirs] = "${S}"
+do_install[dirs] = "${S}"
+
+EXTRA_OEMAKE = " \
+    CC='${CC}' CXX='${CXX} ${CXXFLAGS}' \
+    EXTERNAL_INCLUDE='${EXTERNAL_INCLUDE}' \
+    INSTALL_PATH=${D}${bindir} \
+    INCLUDE_INST_PATH=${D}${includedir} \
+    "
+
+do_install:append() {
+    install -d ${D}${libdir}
+
+    oe_libinstall -C ${S}/bin/ -so libOMX.allegro.core ${D}/${libdir}/
+    oe_libinstall -C ${S}/bin/ -so libOMX.allegro.video_decoder ${D}/${libdir}/
+}
+
+# These libraries shouldn't get installed in world builds unless something
+# explicitly depends upon them.
+
+EXCLUDE_FROM_WORLD = "1"