qemu: Bump to lastest master (2024.2) versions

Signed-off-by: Mark Hatle <mark.hatle@amd.com>
(cherry picked from commit 16b37ceac501e1cba75a9c25d2f4960e9773ab4b)
Signed-off-by: Mark Hatle <mark.hatle@amd.com>

5 files changed, 88 insertions, 1 deletions

diff --git a/meta-xilinx-core/recipes-devtools/qemu/qemu-devicetrees_2024.1.bb b/meta-xilinx-core/recipes-devtools/qemu/qemu-devicetrees_2024.2.bb
index d10504d3..2907bbf1 100644
--- a/meta-xilinx-core/recipes-devtools/qemu/qemu-devicetrees_2024.1.bb
+++ b/meta-xilinx-core/recipes-devtools/qemu/qemu-devicetrees_2024.2.bb
@@ -1,6 +1,6 @@
 
 require qemu-devicetrees.inc
 
-BRANCH ?= "xlnx_rel_v2024.1"
+BRANCH ?= "master"
 SRCREV ?= "b9c88cbfaaa0c8b8be70ea3c74f4cb69fb02a080"
 
diff --git a/meta-xilinx-core/recipes-devtools/qemu/qemu-xilinx-2024.2.inc b/meta-xilinx-core/recipes-devtools/qemu/qemu-xilinx-2024.2.inc
new file mode 100644
index 00000000..a528ea93
--- /dev/null
+++ b/meta-xilinx-core/recipes-devtools/qemu/qemu-xilinx-2024.2.inc
@@ -0,0 +1,3 @@
+XILINX_QEMU_VERSION = "v8.1.0"
+BRANCH = "master"
+SRCREV = "c0e84b2d5c225f5437954f78f44ac6d3200436d4"
diff --git a/meta-xilinx-core/recipes-devtools/qemu/qemu-xilinx-native_2024.2.bb b/meta-xilinx-core/recipes-devtools/qemu/qemu-xilinx-native_2024.2.bb
new file mode 100644
index 00000000..5d780dad
--- /dev/null
+++ b/meta-xilinx-core/recipes-devtools/qemu/qemu-xilinx-native_2024.2.bb
@@ -0,0 +1,11 @@
+BPN = "qemu-xilinx"
+
+DEPENDS += "glib-2.0-native zlib-native"
+
+require qemu-xilinx-2024.2.inc
+require qemu-xilinx-native-8.1.inc
+require qemu-native-alt.inc
+
+EXTRA_OECONF:append = " --target-list=${@get_qemu_usermode_target_list(d)} --disable-tools --disable-install-blobs --disable-guest-agent"
+
+PACKAGECONFIG ??= "pie"
diff --git a/meta-xilinx-core/recipes-devtools/qemu/qemu-xilinx-system-native_2024.2.bb b/meta-xilinx-core/recipes-devtools/qemu/qemu-xilinx-system-native_2024.2.bb
new file mode 100644
index 00000000..42e2462c
--- /dev/null
+++ b/meta-xilinx-core/recipes-devtools/qemu/qemu-xilinx-system-native_2024.2.bb
@@ -0,0 +1,35 @@
+BPN = "qemu-xilinx"
+
+require qemu-system-native-alt.inc
+require qemu-xilinx-2024.2.inc
+require qemu-xilinx-native-8.1.inc
+
+# As some of the files installed by qemu-native and qemu-system-native
+# are the same, we depend on qemu-native to get the full installation set
+# and avoid file clashes
+DEPENDS += "glib-2.0-native zlib-native pixman-native qemu-native"
+
+DEPENDS += "qemu-xilinx-multiarch-helper-native"
+
+EXTRA_OECONF:append = " --target-list=${@get_qemu_system_target_list(d)}"
+
+PACKAGECONFIG ??= "fdt alsa kvm pie slirp png gcrypt \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'virglrenderer epoxy', '', d)} \
+"
+
+# Handle distros such as CentOS 5 32-bit that do not have kvm support
+PACKAGECONFIG:remove = "${@'kvm' if not os.path.exists('/usr/include/linux/kvm.h') else ''}"
+
+do_install:append() {
+    install -Dm 0755 ${WORKDIR}/powerpc_rom.bin ${D}${datadir}/qemu-xilinx
+
+    # The following is also installed by qemu-native
+    rm -f ${D}${datadir}/qemu-xilinx/trace-events-all
+    rm -rf ${D}${datadir}/qemu-xilinx/keymaps
+    rm -rf ${D}${datadir}/icons/
+    rm -rf ${D}${includedir}/qemu-plugin.h
+
+    # Install qmp.py to be used with testimage
+    install -d ${D}${libdir}/qemu-python/qmp/
+    install -D ${S}/python/qemu/qmp/* ${D}${libdir}/qemu-python/qmp/
+}
diff --git a/meta-xilinx-core/recipes-devtools/qemu/qemu-xilinx_2024.2.bb b/meta-xilinx-core/recipes-devtools/qemu/qemu-xilinx_2024.2.bb
new file mode 100644
index 00000000..78e5415e
--- /dev/null
+++ b/meta-xilinx-core/recipes-devtools/qemu/qemu-xilinx_2024.2.bb
@@ -0,0 +1,38 @@
+BBCLASSEXTEND = "nativesdk"
+
+require qemu-xilinx-2024.2.inc
+require qemu-8.1.inc
+require qemu-xilinx-8.1.inc
+require qemu-alt.inc
+
+# Links to libmali-xlnx, so it becomes MACHINE_ARCH specific
+DEFAULT_PACKAGE_ARCH := "${PACKAGE_ARCH}"
+MALI_PACKAGE_ARCH[vardepsexclude] = "MACHINE_ARCH"
+MALI_PACKAGE_ARCH = "${@'${MACHINE_ARCH}' if d.getVar('PREFERRED_PROVIDER_virtual/libgles1') == 'libmali-xlnx' else '${DEFAULT_PACKAGE_ARCH}'}"
+PACKAGE_ARCH[vardepsexclude] = "MALI_PACKAGE_ARCH"
+PACKAGE_ARCH:class-target = "${@bb.utils.contains_any('DEPENDS', 'libepoxy virglrenderer', '${MALI_PACKAGE_ARCH}', '${DEFAULT_PACKAGE_ARCH}', d)}"
+
+
+DEPENDS = "glib-2.0 zlib pixman bison-native ninja-native meson-native"
+
+DEPENDS:append:libc-musl = " libucontext"
+
+CFLAGS += "${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', '-DEGL_NO_X11=1', d)}"
+
+RDEPENDS:${PN}-common:class-target += "bash"
+
+EXTRA_OECONF:append:class-target = " --target-list=${@get_qemu_target_list(d)}"
+EXTRA_OECONF:append:class-target:mipsarcho32 = "${@bb.utils.contains('BBEXTENDCURR', 'multilib', ' --disable-capstone', '', d)}"
+EXTRA_OECONF:append:class-nativesdk = " --target-list=${@get_qemu_target_list(d)}"
+
+PACKAGECONFIG ??= " \
+    fdt sdl kvm pie slirp gcrypt \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'alsa pulseaudio xen', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'virglrenderer epoxy', '', d)} \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'seccomp', d)} \
+"
+PACKAGECONFIG:class-nativesdk ??= "fdt sdl kvm pie slirp gcrypt \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'virglrenderer epoxy', '', d)} \
+"
+# ppc32 hosts are no longer supported in qemu
+COMPATIBLE_HOST:powerpc = "null"