open-amp-device-tree: Add a DTBO generating recipe for OpenAMP

The recipe will generate a DTBO for OpenAMP

Signed-off-by: Mark Hatle <mark.hatle@amd.com>

4 files changed, 90 insertions, 0 deletions

diff --git a/meta-xilinx-core/dynamic-layers/openamp-layer/recipes-bsp/device-tree/files/versal-openamp-overlay.dts b/meta-xilinx-core/dynamic-layers/openamp-layer/recipes-bsp/device-tree/files/versal-openamp-overlay.dts
new file mode 100644
index 00000000..80ed4639
--- /dev/null
+++ b/meta-xilinx-core/dynamic-layers/openamp-layer/recipes-bsp/device-tree/files/versal-openamp-overlay.dts
@@ -0,0 +1,13 @@
+/*
+ * SPDX-License-Identifier: MIT
+ *
+ * dts overlay file for Versal OpenAMP
+ *
+ * Copyright (C) 2022, Advanced Micro Devices, Inc.  All rights reserved.
+ *
+ */
+
+/dts-v1/;
+/plugin/;
+
+#include "versal-openamp.dtsi"
diff --git a/meta-xilinx-core/dynamic-layers/openamp-layer/recipes-bsp/device-tree/files/zynq-openamp-overlay.dts b/meta-xilinx-core/dynamic-layers/openamp-layer/recipes-bsp/device-tree/files/zynq-openamp-overlay.dts
new file mode 100644
index 00000000..b5d238ff
--- /dev/null
+++ b/meta-xilinx-core/dynamic-layers/openamp-layer/recipes-bsp/device-tree/files/zynq-openamp-overlay.dts
@@ -0,0 +1,13 @@
+/*
+ * SPDX-License-Identifier: MIT
+ *
+ * dts overlay file for Zynq OpenAMP
+ *
+ * Copyright (C) 2022, Advanced Micro Devices, Inc.  All rights reserved.
+ *
+ */
+
+/dts-v1/;
+/plugin/;
+
+#include "zynq-openamp.dtsi"
diff --git a/meta-xilinx-core/dynamic-layers/openamp-layer/recipes-bsp/device-tree/files/zynqmp-openamp-overlay.dts b/meta-xilinx-core/dynamic-layers/openamp-layer/recipes-bsp/device-tree/files/zynqmp-openamp-overlay.dts
new file mode 100644
index 00000000..da1d171e
--- /dev/null
+++ b/meta-xilinx-core/dynamic-layers/openamp-layer/recipes-bsp/device-tree/files/zynqmp-openamp-overlay.dts
@@ -0,0 +1,13 @@
+/*
+ * SPDX-License-Identifier: MIT
+ *
+ * dts overlay file for ZynqMP OpenAMP
+ *
+ * Copyright (C) 2022, Advanced Micro Devices, Inc.  All rights reserved.
+ *
+ */
+
+/dts-v1/;
+/plugin/;
+
+#include "zynqmp-openamp.dtsi"
diff --git a/meta-xilinx-core/dynamic-layers/openamp-layer/recipes-bsp/device-tree/open-amp-device-tree.bb b/meta-xilinx-core/dynamic-layers/openamp-layer/recipes-bsp/device-tree/open-amp-device-tree.bb
new file mode 100644
index 00000000..8f77bd54
--- /dev/null
+++ b/meta-xilinx-core/dynamic-layers/openamp-layer/recipes-bsp/device-tree/open-amp-device-tree.bb
@@ -0,0 +1,51 @@
+SUMMARY = "OpenAMP Device Tree Overlay for Xilinx devices."
+SECTION = "bsp"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
+
+SRC_URI = " \
+    file://zynq-openamp.dtsi \
+    file://zynq-openamp-overlay.dts \
+    file://zynqmp-openamp.dtsi \
+    file://zynqmp-openamp-overlay.dts \
+    file://versal-openamp.dtsi \
+    file://versal-openamp-overlay.dts \
+"
+
+# We don't have anything to include from the kernel
+KERNEL_INCLUDE = ""
+
+COMPATIBLE_MACHINE:zynq = "${MACHINE}"
+COMPATIBLE_MACHINE:zynqmp = "${MACHINE}"
+COMPATIBLE_MACHINE:versal = "${MACHINE}"
+
+inherit devicetree image-artifact-names features_check
+
+REQUIRED_DISTRO_FEATURES = "openamp"
+
+# We are not _THE_ virtual/dtb provider
+PROVIDES:remove = "virtual/dtb"
+
+DEPENDS += "python3-dtc-native"
+
+S = "${WORKDIR}/source"
+
+# Set a default so something resolves
+SOC_FAMILY ??= "SOC_FAMILY"
+
+do_configure:prepend() {
+        mkdir -p source
+
+        if [ -e ${WORKDIR}/${MACHINE}-openamp-overlay.dts ]; then
+                install ${WORKDIR}/${MACHINE}-openamp.dtsi ${WORKDIR}/source/. || :
+                install ${WORKDIR}/${MACHINE}-openamp-overlay.dts ${WORKDIR}/source/openamp.dts
+        elif [ -e ${WORKDIR}/${SOC_FAMILY}-openamp-overlay.dts ]; then
+                install ${WORKDIR}/${SOC_FAMILY}-openamp.dtsi ${WORKDIR}/source/. || :
+                install ${WORKDIR}/${SOC_FAMILY}-openamp-overlay.dts ${WORKDIR}/source/openamp.dts
+        else
+                bbfatal "${MACHINE}-openamp-overlay.dts or ${SOC_FAMILY}-openamp-overlay.dts file is not available.  Cannot automatically add OpenAMP dtbo file."
+        fi
+}
+
+FILES:${PN} = "/boot/devicetree/openamp.dtbo"