recipes-kernel: Add udev rules files for linux-xlnx in-tree drivers

This recipe is to add generic udev rules files for linux-xlnx in-tree
drivers.

- Create a new aie group.
- Add udev rules for aie devices and change permissions and
  ownership group to "aie" so that any new user added to aie groups can
  access aie devices(/dev/aie0) from linux userspace.

Signed-off-by: Sandeep Gundlupet Raju <sandeep.gundlupet-raju@xilinx.com>
Signed-off-by: Mark Hatle <mhatle@xilinx.com>

2 files changed, 39 insertions, 0 deletions

diff --git a/meta-xilinx-core/recipes-kernel/linux-xlnx-udev-rules/linux-xlnx-udev-rules.bb b/meta-xilinx-core/recipes-kernel/linux-xlnx-udev-rules/linux-xlnx-udev-rules.bb
new file mode 100644
index 00000000..f5b0ff95
--- /dev/null
+++ b/meta-xilinx-core/recipes-kernel/linux-xlnx-udev-rules/linux-xlnx-udev-rules.bb
@@ -0,0 +1,37 @@
+SUMMARY = "Udev rules files for Linux drivers"
+DESCRIPTION = "Generic udev rules recipe for Xilinx Linux in tree drivers"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
+
+SRC_URI = "\
+    file://99-aie-device.rules \
+"
+
+S = "${WORKDIR}"
+
+inherit useradd
+
+COMPATIBLE_MACHINE ?= "^$"
+COMPATIBLE_MACHINE:zynq = ".*"
+COMPATIBLE_MACHINE:zynqmp = ".*"
+COMPATIBLE_MACHINE:microblaze = ".*"
+COMPATIBLE_MACHINE:versal = ".*"
+
+do_configure[noexec] = '1'
+do_compile[noexec] = '1'
+
+do_install () {
+    install -d ${D}${sysconfdir}/udev/rules.d
+    for rule in $(find ${WORKDIR} -maxdepth 1 -type f -name "*.rules"); do
+        if ${@bb.utils.contains_any('SOC_VARIANT', ['ai-core', 'ai-edge'], 'true', 'false' ,d)}; then
+            install -m 0644 ${WORKDIR}/99-aie-device.rules ${D}${sysconfdir}/udev/rules.d/
+        fi
+        install -m 0644 $rule ${D}${sysconfdir}/udev/rules.d/
+    done
+}
+
+USERADD_PACKAGES = "${PN}"
+GROUPADD_PARAM:${PN} += "${@bb.utils.contains_any('SOC_VARIANT', ['ai-core', 'ai-edge'], '-r aie;', '', d)}"
+
+FILES:${PN} += "${sysconfdir}/udev/rules.d/*"
+
diff --git a/meta-xilinx-core/recipes-kernel/linux-xlnx-udev-rules/linux-xlnx-udev-rules/99-aie-device.rules b/meta-xilinx-core/recipes-kernel/linux-xlnx-udev-rules/linux-xlnx-udev-rules/99-aie-device.rules
new file mode 100644
index 00000000..fffcf6e6
--- /dev/null
+++ b/meta-xilinx-core/recipes-kernel/linux-xlnx-udev-rules/linux-xlnx-udev-rules/99-aie-device.rules
@@ -0,0 +1,2 @@
+# Device rules for AIE drivers.
+ACTION=="add", SUBSYSTEM=="aie", KERNEL=="aie[0-9]*", MODE="0660", GROUP="aie"