qemu: Add target qemu 8.1.2

Backport the QEMU 8.1.x integration from current poky
(commit 4bb222e0d71a4cb159b8a4f1a90b65b1af32ac10).

Split the additional xen/tpm patches by version, disable Xen patches on
the 8.1.2 version, not yet supported.

Signed-off-by: Mark Hatle <mark.hatle@amd.com>

4 files changed, 35 insertions, 0 deletions

diff --git a/meta-xilinx-core/conf/layer.conf b/meta-xilinx-core/conf/layer.conf
index 752eeb37..5f2693cb 100644
--- a/meta-xilinx-core/conf/layer.conf
+++ b/meta-xilinx-core/conf/layer.conf
@@ -49,6 +49,7 @@ BUILDCFG_VARS:append = " SOC_VARIANT XILINX_RELEASE_VERSION"
 XILINX_QEMU_VERSION[v2023.1] = "v7.1.0-xilinx-v2023.1%"
 XILINX_QEMU_VERSION[v2023.2] = "v7.1.0-xilinx-v2023.2%"
 XILINX_QEMU_VERSION[v2024.1] = "v8.1.0-xilinx-v2024.1%"
+PREFERRED_VERSION_qemu ?= "${@ '7.1%' if not (d.getVar('XILINX_RELEASE_VERSION') or 'undefined').startswith('v2024') else '8.1%'}"
 PREFERRED_VERSION_qemu-xilinx ?= "${@d.getVarFlag('XILINX_QEMU_VERSION', d.getVar('XILINX_RELEASE_VERSION')) or 'undefined'}"
 PREFERRED_VERSION_qemu-xilinx-native ?= "${@d.getVarFlag('XILINX_QEMU_VERSION', d.getVar('XILINX_RELEASE_VERSION')) or 'undefined'}"
 PREFERRED_VERSION_qemu-xilinx-system-native ?= "${@d.getVarFlag('XILINX_QEMU_VERSION', d.getVar('XILINX_RELEASE_VERSION')) or 'undefined'}"
diff --git a/meta-xilinx-core/recipes-devtools/qemu/qemu_8.1.2.bb b/meta-xilinx-core/recipes-devtools/qemu/qemu_8.1.2.bb
new file mode 100644
index 00000000..2f9305e1
--- /dev/null
+++ b/meta-xilinx-core/recipes-devtools/qemu/qemu_8.1.2.bb
@@ -0,0 +1,29 @@
+BBCLASSEXTEND = "nativesdk"
+
+FILESEXTRAPATHS:append := ":${THISDIR}/qemu-8.1"
+
+require qemu-8.1.inc
+
+DEPENDS = "glib-2.0 zlib pixman bison-native ninja-native meson-native"
+
+DEPENDS:append:libc-musl = " libucontext"
+
+CFLAGS += "${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', '-DEGL_NO_X11=1', d)}"
+
+RDEPENDS:${PN}-common:class-target += "bash"
+
+EXTRA_OECONF:append:class-target = " --target-list=${@get_qemu_target_list(d)}"
+EXTRA_OECONF:append:class-target:mipsarcho32 = "${@bb.utils.contains('BBEXTENDCURR', 'multilib', ' --disable-capstone', '', d)}"
+EXTRA_OECONF:append:class-nativesdk = " --target-list=${@get_qemu_target_list(d)}"
+
+PACKAGECONFIG ??= " \
+    fdt sdl kvm pie slirp \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'alsa pulseaudio xen', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'virglrenderer epoxy', '', d)} \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'seccomp', d)} \
+"
+PACKAGECONFIG:class-nativesdk ??= "fdt sdl kvm pie slirp \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'virglrenderer epoxy', '', d)} \
+"
+# ppc32 hosts are no longer supported in qemu
+COMPATIBLE_HOST:powerpc = "null"
diff --git a/meta-xilinx-virtualization/recipes-devtools/qemu/qemu_%.bbappend b/meta-xilinx-virtualization/recipes-devtools/qemu/qemu_7.1%.bbappend
index 3e93710c..3e93710c 100644
--- a/meta-xilinx-virtualization/recipes-devtools/qemu/qemu_%.bbappend
+++ b/meta-xilinx-virtualization/recipes-devtools/qemu/qemu_7.1%.bbappend
diff --git a/meta-xilinx-virtualization/recipes-devtools/qemu/qemu_8.1%.bbappend b/meta-xilinx-virtualization/recipes-devtools/qemu/qemu_8.1%.bbappend
new file mode 100644
index 00000000..b1e94b5a
--- /dev/null
+++ b/meta-xilinx-virtualization/recipes-devtools/qemu/qemu_8.1%.bbappend
@@ -0,0 +1,5 @@
+require qemu-tpm.inc
+#require qemu-xen.inc
+
+# We do not want QEMU, on the target to be configured with OpenGL
+PACKAGECONFIG:remove:class-target:petalinux = "virglrenderer epoxy gtk+"