vcontainer: fix yocto-check-layer mcdepends parse error

Fix yocto-check-layer failure:

  ERROR: Multiconfig dependency mc::vruntime-x86-64:vpdmn-initramfs-create:do_deploy
  depends on nonexistent multiconfig configuration named configuration vruntime-x86-64

Several recipes and classes declared static mcdepends referencing
vruntime-aarch64 and vruntime-x86-64 multiconfigs. When parsed without
BBMULTICONFIG set (e.g. yocto-check-layer), BitBake validates these and
fails because the referenced multiconfigs don't exist.

Move mcdepends into anonymous python functions and only set them when
the target multiconfig exists in BBMULTICONFIG, following the pattern
established in meta/classes-recipe/kernel-fit-image.bbclass.

Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>

1 files changed, 12 insertions, 9 deletions

diff --git a/recipes-containers/vcontainer/vcontainer-tarball.bb b/recipes-containers/vcontainer/vcontainer-tarball.bb
index 8d7cecf9..8bbaa85c 100644
--- a/recipes-containers/vcontainer/vcontainer-tarball.bb
+++ b/recipes-containers/vcontainer/vcontainer-tarball.bb
@@ -124,17 +124,20 @@ def get_available_architectures(d):
 #   VCONTAINER_ARCHITECTURES = "aarch64"
 VCONTAINER_ARCHITECTURES ?= "x86_64 aarch64"
 
-# Trigger multiconfig blob builds automatically via mcdepends
-# Build BOTH architectures so a single bitbake command produces a complete SDK
-do_populate_sdk[mcdepends] = "\
-    mc::vruntime-x86-64:vdkr-initramfs-create:do_deploy \
-    mc::vruntime-x86-64:vpdmn-initramfs-create:do_deploy \
-    mc::vruntime-aarch64:vdkr-initramfs-create:do_deploy \
-    mc::vruntime-aarch64:vpdmn-initramfs-create:do_deploy \
-    "
-
 # Print banner at parse time (before builds start)
+# Also conditionally set mcdepends based on available multiconfigs
 python () {
+    # Conditionally set mcdepends based on available multiconfigs
+    # (avoids parse errors when BBMULTICONFIG is not set, e.g. yocto-check-layer)
+    bbmulticonfig = (d.getVar('BBMULTICONFIG') or "").split()
+    mcdeps = []
+    for mc in ['vruntime-x86-64', 'vruntime-aarch64']:
+        if mc in bbmulticonfig:
+            mcdeps.append('mc::%s:vdkr-initramfs-create:do_deploy' % mc)
+            mcdeps.append('mc::%s:vpdmn-initramfs-create:do_deploy' % mc)
+    if mcdeps:
+        d.setVarFlag('do_populate_sdk', 'mcdepends', ' '.join(mcdeps))
+
     # Only print for main multiconfig (not vruntime-* multiconfigs)
     mc = d.getVar('BB_CURRENT_MC') or ''
     if mc == '' and d.getVar('BB_WORKERCONTEXT') != '1':