blob: 8f63c76e5e05f2ea50c52918f941488398b6ee26 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
SUMMARY = "Python GObject bindings"
HOMEPAGE = "http://www.pygtk.org/"
SECTION = "devel/python"
LICENSE = "LGPLv2.1"
LIC_FILES_CHKSUM = "file://COPYING;md5=a916467b91076e631dd8edb7424769c7"
GNOMEBASEBUILDCLASS = "meson"
inherit gnomebase gobject-introspection distutils-base upstream-version-is-even
DEPENDS += "python glib-2.0"
SRCNAME = "pygobject"
SRC_URI = " \
http://ftp.gnome.org/pub/GNOME/sources/${SRCNAME}/${@gnome_verdir("${PV}")}/${SRCNAME}-${PV}.tar.xz \
file://0001-python-pyobject-fix-install-dir.patch \
"
SRC_URI[md5sum] = "9d5dbca10162dd9b0d03fed0c6cf865d"
SRC_URI[sha256sum] = "32c99def94b8dea5ce9e4bc99576ef87591ea779b4db77cfdca7af81b76d04d8"
S = "${WORKDIR}/${SRCNAME}-${PV}"
UNKNOWN_CONFIGURE_WHITELIST = "introspection"
PACKAGECONFIG ??= "stagedir"
PACKAGECONFIG[cairo] = "-Dpycairo=true,-Dpycairo=false, cairo python-pycairo, python-pycairo"
PACKAGECONFIG[tests] = "-Dtests=true, -Dtests=false, , "
PACKAGECONFIG[python] = "-Dpython=python3, -Dpython=python2, , "
PACKAGECONFIG[stagedir] = "-Dstagedir=${PYTHON_SITEPACKAGES_DIR}, -Dstagedir="", , "
BBCLASSEXTEND = "native"
RDEPENDS_${PN} = "python-setuptools"
RDEPENDS_${PN}_class-native = ""
do_install_append() {
# Remove files that clash with python3-pygobject; their content is same
rm -r ${D}${includedir}/pygobject-3.0/pygobject.h ${D}${libdir}/pkgconfig
}
|
