pmu-rom-native: Automatically download from public site for QEMU usage

Move the pmu-rom to pmu-rom-native recipe.  The ROM is only deployed in the
standard directory for qemu-xilinx usage when required by a zynqmp-generic
system.

Signed-off-by: Mark Hatle <mark.hatle@xilinx.com>

3 files changed, 28 insertions, 42 deletions

diff --git a/meta-xilinx-core/conf/machine/zynqmp-generic.conf b/meta-xilinx-core/conf/machine/zynqmp-generic.conf
index 7f89b958..e36e98aa 100644
--- a/meta-xilinx-core/conf/machine/zynqmp-generic.conf
+++ b/meta-xilinx-core/conf/machine/zynqmp-generic.conf
@@ -24,7 +24,7 @@ MACHINE_FEATURES += "rtc ext2 ext3 vfat usbhost"
 # Ultra96 features:
 MACHINE_FEATURES += " usbgadget wifi bluetooth"
 
-EXTRA_IMAGEDEPENDS += "libyaml-native python3-cython-native python3-pyyaml-native"
+EXTRA_IMAGEDEPENDS += "libyaml-native python3-cython-native python3-pyyaml-native pmu-rom-native"
 
 UBOOT_MACHINE ?= "xilinx_zynqmp_virt_defconfig"
 SPL_BINARY ?= "spl/boot.bin"
diff --git a/meta-xilinx-core/recipes-bsp/pmu-firmware/pmu-rom-native_2022.1.bb b/meta-xilinx-core/recipes-bsp/pmu-firmware/pmu-rom-native_2022.1.bb
new file mode 100644
index 00000000..d38b3da0
--- /dev/null
+++ b/meta-xilinx-core/recipes-bsp/pmu-firmware/pmu-rom-native_2022.1.bb
@@ -0,0 +1,27 @@
+SUMMARY = "PMU ROM for QEMU"
+DESCRIPTION = "The ZynqMP PMU ROM for QEMU emulation"
+HOMEPAGE = "http://www.xilinx.com"
+SECTION = "bsp"
+
+LICENSE = "Proprietary"
+LICENSE_FLAGS = "xilinx"
+LIC_FILES_CHKSUM = "file://PMU_ROM-LICENSE.txt;md5=d43d49bc1eb1c907fc6f4ea75abafdfc"
+
+SRC_URI = "https://www.xilinx.com/bin/public/openDownload?filename=PMU_ROM.tar.gz"
+SRC_URI[sha256sum] = "f9a450ef960979463ea0a87a35fafb4a5b62d3a741de30cbcef04c8edc22a7cf"
+
+S = "${WORKDIR}/PMU_ROM"
+
+inherit deploy native
+
+INHIBIT_DEFAULT_DEPS = "1"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+do_compile[noexec] = "1"
+do_install[noexec] = "1"
+
+do_deploy () {
+        install -D ${S}/pmu-rom.elf ${DEPLOYDIR}/pmu-rom.elf
+}
+
+addtask deploy before do_build after do_install
diff --git a/meta-xilinx-core/recipes-bsp/pmu-firmware/pmu-rom_2018.1.bb b/meta-xilinx-core/recipes-bsp/pmu-firmware/pmu-rom_2018.1.bb
deleted file mode 100644
index 195c6309..00000000
--- a/meta-xilinx-core/recipes-bsp/pmu-firmware/pmu-rom_2018.1.bb
+++ /dev/null
@@ -1,41 +0,0 @@
-SUMMARY = "PMU ROM for QEMU"
-DESCRIPTION = "The ZynqMP PMU ROM for QEMU emulation"
-HOMEPAGE = "http://www.xilinx.com"
-SECTION = "bsp"
-
-# The BSP package does not include any license information.
-LICENSE = "Proprietary"
-LICENSE_FLAGS = "xilinx"
-LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/Proprietary;md5=0557f9d92cf58f2ccdd50f62f8ac0b28"
-
-COMPATIBLE_MACHINE = "zcu102-zynqmp"
-
-inherit deploy
-inherit xilinx-fetch-restricted
-
-BSP_NAME = "xilinx-zcu102"
-BSP_FILE = "${BSP_NAME}-v${PV}-final.bsp"
-SRC_URI = "https://www.xilinx.com/member/forms/download/xef.html?filename=${BSP_FILE};downloadfilename=${BSP_FILE}"
-SRC_URI[md5sum] = "cea5f11761e7f38cbfcf0a07a19094e0"
-SRC_URI[sha256sum] = "7ac0ac3a5fb7dd162c0a922c66edb33b5737955ef6570a1a1d3b15b4344f7cc1"
-
-INHIBIT_DEFAULT_DEPS = "1"
-PACKAGE_ARCH = "${MACHINE_ARCH}"
-
-do_compile() {
-        # Extract the rom into workdir
-        tar -xf ${WORKDIR}/${BSP_FILE} ${BSP_NAME}-${PV}/pre-built/linux/images/pmu_rom_qemu_sha3.elf -C ${S}
-        # tar preserves the tree, so use find to get the full path and move to to the root
-        for i in $(find ${S} -type f -name *.elf); do mv $i ${S}/pmu-rom.elf; done
-}
-
-do_install() {
-        :
-}
-
-do_deploy () {
-        install -D ${S}/pmu-rom.elf ${DEPLOYDIR}/pmu-rom.elf
-}
-
-addtask deploy before do_build after do_install
-