Initial restructure/split of meta-xilinx-bsp

Create a new meta-xilinx-core, move core functionality to the core, keeping
board specific files in the bsp layer.

zynqmp-generic changed from require <board> to include, so if meta-xilinx-bsp
is not available it will not fail.

Signed-off-by: Mark Hatle <mark.hatle@xilinx.com>

3 files changed, 81 insertions, 0 deletions

diff --git a/meta-xilinx-core/recipes-xrt/xrt/xrt.inc b/meta-xilinx-core/recipes-xrt/xrt/xrt.inc
new file mode 100644
index 00000000..bcf869d8
--- /dev/null
+++ b/meta-xilinx-core/recipes-xrt/xrt/xrt.inc
@@ -0,0 +1,10 @@
+REPO ?= "git://github.com/Xilinx/XRT.git;protocol=https"
+BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
+SRC_URI = "${REPO};${BRANCHARG}"
+
+BRANCH= "master"
+SRCREV= "5e14f7c0e07cd0ae895b424a1a3f0a8e58b5523b"
+PV = "202120.2.13.0"
+
+
+
diff --git a/meta-xilinx-core/recipes-xrt/xrt/xrt_git.bb b/meta-xilinx-core/recipes-xrt/xrt/xrt_git.bb
new file mode 100644
index 00000000..0d0d71aa
--- /dev/null
+++ b/meta-xilinx-core/recipes-xrt/xrt/xrt_git.bb
@@ -0,0 +1,51 @@
+SUMMARY  = "Xilinx Runtime(XRT) libraries"
+DESCRIPTION = "Xilinx Runtime User Space Libraries and headers"
+
+require xrt.inc
+
+LICENSE = "GPLv2 & Apache-2.0"
+LIC_FILES_CHKSUM = "file://../LICENSE;md5=da5408f748bce8a9851dac18e66f4bcf \
+                    file://runtime_src/core/edge/drm/zocl/LICENSE;md5=7d040f51aae6ac6208de74e88a3795f8 \
+                    file://runtime_src/core/pcie/driver/linux/xocl/LICENSE;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+                    file://runtime_src/core/pcie/linux/LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57 \
+                    file://runtime_src/core/pcie/tools/xbutil/LICENSE;md5=d273d63619c9aeaf15cdaf76422c4f87 \
+                    file://runtime_src/core/edge/tools/xbutil/LICENSE;md5=d273d63619c9aeaf15cdaf76422c4f87 "
+
+S = "${WORKDIR}/git/src"
+
+inherit cmake
+
+BBCLASSEXTEND = "native nativesdk"
+
+# util-linux is for libuuid-dev.
+DEPENDS = "libdrm opencl-headers ocl-icd opencl-clhpp boost util-linux git-replacement-native protobuf-native protobuf elfutils libffi"
+#RDEPENDS:${PN} = "bash ocl-icd boost-system boost-filesystem zocl"
+RDEPENDS:${PN} = "bash ocl-icd boost-system boost-filesystem"
+
+EXTRA_OECMAKE += " \
+                -DCMAKE_BUILD_TYPE=Release \
+                -DCMAKE_EXPORT_COMPILE_COMANDS=ON \
+                "
+
+PACKAGE_ARCH:versal-ai-core = "${SOC_VARIANT_ARCH}"
+EXTRA_OECMAKE:append:versal-ai-core += "-DXRT_AIE_BUILD=true"
+TARGET_CXXFLAGS:append:versal-ai-core += "-DXRT_ENABLE_AIE"
+DEPENDS:append:versal-ai-core += " libmetal libxaiengine aiefal"
+RDEPENDS:${PN}:append:versal-ai-core += " libxaiengine aiefal"
+
+FILES_SOLIBSDEV = ""
+FILES:${PN} += "\
+    ${libdir}/lib*.so \
+    ${libdir}/lib*.so.* \
+    /lib/*.so* "
+INSANE_SKIP:${PN} += "dev-so"
+
+pkg_postinst_ontarget:${PN}() {
+  #!/bin/sh
+  if [ ! -e /etc/OpenCL/vendors/xilinx.icd ]; then
+        echo "INFO: Creating ICD entry for Xilinx Platform"
+        mkdir -p /etc/OpenCL/vendors
+        echo "libxilinxopencl.so" > /etc/OpenCL/vendors/xilinx.icd
+        chmod -R 755 /etc/OpenCL
+  fi
+}
diff --git a/meta-xilinx-core/recipes-xrt/zocl/zocl_git.bb b/meta-xilinx-core/recipes-xrt/zocl/zocl_git.bb
new file mode 100644
index 00000000..40578aa2
--- /dev/null
+++ b/meta-xilinx-core/recipes-xrt/zocl/zocl_git.bb
@@ -0,0 +1,20 @@
+SUMMARY  = "Xilinx Runtime(XRT) driver module"
+DESCRIPTION = "Xilinx Runtime driver module provides memory management and compute unit schedule"
+
+
+require recipes-xrt/xrt/xrt.inc
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=7d040f51aae6ac6208de74e88a3795f8"
+LICENSE = "GPLv2 & Apache-2.0"
+
+S = "${WORKDIR}/git/src/runtime_src/core/edge/drm/zocl"
+
+inherit module
+
+pkg_postinst_ontarget:${PN}() {
+  #!/bin/sh
+  echo "Unloading old XRT Linux kernel modules"
+  ( rmmod zocl || true ) > /dev/null 2>&1
+  echo "Loading new XRT Linux kernel modules"
+  modprobe zocl
+}