Adding bootbin as is from xilinx-tools

Signed-off-by: Jaewon Lee <jaewon.lee@xilinx.com>

5 files changed, 363 insertions, 0 deletions

diff --git a/meta-xilinx-bsp/recipes-bsp/bootbin/machine-xilinx-versal.inc b/meta-xilinx-bsp/recipes-bsp/bootbin/machine-xilinx-versal.inc
new file mode 100644
index 00000000..e10339dd
--- /dev/null
+++ b/meta-xilinx-bsp/recipes-bsp/bootbin/machine-xilinx-versal.inc
@@ -0,0 +1,46 @@
+#Extra args for versal
+BOOTGEN_EXTRA_ARGS += "-dump bh"
+
+#Add pdi dependency for versal
+DEPENDS += "virtual/base-pdi"
+
+# specify BIF common attribute for FSBL
+BIF_COMMON_ATTR ?= ""
+
+# specify BIF partition attributes required for BOOT.bin
+BIF_PARTITION_ATTR ?= "pdi plm psm dtb atf u-boot"
+
+# specify BIF partition attributes for pdi
+BIF_PARTITION_ATTR[pdi] ?= "type=bootimage"
+BIF_PARTITION_IMAGE[pdi] ?= "${RECIPE_SYSROOT}/boot/base-design.pdi"
+BIF_PARTITION_DEPENDS[pdi] ?= "virtual/base-pdi:do_populate_sysroot"
+
+# specify BIF partition attributes for plm
+PLM_IMAGE_NAME ??= "plm-${MACHINE}"
+BIF_PARTITION_ATTR[plm] ?= "type=bootloader"
+BIF_PARTITION_IMAGE[plm] ?= "${DEPLOY_DIR_IMAGE}/${PLM_IMAGE_NAME}.elf"
+BIF_PARTITION_DEPENDS[plm] ?= "virtual/plm:do_deploy"
+
+# specify BIF partition attributes for psm
+PSM_FIRMWARE_IMAGE_NAME ??= "psm-firmware-${MACHINE}"
+BIF_PARTITION_ATTR[psm] ?= "core=psm"
+BIF_PARTITION_IMAGE[psm] ?= "${DEPLOY_DIR_IMAGE}/${PSM_FIRMWARE_IMAGE_NAME}.elf"
+BIF_PARTITION_DEPENDS[psm] ?= "virtual/psm-firmware:do_deploy"
+
+# specify BIF partition attributes for dtb
+BIF_PARTITION_ATTR[dtb] ?= "type=raw, load=0x1000"
+BIF_PARTITION_IMAGE[dtb] ?= "${DEPLOY_DIR_IMAGE}/system.dtb"
+BIF_PARTITION_DEPENDS[dtb] ?= "virtual/dtb:do_deploy"
+BIF_PARTITION_ID[dtb] ?= "0x1c000000"
+
+# specify BIF partition attributes for u-boot
+BIF_PARTITION_ATTR[u-boot] ?= "core=a72-0, exception_level = el-2"
+BIF_PARTITION_IMAGE[u-boot] ?= "${DEPLOY_DIR_IMAGE}/u-boot-${MACHINE}.elf"
+BIF_PARTITION_DEPENDS[u-boot] ?= "virtual/bootloader:do_deploy u-boot-zynq-scr:do_deploy"
+BIF_PARTITION_ID[u-boot] ?= "0x1c000000"
+
+# specify BIF partition attributes for atf
+BIF_PARTITION_ATTR[atf] ?= "core=a72-0, exception_level = el-3, trustzone"
+BIF_PARTITION_IMAGE[atf] ?= "${DEPLOY_DIR_IMAGE}/arm-trusted-firmware.elf"
+BIF_PARTITION_DEPENDS[atf] ?= "virtual/arm-trusted-firmware:do_deploy"
+BIF_PARTITION_ID[atf] ?= "0x1c000000"
diff --git a/meta-xilinx-bsp/recipes-bsp/bootbin/machine-xilinx-zynq.inc b/meta-xilinx-bsp/recipes-bsp/bootbin/machine-xilinx-zynq.inc
new file mode 100644
index 00000000..b8d75c4f
--- /dev/null
+++ b/meta-xilinx-bsp/recipes-bsp/bootbin/machine-xilinx-zynq.inc
@@ -0,0 +1,17 @@
+#specify BIF partition attributes required for BOOT.bin
+BIF_PARTITION_ATTR ?= "fsbl bitstream u-boot"
+
+#specify BIF partition attributes for FSBL
+#bootloader is FSBL. Location where FSBL binary is present and dependency to build FSBL
+BIF_PARTITION_ATTR[fsbl] ?= "bootloader"
+BIF_PARTITION_IMAGE[fsbl] ?= "${DEPLOY_DIR_IMAGE}/fsbl-${MACHINE}.elf"
+BIF_PARTITION_DEPENDS[fsbl] ?= "virtual/fsbl:do_deploy"
+
+#specify BIF partition attributes for u-boot
+#Location where u-boot binary is present
+BIF_PARTITION_IMAGE[u-boot] ?= "${DEPLOY_DIR_IMAGE}/u-boot-${MACHINE}.elf"
+BIF_PARTITION_DEPENDS[u-boot] ?= "virtual/bootloader:do_deploy"
+
+# enable bitstream-Note this is not enabled by default (missing in BIF_PARTITION_ATTR)
+BIF_PARTITION_IMAGE[bitstream] ?= "${DEPLOY_DIR_IMAGE}/download-${MACHINE}.bit"
+BIF_PARTITION_DEPENDS[bitstream] ?= "virtual/bitstream:do_deploy"
diff --git a/meta-xilinx-bsp/recipes-bsp/bootbin/machine-xilinx-zynqmp.inc b/meta-xilinx-bsp/recipes-bsp/bootbin/machine-xilinx-zynqmp.inc
new file mode 100644
index 00000000..cd2026ad
--- /dev/null
+++ b/meta-xilinx-bsp/recipes-bsp/bootbin/machine-xilinx-zynqmp.inc
@@ -0,0 +1,40 @@
+# specify BIF common attribute for FSBL
+BIF_COMMON_ATTR ?= ""
+
+# specify BIF partition attributes required for BOOT.bin
+BIF_PARTITION_ATTR ?= "fsbl pmu atf u-boot"
+
+# specify BIF partition attributes for FSBL
+# bootloader is FSBL. Location where FSBL binary is present and dependency to build FSBL
+BIF_PARTITION_ATTR[fsbl] ?= "bootloader, destination_cpu=a53-0"
+BIF_PARTITION_IMAGE[fsbl] ?= "${DEPLOY_DIR_IMAGE}/fsbl-${MACHINE}.elf"
+BIF_PARTITION_DEPENDS[fsbl] ?= "virtual/fsbl:do_deploy"
+
+# specify BIF partition attributes for PMU Firmware
+# destination cpu for PMU. Location where PMU binary is present and dependency to build PMU Firmware
+PMU_FIRMWARE_IMAGE_NAME ??= "pmu-firmware-${MACHINE}"
+BIF_PARTITION_ATTR[pmu] ?= "destination_cpu=pmu"
+BIF_PARTITION_IMAGE[pmu] ?= "${DEPLOY_DIR_IMAGE}/${PMU_FIRMWARE_IMAGE_NAME}.elf"
+BIF_PARTITION_DEPENDS[pmu] ?= "virtual/pmu-firmware:do_deploy"
+
+# specify BIF partition attributes for ATF
+# destination cpu for ATF, security levels. Location where ATF binary is present (dependency is not required as ATF is always built for ZU+, see zcu102-zynqmp.conf)
+BIF_PARTITION_ATTR[atf] ?= "destination_cpu=a53-0,exception_level=el-3,trustzone"
+BIF_PARTITION_IMAGE[atf] ?= "${DEPLOY_DIR_IMAGE}/arm-trusted-firmware.elf"
+BIF_PARTITION_DEPENDS[atf] ?= "arm-trusted-firmware:do_deploy"
+
+# specify BIF partition attributes for u-boot
+# destination cpu for u-boot, security levels. Location where u-boot binary is present (dependency is not required as u-boot is always built for ZU+, see zcu102-zynqmp.conf)
+BIF_PARTITION_ATTR[u-boot] ?= "destination_cpu=a53-0,exception_level=el-2"
+BIF_PARTITION_IMAGE[u-boot] ?= "${DEPLOY_DIR_IMAGE}/u-boot-${MACHINE}.elf"
+BIF_PARTITION_DEPENDS[u-boot] ?= "virtual/bootloader:do_deploy"
+
+# specify BIF partition attributes for dtb
+BIF_PARTITION_ATTR[dtb] ?= "load=0x100000"
+BIF_PARTITION_IMAGE[dtb] ?= "${DEPLOY_DIR_IMAGE}/system.dtb"
+BIF_PARTITION_DEPENDS[dtb] ?= "virtual/dtb:do_deploy"
+
+# enable bitstream-Note this is not enabled by default (missing in BIF_PARTITION_ATTR)
+BIF_PARTITION_ATTR[bitstream] ?= "destination_device=pl"
+BIF_PARTITION_IMAGE[bitstream] ?= "${DEPLOY_DIR_IMAGE}/download-${MACHINE}.bit"
+BIF_PARTITION_DEPENDS[bitstream] ?= "virtual/bitstream:do_deploy"
diff --git a/meta-xilinx-bsp/recipes-bsp/bootbin/xilinx-bootbin_1.0.bb b/meta-xilinx-bsp/recipes-bsp/bootbin/xilinx-bootbin_1.0.bb
new file mode 100644
index 00000000..3a0535b7
--- /dev/null
+++ b/meta-xilinx-bsp/recipes-bsp/bootbin/xilinx-bootbin_1.0.bb
@@ -0,0 +1,190 @@
+SUMMARY = "Generates boot.bin using bootgen tool"
+DESCRIPTION = "Manages task dependencies and creation of boot.bin. Use the \
+BIF_PARTITION_xyz global variables and flags to determine what makes it into \
+the image."
+
+LICENSE = "BSD"
+
+include machine-xilinx-${SOC_FAMILY}.inc
+
+inherit deploy
+
+PROVIDES = "virtual/boot-bin"
+
+DEPENDS += "bootgen-native"
+
+do_configure[depends] += "${@get_bootbin_depends(d)}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+BIF_FILE_PATH ?= "${B}/bootgen.bif"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
+
+SRC_URI += "${@('file://' + d.getVar("BIF_FILE_PATH")) if d.getVar("BIF_FILE_PATH") != (d.getVar('B') + '/bootgen.bif') else ''}"
+
+BOOTGEN_EXTRA_ARGS ?= ""
+
+BIF_PARTITION_ATTR_zynqmp = "${@'fsbl pmu atf dtb u-boot' if d.getVar('FPGA_MNGR_RECONFIG_ENABLE') == '1' else 'fsbl bitstream pmu atf dtb u-boot'}"
+
+do_patch[noexec] = "1"
+
+def get_bootbin_depends(d):
+    bootbindeps = ""
+    bifpartition = (d.getVar("BIF_PARTITION_ATTR") or "").split()
+    attrdepends = d.getVarFlags("BIF_PARTITION_DEPENDS") or {}
+    for cfg in bifpartition:
+        if cfg in attrdepends:
+            bootbindeps = bootbindeps + " " + attrdepends[cfg]
+
+    return bootbindeps
+
+def create_bif(config, attrflags, attrimage, ids, common_attr, biffd, d):
+    import re, os
+    for cfg in config:
+        if cfg not in attrflags and common_attr:
+            error_msg = "%s: invalid ATTRIBUTE" % (cfg)
+            bb.error("BIF attribute Error: %s " % (error_msg))
+        else:
+            if common_attr:
+                cfgval = d.expand(attrflags[cfg]).split(',')
+                cfgstr = "\t [%s] %s\n" % (cfg,', '.join(cfgval))
+            else:
+                if cfg not in attrimage:
+                    error_msg = "%s: invalid or missing elf or image" % (cfg)
+                    bb.error("BIF atrribute Error: %s " % (error_msg))
+                imagestr = d.expand(attrimage[cfg])
+                if os.stat(imagestr).st_size == 0:
+                    bb.warn("Empty file %s, excluding from bif file" %(imagestr))
+                    continue
+                if cfg in attrflags:
+                    cfgval = d.expand(attrflags[cfg]).split(',')
+                    cfgstr = "\t [%s] %s\n" % (', '.join(cfgval), imagestr)
+                else:
+                    cfgstr = "\t %s\n" % (imagestr)
+            biffd.write(cfgstr)
+
+    return
+
+def create_versal_bif(config, attrflags, attrimage, ids, common_attr, biffd, d):
+    import re, os
+    id_dict = {}
+    for cfg in config:
+        if cfg not in attrflags and common_attr:
+            error_msg = "%s: invalid ATTRIBUTE" % (cfg)
+            bb.error("BIF attribute Error: %s " % (error_msg))
+        else:
+            if common_attr:
+                cfgval = d.expand(attrflags[cfg]).split(',')
+                #TODO: Does common attribute syntax change in similar way for versal?
+                cfgstr = "\t { %s %s }\n" % (cfg,', '.join(cfgval))
+                biffd.write(cfgstr)
+            else:
+                if cfg not in attrimage:
+                    error_msg = "%s: invalid or missing elf or image" % (cfg)
+                    bb.error("BIF atrribute Error: %s " % (error_msg))
+                imagestr = d.expand(attrimage[cfg])
+                if os.stat(imagestr).st_size == 0:
+                    bb.warn("Empty file %s, excluding from bif file" %(imagestr))
+                    continue
+                if cfg in attrflags:
+                    cfgval = d.expand(attrflags[cfg]).split(',')
+                    try:
+                        id = d.expand(ids[cfg])
+                    except:
+                        id = '0'
+                    cfgstr = "\t { %s, file=%s }\n" % (', '.join(cfgval), imagestr)
+                    try:
+                        id_dict[id] += cfgstr
+                    except:
+                        id_dict[id] = cfgstr
+                else:
+                    cfgstr = "\t %s\n" % (imagestr)
+    for id, string in id_dict.items():
+        biffd.write("\timage {\n")
+        if id != '0':
+            biffd.write("\t id = " + id + "\n")
+        biffd.write(string)
+        biffd.write("\t}\n")
+    return
+
+python do_configure() {
+    fp = d.getVar("BIF_FILE_PATH")
+    if fp == (d.getVar('B') + '/bootgen.bif'):
+        arch = d.getVar("SOC_FAMILY")
+        biffunc = {'versal':create_versal_bif, 'zynq':create_bif, 'zynqmp':create_bif}
+        biffd = open(fp, 'w')
+        biffd.write("the_ROM_image:\n")
+        biffd.write("{\n")
+
+        bifattr = (d.getVar("BIF_COMMON_ATTR") or "").split()
+        if bifattr:
+            attrflags = d.getVarFlags("BIF_COMMON_ATTR") or {}
+            biffunc[arch](bifattr, attrflags,'','', 1, biffd, d)
+
+        bifpartition = (d.getVar("BIF_PARTITION_ATTR") or "").split()
+        if bifpartition:
+            attrflags = d.getVarFlags("BIF_PARTITION_ATTR") or {}
+            attrimage = d.getVarFlags("BIF_PARTITION_IMAGE") or {}
+            ids = d.getVarFlags("BIF_PARTITION_ID") or {}
+            biffunc[arch](bifpartition, attrflags, attrimage, ids, 0, biffd, d)
+
+        biffd.write("}")
+        biffd.close()
+    else:
+        print("Using custom BIF file: " + d.getVar("BIF_FILE_PATH") )
+}
+
+do_configure[vardeps] += "BIF_PARTITION_ATTR BIF_PARTITION_IMAGE BIF_COMMON_ATTR"
+
+do_compile() {
+    cd ${WORKDIR}
+    rm -f ${B}/BOOT.bin
+    if [ "${BIF_FILE_PATH}" != "${B}/bootgen.bif" ];then
+        BIF_FILE_PATH="${WORKDIR}${BIF_FILE_PATH}"
+    fi
+    bootgen -image ${BIF_FILE_PATH} -arch ${SOC_FAMILY} ${BOOTGEN_EXTRA_ARGS} -w -o ${B}/BOOT.bin
+    if [ ! -e ${B}/BOOT.bin ]; then
+        bbfatal "bootgen failed. See log"
+    fi
+}
+
+do_compile_append_versal() {
+    dd if=/dev/zero bs=256M count=1  > ${B}/QEMU_qspi.bin
+    dd if=${B}/BOOT.bin of=${B}/QEMU_qspi.bin bs=1 seek=0 conv=notrunc
+    dd if=${DEPLOY_DIR_IMAGE}/boot.scr of=${B}/QEMU_qspi.bin bs=1 seek=66584576 conv=notrunc
+}
+
+do_install() {
+    install -d ${D}/boot
+    install -m 0644 ${B}/BOOT.bin ${D}/boot/BOOT.bin
+}
+
+inherit image-artifact-names
+
+QEMUQSPI_BASE_NAME ?= "QEMU_qspi-${MACHINE}${IMAGE_VERSION_SUFFIX}"
+
+BOOTBIN_BASE_NAME ?= "BOOT-${MACHINE}${IMAGE_VERSION_SUFFIX}"
+
+do_deploy() {
+    install -d ${DEPLOYDIR}
+    install -m 0644 ${B}/BOOT.bin ${DEPLOYDIR}/${BOOTBIN_BASE_NAME}.bin
+    ln -sf ${BOOTBIN_BASE_NAME}.bin ${DEPLOYDIR}/BOOT-${MACHINE}.bin
+    ln -sf ${BOOTBIN_BASE_NAME}.bin ${DEPLOYDIR}/boot.bin
+}
+
+do_deploy_append_versal () {
+
+    install -m 0644 ${B}/BOOT_bh.bin ${DEPLOYDIR}/${BOOTBIN_BASE_NAME}_bh.bin
+    ln -sf ${BOOTBIN_BASE_NAME}_bh.bin ${DEPLOYDIR}/BOOT-${MACHINE}_bh.bin
+
+    install -m 0644 ${B}/QEMU_qspi.bin ${DEPLOYDIR}/${QEMUQSPI_BASE_NAME}.bin
+    ln -sf ${QEMUQSPI_BASE_NAME}.bin ${DEPLOYDIR}/QEMU_qspi-${MACHINE}.bin
+}
+
+FILES_${PN} += "/boot/BOOT.bin"
+SYSROOT_DIRS += "/boot"
+
+addtask do_deploy before do_build after do_compile
+
diff --git a/meta-xilinx-bsp/recipes-bsp/bootbin/xilinx-mcs_1.0.bb b/meta-xilinx-bsp/recipes-bsp/bootbin/xilinx-mcs_1.0.bb
new file mode 100644
index 00000000..4e3b11db
--- /dev/null
+++ b/meta-xilinx-bsp/recipes-bsp/bootbin/xilinx-mcs_1.0.bb
@@ -0,0 +1,70 @@
+SUMMARY = "Generates boot.mcs using vivado"
+DESCRIPTION = "Manages task dependencies and creation of boot.mcs for microblaze"
+
+LICENSE = "BSD"
+
+PROVIDES = "virtual/boot-bin"
+
+DEPENDS = "bitstream-microblaze"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+COMPATIBLE_MACHINE ?= "^$"
+COMPATIBLE_MACHINE_microblaze = ".*"
+
+inherit deploy image-artifact-names
+
+do_fetch[noexec] = "1"
+do_unpack[noexec] = "1"
+do_patch[noexec] = "1"
+
+PROC ??= "kc705_i/microblaze_0"
+PROC_kc705 = "kc705_i/microblaze_0"
+
+FLASH_SIZE ??= "0x80"
+FLASH_INTERFACE ??= "BPIx16"
+MB_OUT_FORMAT  ??= "mcs"
+BOOT_EXT = "${@d.getVar('MB_OUT_FORMAT').lower()}"
+
+BITSTREAM_FILE ?= "${RECIPE_SYSROOT}/boot/bitstream/download.bit"
+B = "${WORKDIR}/build"
+WR_CFGMEM_MISC ?= "-loadbit \" up 0 ${BITSTREAM_FILE}\""
+
+do_check_for_vivado() {
+        bbnote "Checking Vivado install path"
+        which "vivado" 2>/dev/null || {
+                bbfatal "Vivado not found! Please add \"INHERIT += \"vivado\"\" to your local.conf"
+  }
+}
+
+addtask do_check_for_vivado before do_configure
+
+do_configure() {
+    echo " write_cfgmem -force -format ${MB_OUT_FORMAT} -size ${FLASH_SIZE} -interface ${FLASH_INTERFACE} ${WR_CFGMEM_MISC} ${B}/BOOT.${BOOT_EXT} " > ${B}/write_cfgmem_boot_mcs.tcl
+    if [ ! -e ${B}/write_cfgmem_boot_mcs.tcl ]; then
+        bbfatal "write_cfgmem_boot_mcs.tcl creation failed. See log for details"
+    fi
+}
+
+
+do_compile() {
+    vivado -log "${B}/cfgmem_mcs.log" -jou "${B}/cfgmem_mcs.jou" -mode batch -s ${B}/write_cfgmem_boot_mcs.tcl
+    if [ ! -e ${B}/BOOT.${BOOT_EXT} ]; then
+        bbfatal "BOOT.${BOOT_EXT} failed. See log"
+    fi
+}
+
+do_install() {
+        :
+}
+
+BOOT_BASE_NAME ?= "BOOT-${MACHINE}${IMAGE_VERSION_SUFFIX}"
+
+do_deploy() {
+    #install BOOT.mcs
+    if [ -e ${B}/BOOT.${BOOT_EXT} ]; then
+        install -Dm 0644 ${B}/BOOT.${BOOT_EXT} ${DEPLOYDIR}/${BOOT_BASE_NAME}.${BOOT_EXT}
+        ln -sf ${BOOT_BASE_NAME}.${BOOT_EXT} ${DEPLOYDIR}/BOOT-${MACHINE}.${BOOT_EXT}
+    fi
+}
+addtask do_deploy before do_build after do_compile