binutils/gcc: Refactor the oeconf

The result of the refactoring is equivalent to before the changes, with the
following changes:

- cortexa72 has been removed
- cortexa53 has been replaced with aarch64
- zc702-zynq7 has been replaced with arm
- zynqmp-pmu has been replaced with microblaze

In order to avoid a multilib cflag collision on arm, clear the TUNE_CCARGS on
arm (and cortexr5).

Signed-off-by: Mark Hatle <mark.hatle@xilinx.com>

7 files changed, 88 insertions, 282 deletions

diff --git a/meta-xilinx-standalone/recipes-standalone/binutils/binutils-cross-canadian_%.bbappend b/meta-xilinx-standalone/recipes-standalone/binutils/binutils-cross-canadian_%.bbappend
index 1e4d8b02..5ba6039b 100644
--- a/meta-xilinx-standalone/recipes-standalone/binutils/binutils-cross-canadian_%.bbappend
+++ b/meta-xilinx-standalone/recipes-standalone/binutils/binutils-cross-canadian_%.bbappend
@@ -1,29 +1 @@
-include binutils-xilinx-standalone.inc
-
-
-# The following is a copy of what is in OE-Core, without LDGOLD, because we have to do gold per machine instead
-EXTRA_OECONF_pn-binutils-cross-canadian-${TARGET_ARCH}_xilinx-standalone = " \
-        --program-prefix=${TARGET_PREFIX} \
-        --disable-werror \
-        --enable-deterministic-archives \ 
-        --enable-plugins \
-        ${BINUTILS_CONFIGURE_COMMON_XILINX_STANDALONE} \
-"
-
-
-EXTRA_OECONF_pn-binutils-cross-canadian-${TARGET_ARCH}_xilinx-standalone_append_cortexa53 = " \
-        ${BINUTILS_CONFIGURE_A53} \
-"
-
-EXTRA_OECONF_pn-binutils-cross-canadian-${TARGET_ARCH}_xilinx-standalone_append_cortexa72 = " \
-        ${BINUTILS_CONFIGURE_A72} \
-"
-EXTRA_OECONF_pn-binutils-cross-canadian-${TARGET_ARCH}_xilinx-standalone_append_cortexr5 = " \
-        ${BINUTILS_CONFIGURE_R5} \
-"
-EXTRA_OECONF_pn-binutils-cross-canadian-${TARGET_ARCH}_xilinx-standalone_append_zynqmp-pmu = " \
-        ${BINUTILS_CONFIGURE_MB} \
-"
-EXTRA_OECONF_pn-binutils-cross-canadian-${TARGET_ARCH}_xilinx-standalone_append_zc702-zynq7 = " \
-        ${BINUTILS_CONFIGURE_A9} \
-"
+require binutils-xilinx-standalone.inc
diff --git a/meta-xilinx-standalone/recipes-standalone/binutils/binutils-cross_%.bbappend b/meta-xilinx-standalone/recipes-standalone/binutils/binutils-cross_%.bbappend
index fd1702e4..5ba6039b 100644
--- a/meta-xilinx-standalone/recipes-standalone/binutils/binutils-cross_%.bbappend
+++ b/meta-xilinx-standalone/recipes-standalone/binutils/binutils-cross_%.bbappend
@@ -1,31 +1 @@
-include binutils-xilinx-standalone.inc
-
-
-# The following is a copy of what is in OE-Core, without LDGOLD, because we have to do gold per machine instead
-EXTRA_OECONF_pn-binutils-cross-${TARGET_ARCH}_xilinx-standalone = " \
-        --program-prefix=${TARGET_PREFIX} \
-        --disable-werror \
-        --enable-deterministic-archives \ 
-        --enable-plugins \
-        ${BINUTILS_CONFIGURE_COMMON_XILINX_STANDALONE} \
-"
-
-EXTRA_OECONF_pn-binutils-cross-${TARGET_ARCH}_xilinx-standalone_append_cortexa53 = " \
-        ${BINUTILS_CONFIGURE_A53} \
-"
-
-EXTRA_OECONF_pn-binutils-cross-${TARGET_ARCH}_xilinx-standalone_append_cortexa72 = " \
-        ${BINUTILS_CONFIGURE_A72} \
-"
-
-EXTRA_OECONF_pn-binutils-cross-${TARGET_ARCH}_xilinx-standalone_append_cortexr5 = " \
-        ${BINUTILS_CONFIGURE_R5} \
-"
-
-EXTRA_OECONF_pn-binutils-cross-${TARGET_ARCH}_xilinx-standalone_append_zynqmp-pmu = " \
-        ${BINUTILS_CONFIGURE_MB} \
-"
-
-EXTRA_OECONF_pn-binutils-cross-${TARGET_ARCH}_xilinx-standalone_append_zc702-zynq7 = " \
-        ${BINUTILS_CONFIGURE_A9} \
-"
+require binutils-xilinx-standalone.inc
diff --git a/meta-xilinx-standalone/recipes-standalone/binutils/binutils-xilinx-standalone.inc b/meta-xilinx-standalone/recipes-standalone/binutils/binutils-xilinx-standalone.inc
index 4170ee02..ac569736 100644
--- a/meta-xilinx-standalone/recipes-standalone/binutils/binutils-xilinx-standalone.inc
+++ b/meta-xilinx-standalone/recipes-standalone/binutils/binutils-xilinx-standalone.inc
@@ -1,46 +1,19 @@
-# This inc file contains common configuration used for Binutils for several
-# MACHINES when using xilinx-standalone a DISTRO.
-# This should be applicable to both cross and cross-canadian toolchain.
+LDGOLD_xilinx-standalone = ""
+LDGOLD_ALTS_xilinx-standalone = ""
 
-BINUTILS_CONFIGURE_COMMON_XILINX_STANDALONE = " \
-        --disable-gdb \
-        --disable-sim \
-"
-
-BINUTILS_CONFIGURE_A53 ?= " \
-        --disable-gprof \
-        --disable-libdecnumber \
-        --disable-readline \
-        --disable-shared \
-        --enable-lto \
-        --enable-static \
-"
-
-BINUTILS_CONFIGURE_A72 ?= " \
+EXTRA_OECONF_append_xilinx-standalone = " \
         --disable-gprof \
-        --disable-libdecnumber \
-        --disable-readline \
         --disable-shared \
         --enable-lto \
         --enable-static \
+        --enable-multilib \
 "
 
-BINUTILS_CONFIGURE_R5 ?= " \
-        --disable-docs \
-        --disable-nls \
+# CortexR5 and 32-bit arm are both "arm"
+EXTRA_OECONF_append_xilinx-standalone_arm = " \
         --enable-interwork \
 "
 
-BINUTILS_CONFIGURE_MB ?= " \
+EXTRA_OECONF_append_xilinx-standalone_microblaze = " \
         --disable-initfini-array \
-        --disable-nls \
-        --enable-gold=no \
-        --enable-ld=yes \
-        --enable-multilib \
 "
-
-BINUTILS_CONFIGURE_A9 ?= " \
-        --disable-docs \
-        --disable-nls \
-        --enable-interwork \
-"
\ No newline at end of file
diff --git a/meta-xilinx-standalone/recipes-standalone/gcc/gcc-cross-canadian_%.bbappend b/meta-xilinx-standalone/recipes-standalone/gcc/gcc-cross-canadian_%.bbappend
index 9143434a..19862cb9 100644
--- a/meta-xilinx-standalone/recipes-standalone/gcc/gcc-cross-canadian_%.bbappend
+++ b/meta-xilinx-standalone/recipes-standalone/gcc/gcc-cross-canadian_%.bbappend
@@ -1,45 +1 @@
-include gcc-xilinx-standalone.inc
-
-# This is still missing a way to remove infiniarray, if we really have to we could use _remove
-EXTRA_OECONF_pn-gcc-cross-canadian-${TARGET_ARCH}_xilinx-standalone = " \
-    ${GCC_CONFIGURE_COMMON_XILINX_STANDALONE} \
-    --program-prefix=${TARGET_PREFIX} \
-    --without-local-prefix \
-    ${EXTRA_OECONF_PATHS} \
-"
-
-
-# Cortex-A53
-EXTRA_OECONF_pn-gcc-cross-canadian-${TARGET_ARCH}_xilinx-standalone_append_cortexa53 = " \
-        ${GCC_CONFIGURE_A53} \
-"
-
-# Cortex-A72
-EXTRA_OECONF_pn-gcc-cross-canadian-${TARGET_ARCH}_xilinx-standalone_append_cortexa72 = " \
-        ${GCC_CONFIGURE_A72} \
-"
-
-# Cortex-R5
-EXTRA_OECONF_pn-gcc-cross-canadian-${TARGET_ARCH}_xilinx-standalone_append_cortexr5 = " \
-        ${GCC_CONFIGURE_R5} \
-"
-
-# MB
-EXTRA_OECONF_pn-gcc-cross-canadian-${TARGET_ARCH}_xilinx-standalone_append_zynqmp-pmu = " \
-        ${GCC_CONFIGURE_MB} \
-"
-
-# Cortex-A9
-EXTRA_OECONF_pn-gcc-cross-canadian-${TARGET_ARCH}_xilinx-standalone_append_zc702-zynq7 = " \
-        ${GCC_CONFIGURE_A9} \
-"
-
-# Temporary hack to build gcc cross canadian for tclibc-newlib as --with-sysroot=/not/exist
-# has been removed from TARGET_OS for elf and eabi in gcc-cross-canadian.inc
-
-python() {
-    extraoeconfgcc = d.getVar('EXTRA_OECONF')
-    extraoeconfgcc += " --with-sysroot=/not/exist"
-    d.delVar('EXTRA_OECONF')
-    d.setVar('EXTRA_OECONF', extraoeconfgcc)
-}
+require gcc-xilinx-standalone.inc
diff --git a/meta-xilinx-standalone/recipes-standalone/gcc/gcc-cross_%.bbappend b/meta-xilinx-standalone/recipes-standalone/gcc/gcc-cross_%.bbappend
index cad0cecc..19862cb9 100644
--- a/meta-xilinx-standalone/recipes-standalone/gcc/gcc-cross_%.bbappend
+++ b/meta-xilinx-standalone/recipes-standalone/gcc/gcc-cross_%.bbappend
@@ -1,40 +1 @@
-include gcc-xilinx-standalone.inc
-
-
-
-# This is still missing a way to remove infiniarray, if we really have to we could use _remove
-EXTRA_OECONF_pn-gcc-cross-${TARGET_ARCH}_xilinx-standalone = " \
-    ${GCC_CONFIGURE_COMMON_XILINX_STANDALONE} \
-    --program-prefix=${TARGET_PREFIX} \
-    --without-local-prefix \
-    ${EXTRA_OECONF_PATHS} \
-"
-
-
-#   --with-multilib-list=aprofile doesnt exist in gcc 8
-
-
-# Cortex-A53
-EXTRA_OECONF_pn-gcc-cross-${TARGET_ARCH}_xilinx-standalone_append_cortexa53 = " \
-        ${GCC_CONFIGURE_A53} \
-"
-
-# Cortex-A72
-EXTRA_OECONF_pn-gcc-cross-${TARGET_ARCH}_xilinx-standalone_append_cortexa72 = " \
-        ${GCC_CONFIGURE_A72} \
-"
-
-# Cortex-R5
-EXTRA_OECONF_pn-gcc-cross-${TARGET_ARCH}_xilinx-standalone_append_cortexr5 = " \
-        ${GCC_CONFIGURE_R5} \
-"
-
-# MB
-EXTRA_OECONF_pn-gcc-cross-${TARGET_ARCH}_xilinx-standalone_append_zynqmp-pmu = " \
-        ${GCC_CONFIGURE_MB} \
-"
-
-# Cortex-A9
-EXTRA_OECONF_pn-gcc-cross-${TARGET_ARCH}_xilinx-standalone_append_zc702-zynq7 = " \
-        ${GCC_CONFIGURE_A9} \
-"
+require gcc-xilinx-standalone.inc
diff --git a/meta-xilinx-standalone/recipes-standalone/gcc/gcc-runtime_%.bbappend b/meta-xilinx-standalone/recipes-standalone/gcc/gcc-runtime_%.bbappend
index ba009a9d..d7531752 100644
--- a/meta-xilinx-standalone/recipes-standalone/gcc/gcc-runtime_%.bbappend
+++ b/meta-xilinx-standalone/recipes-standalone/gcc/gcc-runtime_%.bbappend
@@ -1,16 +1,54 @@
+# Copy of gcc-xilinx-standalone.inc, but with _class-target added
+LINKER_HASH_STYLE_xilinx-standalone_class-target = ""
+SYMVERS_CONF_xilinx-standalone_class-target = ""
+
+EXTRA_OECONF_append_xilinx-standalone_class-target = " \
+        --disable-libstdcxx-pch \
+        --with-newlib \
+        --disable-threads \
+        --enable-plugins \
+        --with-gnu-as \
+        --disable-libitm \
+        --enable-multilib \
+"
+
+EXTRA_OECONF_append_xilinx-standalone_aarch64_class-target = " \
+        --disable-multiarch \
+        --enable-fix-cortex-a53-835769 \
+        --enable-fix-cortex-a53-843419 \
+        --with-arch=armv8-a \
+        "
+
+# Both arm and cortexr5 overrides are set w/ r5
+# So only set rmprofile if r5 is defined.
+ARM_PROFILE = "aprofile"
+ARM_PROFILE_cortexr5 = "rmprofile"
+EXTRA_OECONF_append_xilinx-standalone_arm_class-target = " \
+        --with-multilib-list=${ARM_PROFILE} \
+        "
+
+EXTRA_OECONF_append_xilinx-standalone_cortexr5_class-target = " \
+        --disable-tls \
+        --disable-decimal-float \
+        "
+
+EXTRA_OECONF_append_xilinx-standalone_microblaze_class-target = " \
+        --disable-__cxa_atexit \
+        --enable-target-optspace \
+        --without-long-double-128 \
+        "
+
+# Changes local to gcc-runtime...
+
+# Due to multilibs, we need to clear the default TUNE_CCARGS on arm
+TUNE_CCARGS_xilinx-standalone_arm_class-target = ""
+
 # Configure fails on multilib when using a cache file, this re-sets it to nothing
 EXTRA_OECONF_append_xilinx-standalone_class-target = " --cache-file="
 
 # Dont build libitm, etc.
 RUNTIMETARGET_xilinx-standalone_class-target = "libstdc++-v3"
 
-SYMVERS_CONF_xilinx-standalone_class-target =""
-
-
-EXTRA_OECONF_append_xilinx-standalone_class-target = " --enable-multilib  --with-newlib"
-EXTRA_OECONF_append_xilinx-standalone_cortexr5_class-target = " --with-multilib-list=rmprofile"
-EXTRA_OECONF_append_xilinx-standalone_zc702-zynq7_class-target = " --with-multilib-list=aprofile"
-
 # Recursve 5 levels due to the several combinations of multilibs built
 FILES_libstdc++-staticdev_append_xilinx-standalone_class-target = " \
     ${libdir}/libsupc++.a* \
diff --git a/meta-xilinx-standalone/recipes-standalone/gcc/gcc-xilinx-standalone.inc b/meta-xilinx-standalone/recipes-standalone/gcc/gcc-xilinx-standalone.inc
index 93d7a86f..83834c18 100644
--- a/meta-xilinx-standalone/recipes-standalone/gcc/gcc-xilinx-standalone.inc
+++ b/meta-xilinx-standalone/recipes-standalone/gcc/gcc-xilinx-standalone.inc
@@ -1,104 +1,40 @@
-# This inc file contains common configuration used for GCC for several
-# MACHINES when using xilinx-standalone a DISTRO.
-# This should be applicable to both cross and cross-canadian toolchain.
+# Any changes to this file should be synced with gcc-runtime_%.bbappend
 
+LINKER_HASH_STYLE_xilinx-standalone = ""
+SYMVERS_CONF_xilinx-standalone = ""
 
-GCC_CONFIGURE_COMMON_XILINX_STANDALONE = " \
-        --disable-libmudflap \
+EXTRA_OECONF_append_xilinx-standalone = " \
         --disable-libstdcxx-pch \
-        --disable-nls \
-        --enable-languages=${LANGUAGES} \
         --with-newlib \
-"
-
-
-GCC_CONFIGURE_A53 ?= " \
-        --disable-bootstrap \
-        --disable-multiarch \
-        --disable-threads \
-        --enable-c99 \
-        --enable-checking=yes \
-        --enable-fix-cortex-a53-835769 \
-        --enable-fix-cortex-a53-843419 \
-        --enable-linker-build-id \
-        --enable-long-long \
-        --enable-lto \
-        --enable-plugins \
-        --enable-shared \
-        --with-arch=armv8-a \
-        --with-cloog=no \
-        --with-gnu-as \
-        --with-gnu-ld \
-        --with-isl=no \
-        --with-ppl=no \
-"
-
-GCC_CONFIGURE_A72 ?= " \
-        --disable-bootstrap \
-        --disable-multiarch \
-        --disable-threads \
-        --enable-c99 \
-        --enable-checking=yes \
-        --enable-linker-build-id \
-        --enable-long-long \
-        --enable-lto \
+        --disable-threads \
+        --enable-plugins \
+        --with-gnu-as \
+        --disable-libitm \
         --enable-multilib \
-        --enable-plugins \
-        --enable-shared \
-        --enable-threads=no \
-        --with-cloog=no \
-        --with-gnu-as \
-        --with-gnu-ld \
-        --with-isl=no \
-        --with-ppl=no \
 "
 
-GCC_CONFIGURE_R5 ?= " \
-        --disable-decimal-float \
-        --disable-libffi \
-        --disable-libgomp \
-        --disable-libquadmath \
-        --disable-libssp \
-        --disable-shared \
-        --disable-threads \
-        --disable-tls \
-        --enable-plugins \
-        --with-gnu-as \
-        --with-gnu-ld \
-        --with-headers=yes \
-        --with-host-libstdcxx=-static-libgcc \
-         --with-multilib-list=rmprofile \
-"
-
-GCC_CONFIGURE_MB ?= " \
-        --disable-__cxa_atexit \
-        --disable-libgomp \
-        --disable-shared \
-        --enable-lto \
-        --enable-target-optspace \
-        --enable-threads=no \
-        --with-isl=no \
-        --with-ppl=no \
-        --without-long-double-128 \
-"
-
-GCC_CONFIGURE_A9 ?= " \
-        --disable-bootstrap \
+EXTRA_OECONF_append_xilinx-standalone_aarch64 = " \
         --disable-multiarch \
-        --disable-nls \
-        --disable-threads \
-        --enable-c99 \
-        --enable-checking=yes \
-        --enable-linker-build-id \
-        --enable-long-long \
-        --enable-lto \
-        --enable-multilib \
-        --enable-plugins \
-        --enable-shared \
-        --with-cloog=no \
-        --with-gnu-as \
-        --with-gnu-ld \
-        --with-isl=no \
-        --with-ppl=no \
-        --with-multilib-list=aprofile \
-"
\ No newline at end of file
+        --enable-fix-cortex-a53-835769 \
+        --enable-fix-cortex-a53-843419 \
+        --with-arch=armv8-a \
+        "
+
+# Both arm and cortexr5 overrides are set w/ r5
+# So only set rmprofile if r5 is defined.
+ARM_PROFILE = "aprofile"
+ARM_PROFILE_cortexr5 = "rmprofile"
+EXTRA_OECONF_append_xilinx-standalone_arm = " \
+        --with-multilib-list=${ARM_PROFILE} \
+        "
+
+EXTRA_OECONF_append_xilinx-standalone_cortexr5 = " \
+        --disable-tls \
+        --disable-decimal-float \
+        "
+
+EXTRA_OECONF_append_xilinx-standalone_microblaze = " \
+        --disable-__cxa_atexit \
+        --enable-target-optspace \
+        --without-long-double-128 \
+        "