embeddedsw: Rework the embeddedsw copy firmware recipes

fsbl, plmfw, pufw, and psmfw are reworked to provide earlier error messages,
and better handle multiconfig builds.

Also adjust MACHINE specific changes to use .* for compatibility based on the
SOC_FAMILY override.  The system doesn't always set the SOC_FAMILY as
COMPATIBLE_MACHINE, so this avoids an error of incompatible machine.

Align all of the expected firmware filenames to be <firmware>-${MACHINE}.
The user can override as necessary.

The license moves to CLOSED as we don't know the license of the software being
provided by the user or other dependencies.  It'll be up to the user to
reconcile it.

Signed-off-by: Mark Hatle <mark.hatle@xilinx.com>

4 files changed, 152 insertions, 40 deletions

diff --git a/meta-xilinx-core/recipes-bsp/embeddedsw/fsbl.bb b/meta-xilinx-core/recipes-bsp/embeddedsw/fsbl.bb
index ae2123e7..f8679f0e 100644
--- a/meta-xilinx-core/recipes-bsp/embeddedsw/fsbl.bb
+++ b/meta-xilinx-core/recipes-bsp/embeddedsw/fsbl.bb
@@ -1,6 +1,6 @@
 DESCRIPTION = "Xilinx First Stage Boot Loader"
 
-LICENSE = "MIT"
+LICENSE = "CLOSED"
 
 PROVIDES = "virtual/fsbl"
 
@@ -10,19 +10,21 @@ COMPATIBLE_MACHINE = "^$"
 COMPATIBLE_MACHINE:zynq = "zynq"
 COMPATIBLE_MACHINE:zynqmp = "zynqmp"
 
+# Since we're just copying, we can run any config
+COMPATIBLE_HOST = ".*"
+
 PACKAGE_ARCH = "${MACHINE_ARCH}"
 
-# Default would be a multiconfig (versal) build
-# For this to work, BBMULTICONFIG += "fsbl-fw" must be in the user's local.conf!
+# Default expects the user to provide the fsbl in the deploy
+# directory, named "fsbl.elf"
+# A machine, multiconfig, or local.conf should override this
 FSBL_DEPENDS ??= ""
-FSBL_MCDEPENDS ??= "mc::fsbl-fw:fsbl-firmware:do_deploy"
-
-# This must be defined to the file output by whatever is providing the fsbl-firmware
-# The following sets the default, but the BSP may select a different name
-FSBL_IMAGE_NAME ??= "fsbl"
-FSBL_DEPLOY_DIR ??= "${TOPDIR}/tmp-fsbl-fw/deploy/images/${MACHINE}"
+FSBL_MCDEPENDS ??= ""
+FSBL_DEPLOY_DIR ??= "${DEPLOY_DIR_IMAGE}"
+FSBL_DEPLOY_DIR[vardepsexclude] += "TOPDIR"
+FSBL_IMAGE_NAME ??= "fsbl-${MACHINE}"
 
-# Default is for the multilib case (without the extension .elf/.bin)
+# Default is for the multilib case (without the extension .elf)
 FSBL_FILE ??= "${FSBL_DEPLOY_DIR}/${FSBL_IMAGE_NAME}"
 FSBL_FILE[vardepsexclude] = "FSBL_DEPLOY_DIR"
 
@@ -56,3 +58,22 @@ INSANE_SKIP:${PN}-dbg = "arch"
 
 SYSROOT_DIRS += "/boot"
 FILES:${PN} = "/boot/${PN}.elf"
+
+def check_fsbl_variables(d):
+    # If both are blank, the user MUST pass in the path to the firmware!
+    if not d.getVar('FSBL_DEPENDS') and not d.getVar('FSBL_MCDEPENDS'):
+        # Don't cache this, as the items on disk can change!
+        d.setVar('BB_DONT_CACHE', '1')
+
+        if not os.path.exists(d.getVar('FSBL_FILE') + ".elf"):
+            raise bb.parse.SkipRecipe("The expect file %s.elf is not available.\nSet FSBL_FILE to the path with a precompiled FSBL binary. See the meta-xilinx-core README for more information." % d.getVar('FSBL_FILE'))
+        else:
+            # We found the file, so be sure to track it
+            d.setVar('SRC_URI', 'file://${FSBL_FILE}.elf')
+            d.setVarFlag('do_install', 'file-checksums', '${FSBL_FILE}.elf:True')
+            d.setVarFlag('do_deploy', 'file-checksums', '${FSBL_FILE}.elf:True')
+
+python() {
+    # Need to allow bbappends to change the check
+    check_fsbl_variables(d)
+}
diff --git a/meta-xilinx-core/recipes-bsp/embeddedsw/plmfw.bb b/meta-xilinx-core/recipes-bsp/embeddedsw/plmfw.bb
index 6a2a5172..0306ef46 100644
--- a/meta-xilinx-core/recipes-bsp/embeddedsw/plmfw.bb
+++ b/meta-xilinx-core/recipes-bsp/embeddedsw/plmfw.bb
@@ -1,26 +1,28 @@
 DESCRIPTION = "Platform Loader and Manager"
 SUMMARY = "Platform Loader and Manager for Versal devices"
 
-LICENSE = "MIT"
+LICENSE = "CLOSED"
 
 PROVIDES = "virtual/plm"
 
 INHERIT_DEFAULT_DEPENDS = "1"
 
 COMPATIBLE_MACHINE = "^$"
-COMPATIBLE_MACHINE:versal = "versal"
+COMPATIBLE_MACHINE:versal = ".*"
+
+# Since we're just copying, we can run any config
+COMPATIBLE_HOST = ".*"
 
 PACKAGE_ARCH = "${MACHINE_ARCH}"
 
-# Default would be a multiconfig (versal) build
-# For this to work, BBMULTICONFIG += "versal-fw" must be in the user's local.conf!
+# Default expects the user to provide the plm-firmware in the deploy
+# directory, named "plm-${MACHINE}.elf" and "plm-${MACHINE}.bin"
+# A machine, multiconfig, or local.conf should override this
 PLM_DEPENDS ??= ""
-PLM_MCDEPENDS ??= "mc::versal-fw:plm-firmware:do_deploy"
-
-# This must be defined to the file output by whatever is providing the plm-firmware
-# The following sets the default, but the BSP may select a different name
-PLM_IMAGE_NAME ??= "plm-versal-mb"
-PLM_DEPLOY_DIR ??= "${TOPDIR}/tmp-microblaze-versal-fw/deploy/images/${MACHINE}"
+PLM_MCDEPENDS ??= ""
+PLM_DEPLOY_DIR ??= "${DEPLOY_DIR_IMAGE}"
+PLM_DEPLOY_DIR[vardepsexclude] += "TOPDIR"
+PLM_IMAGE_NAME ??= "plm-${MACHINE}"
 
 # Default is for the multilib case (without the extension .elf/.bin)
 PLM_FILE ??= "${PLM_DEPLOY_DIR}/${PLM_IMAGE_NAME}"
@@ -57,3 +59,31 @@ INSANE_SKIP:${PN}-dbg = "arch"
 
 SYSROOT_DIRS += "/boot"
 FILES:${PN} = "/boot/${PN}.elf"
+
+def check_plm_vars(d):
+    # If both are blank, the user MUST pass in the path to the firmware!
+    if not d.getVar('PLM_DEPENDS') and not d.getVar('PLM_MCDEPENDS'):
+        # Don't cache this, as the items on disk can change!
+        d.setVar('BB_DONT_CACHE', '1')
+
+        msg = ""
+        fail = False
+        if not os.path.exists(d.getVar('PLM_FILE') + ".elf"):
+            msg = msg + "The expected file %s.elf is not available.  " % d.getVar('PLM_FILE')
+            fail = True
+        if not os.path.exists(d.getVar('PLM_FILE') + ".bin"):
+            msg = msg + "The expected file %s.bin is not available.  " % d.getVar('PLM_FILE')
+            fail = True
+        if fail:
+            raise bb.parse.SkipRecipe("%s\nSee the meta-xilinx-core README." % msg)
+        else:
+            # We found the file, so be sure to track it
+            d.setVar('SRC_URI', 'file://${PLM_FILE}.elf file://${PLM_FILE}.bin')
+            d.setVarFlag('do_install', 'file-checksums', '${PLM_FILE}.elf:True')
+            d.setVarFlag('do_deploy', 'file-checksums', '${PLM_FILE}.elf:True ${PLM_FILE}.bin:True')
+
+python() {
+    # Need to allow bbappends to change the check
+    check_plm_vars(d)
+}
+
diff --git a/meta-xilinx-core/recipes-bsp/embeddedsw/pmufw.bb b/meta-xilinx-core/recipes-bsp/embeddedsw/pmufw.bb
index ea0eb5a6..b3f9664e 100644
--- a/meta-xilinx-core/recipes-bsp/embeddedsw/pmufw.bb
+++ b/meta-xilinx-core/recipes-bsp/embeddedsw/pmufw.bb
@@ -1,25 +1,27 @@
 DESCRIPTION = "PMU Firmware"
 
-LICENSE = "MIT"
+LICENSE = "CLOSED"
 
 PROVIDES = "virtual/pmu-firmware"
 
 INHERIT_DEFAULT_DEPENDS = "1"
 
 COMPATIBLE_MACHINE = "^$"
-COMPATIBLE_MACHINE:zynqmp = "zynqmp"
+COMPATIBLE_MACHINE:zynqmp = ".*"
+
+# Since we're just copying, we can run any config
+COMPATIBLE_HOST = ".*"
 
 PACKAGE_ARCH = "${MACHINE_ARCH}"
 
-# Default would be a multiconfig (zynqmp-pmufw) build
-# For this to work, BBMULTICONFIG += "zynqmp-pmufw" must be in the user's local.conf!
+# Default expects the user to provide the pmu-firmware in the deploy
+# directory, named "pmu-firmware-${MACHINE}.elf" and "pmu-firmware-${MACHINE}.bin"
+# A machine, multiconfig, or local.conf should override this
 PMU_DEPENDS ??= ""
-PMU_MCDEPENDS ??= "mc::zynqmp-pmufw:pmu-firmware:do_deploy"
-
-# This must be defined to the file output by whatever is providing the pmu-firmware
-# The following sets the default, but the BSP may select a different name
-PMU_FIRMWARE_IMAGE_NAME ??= "pmu-firmware-zynqmp-pmu"
-PMU_FIRMWARE_DEPLOY_DIR ??= "${TOPDIR}/tmp-microblaze-zynqmp-pmufw/deploy/images/${MACHINE}"
+PMU_MCDEPENDS ??= ""
+PMU_FIRMWARE_DEPLOY_DIR ??= "${DEPLOY_DIR_IMAGE}"
+PMU_FIRMWARE_DEPLOY_DIR[vardepsexclude] += "TOPDIR"
+PMU_FIRMWARE_IMAGE_NAME ??= "pmu-firmware-${MACHINE}"
 
 # Default is for the multilib case (without the extension .elf/.bin)
 PMU_FILE ??= "${PMU_FIRMWARE_DEPLOY_DIR}/${PMU_FIRMWARE_IMAGE_NAME}"
@@ -55,3 +57,31 @@ INSANE_SKIP:${PN}-dbg = "arch"
 
 SYSROOT_DIRS += "/boot"
 FILES:${PN} = "/boot/${PN}.elf"
+
+def check_pmu_vars(d):
+    # If both are blank, the user MUST pass in the path to the firmware!
+    if not d.getVar('PMU_FIRMWARE_DEPENDS') and not d.getVar('PMU_FIRMWARE_MCDEPENDS'):
+        # Don't cache this, as the items on disk can change!
+        d.setVar('BB_DONT_CACHE', '1')
+
+        msg = ""
+        fail = False
+        if not os.path.exists(d.getVar('PMU_FILE') + ".elf"):
+            msg = msg + "The expected file %s.elf is not available.  " % d.getVar('PMU_FILE')
+            fail = True
+        if not os.path.exists(d.getVar('PMU_FILE') + ".bin"):
+            msg = msg + "The expected file %s.bin is not available.  " % d.getVar('PMU_FILE')
+            fail = True
+        if fail:
+            raise bb.parse.SkipRecipe("%s  See the meta-xilinx-core README." % msg)
+        else:
+            # We found the file, so be sure to track it
+            d.setVar('SRC_URI', 'file://${PMU_FILE}.elf file://${PMU_FILE}.bin')
+            d.setVarFlag('do_install', 'file-checksums', '${PMU_FILE}.elf:True')
+            d.setVarFlag('do_deploy', 'file-checksums', '${PMU_FILE}.elf:True ${PMU_FILE}.bin:True')
+
+
+python() {
+    # Need to allow bbappends to change the check
+    check_pmu_vars(d)
+}
diff --git a/meta-xilinx-core/recipes-bsp/embeddedsw/psmfw.bb b/meta-xilinx-core/recipes-bsp/embeddedsw/psmfw.bb
index 89a9e93f..46124591 100644
--- a/meta-xilinx-core/recipes-bsp/embeddedsw/psmfw.bb
+++ b/meta-xilinx-core/recipes-bsp/embeddedsw/psmfw.bb
@@ -1,26 +1,28 @@
 DESCRIPTION = "PSM Firmware"
 SUMMARY = "PSM firmware for versal devices"
 
-LICENSE = "MIT"
+LICENSE = "CLOSED"
 
 PROVIDES = "virtual/psm-firmware"
 
 INHERIT_DEFAULT_DEPENDS = "1"
 
 COMPATIBLE_MACHINE = "^$"
-COMPATIBLE_MACHINE:versal = "versal"
+COMPATIBLE_MACHINE:versal = ".*"
+
+# Since we're just copying, we can run any config
+COMPATIBLE_HOST = ".*"
 
 PACKAGE_ARCH = "${MACHINE_ARCH}"
 
-# Default would be a multiconfig (versal) build
-# For this to work, BBMULTICONFIG += "versal-fw" must be in the user's local.conf!
+# Default expects the user to provide the psm-firmware in the deploy
+# directory, named "psm-firmware-${MACHINE}.elf" and "psm-firmware-${MACHINE}.bin"
+# A machine, multiconfig, or local.conf should override this
 PSM_DEPENDS ??= ""
-PSM_MCDEPENDS ??= "mc::versal-fw:psm-firmware:do_deploy"
-
-# This must be defined to the file output by whatever is providing the psm-firmware
-# The following sets the default, but the BSP may select a different name
-PSM_FIRMWARE_IMAGE_NAME ??= "psm-firmware-versal-mb"
-PSM_FIRMWARE_DEPLOY_DIR ??= "${TOPDIR}/tmp-microblaze-versal-fw/deploy/images/${MACHINE}"
+PSM_MCDEPENDS ??= ""
+PSM_DEPLOY_DIR ??= "${DEPLOY_DIR_IMAGE}"
+PSM_FIRMWARE_DEPLOY_DIR[vardepsexclude] += "TOPDIR"
+PSM_FIRMWARE_IMAGE_NAME ??= "psm-firmware-${MACHINE}"
 
 # Default is for the multilib case (without the extension .elf/.bin)
 PSM_FILE ??= "${PSM_FIRMWARE_DEPLOY_DIR}/${PSM_FIRMWARE_IMAGE_NAME}"
@@ -57,3 +59,32 @@ INSANE_SKIP:${PN}-dbg = "arch"
 
 SYSROOT_DIRS += "/boot"
 FILES:${PN} = "/boot/${PN}.elf"
+
+def check_psm_vars(d):
+    # If both are blank, the user MUST pass in the path to the firmware!
+    if not d.getVar('PSM_DEPENDS') and not d.getVar('PSM_MCDEPENDS'):
+        # Don't cache this, as the items on disk can change!
+        d.setVar('BB_DONT_CACHE', '1')
+
+        msg = ""
+        fail = False
+        if not os.path.exists(d.getVar('PSM_FILE') + ".elf"):
+            msg = msg + "The expected file %s.elf is not available.  " % d.getVar('PSM_FILE')
+            fail = True
+        if not os.path.exists(d.getVar('PSM_FILE') + ".bin"):
+            msg = msg + "The expected file %s.bin is not available.  " % d.getVar('PSM_FILE')
+            fail = True
+
+        if fail:
+            raise bb.parse.SkipRecipe("%s\nSee the meta-xilinx-core README." % msg)
+        else:
+            # We found the file, so be sure to track it
+            d.setVar('SRC_URI', 'file://${PSM_FILE}.elf file://${PSM_FILE}.bin')
+            d.setVarFlag('do_install', 'file-checksums', '${PSM_FILE}.elf:True')
+            d.setVarFlag('do_deploy', 'file-checksums', '${PSM_FILE}.elf:True ${PSM_FILE}.bin:True')
+
+python() {
+    # Need to allow bbappends to change the check
+    check_psm_vars(d)
+}
+