1 files changed, 39 insertions, 0 deletions

diff --git a/meta-python/recipes-extended/python-pykickstart/python3-pykickstart_3.69.bb b/meta-python/recipes-extended/python-pykickstart/python3-pykickstart_3.69.bb
new file mode 100644
index 0000000000..c566f5a0e6
--- /dev/null
+++ b/meta-python/recipes-extended/python-pykickstart/python3-pykickstart_3.69.bb
@@ -0,0 +1,39 @@
+DESCRIPTION = "A python library for manipulating kickstart files"
+HOMEPAGE = "https://fedoraproject.org/wiki/pykickstart"
+LICENSE = "GPL-2.0-or-later"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=81bcece21748c91ba9992349a91ec11d"
+
+inherit python_setuptools_build_meta ptest
+
+RDEPENDS:${PN} = "python3 \
+                  python3-requests \
+                  python3-six \
+"
+
+RDEPENDS:${PN}-ptest += " \
+    python3-pytest \
+    python3-unittest-automake-output \
+"
+
+do_install_ptest() {
+    install -d ${D}${PTEST_PATH}/tests
+    cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests
+    for file in `grep -Rl unittest.main ${D}${PTEST_PATH}/tests/`; do
+        dirname=`dirname $file`
+        basename=`basename $file`
+        [ $basename != "__init__.py" ] && mv $file ${dirname}/test_${basename}
+    done
+}
+
+SRC_URI = "git://github.com/rhinstaller/pykickstart.git;protocol=https;branch=master;tag=r${PV} \
+           file://0001-support-authentication-for-kickstart.patch \
+           file://0002-pykickstart-parser.py-add-lock-for-readKickstart-and.patch \
+           file://0003-comment-out-sections-shutdown-and-environment-in-gen.patch \
+           file://0004-load.py-retry-to-invoke-request-with-timeout.patch \
+           file://run-ptest \
+           "
+SRCREV = "601ec2d2f254909f56e2ee961d2056e0d5bc4a97"
+
+UPSTREAM_CHECK_GITTAGREGEX = "r(?P<pver>\d+(\.\d+)+(-\d+)*)"
+