qttools: use one recipe for all compilations

Instead of separate recipes for target, native and nativesdk, use
one recipe with BBCLASSEXTEND in place.

Signed-off-by: Samuli Piippo <samuli.piippo@theqtcompany.com>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

3 files changed, 9 insertions, 67 deletions

diff --git a/recipes-qt/qt5/nativesdk-qttools_git.bb b/recipes-qt/qt5/nativesdk-qttools_git.bb
deleted file mode 100644
index b217da1f..00000000
--- a/recipes-qt/qt5/nativesdk-qttools_git.bb
+++ /dev/null
@@ -1,42 +0,0 @@
-LICENSE = "GFDL-1.3 & BSD & (LGPL-2.1 & Digia-Qt-LGPL-Exception-1.1 | LGPL-3.0)"
-LIC_FILES_CHKSUM = " \
-    file://LICENSE.LGPLv21;md5=58a180e1cf84c756c29f782b3a485c29 \
-    file://LICENSE.LGPLv3;md5=c4fe8c6de4eef597feec6e90ed62e962 \
-    file://LGPL_EXCEPTION.txt;md5=9625233da42f9e0ce9d63651a9d97654 \
-    file://LICENSE.FDL;md5=6d9f2a9af4c8b8c3c769f6cc1b6aaf7e \
-"
-
-QT_MODULE = "qttools"
-
-DEPENDS = "nativesdk-qtbase qtbase-native"
-
-require nativesdk-qt5.inc
-require qt5-git.inc
-
-SRC_URI += "file://0001-Allow-to-build-only-lrelease-lupdate-lconvert.patch"
-
-PACKAGE_DEBUG_SPLIT_STYLE = "debug-without-src"
-
-FILES_${PN}-dbg = " \
-    ${OE_QMAKE_PATH_BINS}/.debug \
-"
-
-FILES_${PN} = " \
-    ${OE_QMAKE_PATH_BINS}/* \
-"
-
-do_configure() {
-    ${OE_QMAKE_QMAKE} ${OE_QMAKE_DEBUG_OUTPUT} -r ${S} CONFIG+=linguistonly
-}
-
-do_install() {
-    # Fix install paths for all
-    find -name "Makefile*" | xargs sed -i "s,(INSTALL_ROOT)${STAGING_DIR_HOST},(INSTALL_ROOT),g"
-
-    oe_runmake install INSTALL_ROOT=${D}
-
-    # remove things unused in nativesdk
-    rm -rf ${D}${libdir}
-}
-
-SRCREV = "33c65366a7c3901d2aecfde3dbc485e1eac5c10c"
diff --git a/recipes-qt/qt5/qttools-native_git.bb b/recipes-qt/qt5/qttools-native_git.bb
deleted file mode 100644
index cb786978..00000000
--- a/recipes-qt/qt5/qttools-native_git.bb
+++ /dev/null
@@ -1,24 +0,0 @@
-DEPENDS = "qtbase-native"
-
-LICENSE = "GFDL-1.3 & BSD & (LGPL-2.1 & Digia-Qt-LGPL-Exception-1.1 | LGPL-3.0)"
-LIC_FILES_CHKSUM = " \
-    file://LICENSE.LGPLv21;md5=58a180e1cf84c756c29f782b3a485c29 \
-    file://LICENSE.LGPLv3;md5=c4fe8c6de4eef597feec6e90ed62e962 \
-    file://LGPL_EXCEPTION.txt;md5=9625233da42f9e0ce9d63651a9d97654 \
-    file://LICENSE.FDL;md5=6d9f2a9af4c8b8c3c769f6cc1b6aaf7e \
-"
-
-QT_MODULE = "qttools"
-
-require qt5-native.inc
-require qt5-git.inc
-
-do_configure() {
-    ${OE_QMAKE_QMAKE} ${OE_QMAKE_DEBUG_OUTPUT} -r ${S} CONFIG+=linguistonly
-}
-
-do_install() {
-    oe_runmake install INSTALL_ROOT=${D}
-}
-
-SRCREV = "33c65366a7c3901d2aecfde3dbc485e1eac5c10c"
diff --git a/recipes-qt/qt5/qttools_git.bb b/recipes-qt/qt5/qttools_git.bb
index afc89849..a13fb747 100644
--- a/recipes-qt/qt5/qttools_git.bb
+++ b/recipes-qt/qt5/qttools_git.bb
@@ -9,9 +9,11 @@ LIC_FILES_CHKSUM = " \
     file://LICENSE.FDL;md5=6d9f2a9af4c8b8c3c769f6cc1b6aaf7e \
 "
 
-DEPENDS += "qtbase qtdeclarative qtxmlpatterns"
+DEPENDS += "qtbase"
+DEPENDS_class-target = "qtdeclarative qtxmlpatterns"
 
 SRC_URI += " \
+    file://0001-Allow-to-build-only-lrelease-lupdate-lconvert.patch \
     file://0002-assistant-help-fix-linking-of-dependent-libraries.patch \
     file://0003-add-noqtwebkit-configuration.patch \
 "
@@ -20,8 +22,14 @@ FILES_${PN}-tools += "${datadir}/${QT_DIR_NAME}/phrasebooks"
 FILES_${PN}-examples = "${datadir}/${QT_DIR_NAME}/examples"
 
 PACKAGECONFIG ??= ""
+PACKAGECONFIG_class-native ??= "linguistonly"
+PACKAGECONFIG_class-nativesdk ??= "linguistonly"
+PACKAGECONFIG[linguistonly] = ""
 PACKAGECONFIG[qtwebkit] = ",,qtwebkit"
 
 EXTRA_QMAKEVARS_PRE += "${@base_contains('PACKAGECONFIG', 'qtwebkit', '', 'CONFIG+=noqtwebkit', d)}"
+EXTRA_QMAKEVARS_PRE += "${@base_contains('PACKAGECONFIG', 'linguistonly', 'CONFIG+=linguistonly', '', d)}"
 
 SRCREV = "33c65366a7c3901d2aecfde3dbc485e1eac5c10c"
+
+BBCLASSEXTEND = "native nativesdk"