vdu: Enable VDU IP in yocto

Enable VDU IP in yocto.  Video Decode Unit (VDU) core is a Hard IP in Versal®
AI Edge and Versal® AI Core series. The VDU core has multiple instance decoder
cores (upto four cores) and are implemented as Hard IP in Versal® AI Edge and
Versal® AI Core series.  To enable this the following recipes are included:
- kernel-module-vdu
- vdu-firmware
- vdu-ctrlsw

Signed-off-by: Sai Hari Chandana Kalluri <chandana.kalluri@xilinx.com>
Signed-off-by: Mark Hatle <mark.hatle@amd.com>

3 files changed, 117 insertions, 0 deletions

diff --git a/meta-xilinx-core/recipes-multimedia/vdu/kernel-module-vdu.bb b/meta-xilinx-core/recipes-multimedia/vdu/kernel-module-vdu.bb
new file mode 100755
index 00000000..63dab807
--- /dev/null
+++ b/meta-xilinx-core/recipes-multimedia/vdu/kernel-module-vdu.bb
@@ -0,0 +1,31 @@
+SUMMARY = "Linux kernel module for Video Decode Unit"
+DESCRIPTION = "Out-of-tree VDU decoder common kernel modules"
+SECTION = "kernel/modules"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=eb723b61539feef013de476e68b5c50a"
+
+XILINX_VDU_VERSION = "1.0.0"
+PV = "${XILINX_VDU_VERSION}-xilinx-${XILINX_RELEASE_VERSION}+git${SRCPV}"
+
+S = "${WORKDIR}/git"
+
+BRANCH ?= "master"
+REPO ?= "git://github.com/Xilinx/vdu-modules.git;protocol=https"
+SRCREV ?= "a3284231bf46fd32d57d6be35c197eb297e722c8"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = "${REPO};${BRANCHARG}"
+
+inherit module features_check
+
+REQUIRED_MACHINE_FEATURES = "vdu"
+
+EXTRA_OEMAKE += "O=${STAGING_KERNEL_BUILDDIR}"
+
+RDEPENDS:${PN} = "vdu-firmware"
+
+COMPATIBLE_MACHINE = "^$"
+COMPATIBLE_MACHINE:versal-ai-core = "versal-ai-core"
+COMPATIBLE_MACHINE:versal-ai-edge = "versal-ai-edge"
+
+PACKAGE_ARCH = "${SOC_FAMILY_ARCH}"
diff --git a/meta-xilinx-core/recipes-multimedia/vdu/libvdu-ctrlsw.bb b/meta-xilinx-core/recipes-multimedia/vdu/libvdu-ctrlsw.bb
new file mode 100755
index 00000000..b2a5abc3
--- /dev/null
+++ b/meta-xilinx-core/recipes-multimedia/vdu/libvdu-ctrlsw.bb
@@ -0,0 +1,44 @@
+SUMMARY = "Control Software for VDU"
+DESCRIPTION = "Control software libraries, test applications and headers provider for VDU"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=c15ae83ba15c4ab3fa4eb2c22975258f"
+
+XILINX_VDU_VERSION = "1.0.0"
+PV = "${XILINX_VDU_VERSION}-xilinx-${XILINX_RELEASE_VERSION}+git${SRCPV}"
+
+inherit autotools features_check
+
+REQUIRED_MACHINE_FEATURES = "vdu"
+
+BRANCH ?= "master"
+REPO   ?= "git://github.com/Xilinx/vdu-ctrl-sw.git;protocol=https"
+SRCREV ?= "30977b11d7464a0472e7c8b7d55ed429daf110df"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = "${REPO};${BRANCHARG}"
+
+S  = "${WORKDIR}/git"
+
+COMPATIBLE_MACHINE = "^$"
+COMPATIBLE_MACHINE:versal-ai-core = "versal-ai-core"
+COMPATIBLE_MACHINE:versal-ai-edge = "versal-ai-edge"
+
+PACKAGE_ARCH = "${SOC_FAMILY_ARCH}"
+
+RDEPENDS:${PN} = "kernel-module-vdu"
+
+do_compile[dirs] = "${S}"
+do_install[dirs] = "${S}"
+
+EXTRA_OEMAKE = "CC='${CC}' CXX='${CXX} ${CXXFLAGS}'"
+EXTRA_OEMAKE +=" INSTALL_HDR_PATH=${D}${includedir}/vdu-ctrl-sw/include INSTALL_PATH=${D}${bindir}"
+
+do_install:append() {
+
+    oe_libinstall -C ${S}/bin/ -so liballegro_decode ${D}/${libdir}/
+}
+
+# These libraries shouldn't get installed in world builds unless something
+# explicitly depends upon them.
+
+EXCLUDE_FROM_WORLD = "1"
diff --git a/meta-xilinx-core/recipes-multimedia/vdu/vdu-firmware.bb b/meta-xilinx-core/recipes-multimedia/vdu/vdu-firmware.bb
new file mode 100755
index 00000000..91a324d9
--- /dev/null
+++ b/meta-xilinx-core/recipes-multimedia/vdu/vdu-firmware.bb
@@ -0,0 +1,42 @@
+SUMMARY = "Firmware for VDU"
+DESCRIPTION = "Firmware binaries provider for VDU"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=7ab4113b0b7ac6f3bd45429a8a6d5a58"
+
+XILINX_VDU_VERSION = "1.0.0"
+PV = "${XILINX_VDU_VERSION}-xilinx-${XILINX_RELEASE_VERSION}+git${SRCPV}"
+
+S  = "${WORKDIR}/git"
+
+inherit autotools features_check
+
+REQUIRED_MACHINE_FEATURES = "vdu"
+
+BRANCH ?= "master"
+REPO ?= "git://github.com/Xilinx/vdu-firmware.git;protocol=https"
+SRCREV ?= "3d2ae1d8d9404dc18c64a4358d38ca049011a316"
+
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI   = "${REPO};${BRANCHARG}"
+
+COMPATIBLE_MACHINE = "^$"
+COMPATIBLE_MACHINE:versal-ai-core = "versal-ai-core"
+COMPATIBLE_MACHINE:versal-ai-edge = "versal-ai-edge"
+
+PACKAGE_ARCH = "${SOC_FAMILY_ARCH}"
+EXTRA_OEMAKE +="INSTALL_PATH=${D}/lib/firmware"
+
+do_compile[noexec] = "1"
+do_install[dirs] = "${S}"
+
+# Inhibit warnings about files being stripped
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INHIBIT_PACKAGE_STRIP = "1"
+FILES:${PN} = "/lib/firmware/*"
+
+
+# These libraries shouldn't get installed in world builds unless something
+# explicitly depends upon them.
+EXCLUDE_FROM_WORLD = "1"
+
+INSANE_SKIP:${PN} = "ldflags"