conf/machine: Better document inheritence expectations

See the README files for specific requirements, but we have designed the
machine configurations into an inheritance model.  This module can be
further broken into 3 distinct categories of variables:

1 - Variables that MUST be declared BEFORE inheriting the base machine

2 - Variables that SHOULD be declared BEFORE inheriting the base machine,
    as they are commonly overridden.  (This will need continual review.)

3 - All remaining variables that should only be declared in the machine
    .conf file, and MUST be declared AFTER inheriting the base machine.

Signed-off-by: Mark Hatle <mark.hatle@amd.com>

1 files changed, 26 insertions, 0 deletions

diff --git a/meta-xilinx-core/classes/xilinx-vars.bbclass b/meta-xilinx-core/classes/xilinx-vars.bbclass
new file mode 100644
index 00000000..a1a0e38c
--- /dev/null
+++ b/meta-xilinx-core/classes/xilinx-vars.bbclass
@@ -0,0 +1,26 @@
+# Check variable usage to make sure that the machine is probably configured
+# properly.
+addhandler xilinx_variables_config_eventhandler
+xilinx_variables_config_eventhandler[eventmask] = "bb.event.ConfigParsed"
+
+# It's up to the base sytem to define the variables being used here, we're
+# only going to check them.
+python xilinx_variables_config_eventhandler () {
+    # Verify HDF_MACHINE
+    hdf_prior = d.getVar('HDF_MACHINE_PRIOR')
+    hdf_final = d.getVar('HDF_MACHINE')
+
+    if hdf_prior and hdf_prior != hdf_final:
+        bb.fatal("HDF_MACHINE is set to %s, it appears you intended %s. " \
+                 "This is usually as a result of specifying it in the local.conf or before the 'require' in the machine .conf file. " \
+                 "See meta-xilinx-core/conf/machine/README." % (hdf_final, hdf_prior))
+
+    # Verify DEFAULTTUNE
+    tune_prior = d.getVar('DEFAULTTUNE_PRIOR')
+    tune_final = d.getVar('DEFAULTTUNE')
+
+    if tune_prior and tune_prior != tune_final:
+        bb.fatal("The loaded DEFAULTTUNE is %s, but it appears you intended %s. " \
+                 "This is usually as a result of specifying it after the 'require' in the machine .conf file. " \
+                 "See meta-xilinx-core/conf/machine/README." % (tune_prior, tune_final))
+}