xfce4-settings: move to schnitzeltony's git repo to get new datetime setter

I implemented a datetime setting dialog based on gnome-control-center and
submitted a pull-request in [1,2]. As long as it is not submitted - or as long
as I find no way to patch binary files (e.g. icons - I asked for that in [3] -
no response yet) we use the git repo and a copied branch of the pull-request
(just in case some feedback from xfce-devels requires modifcations).

Some patches had to be modified/removed to apply against mainline HEAD still.
Furthermore in 0002-mouse-settings-dialog-add-touchscreen-pointer-option.patch
label 'alignment8' was introduced mainline and we do not need mouse-dialog_ui.h
when building from git in maintainer-mode - this file is created during build
process.

[1] http://mail.xfce.org/pipermail/xfce4-dev/2013-September/030442.html
[2] https://bugzilla.xfce.org/show_bug.cgi?id=10354
[3] http://lists.openembedded.org/pipermail/openembedded-core/2013-September/083804.html

Signed-off-by: Andreas Müller <schnitzeltony@googlemail.com>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

1 files changed, 45 insertions, 0 deletions

diff --git a/meta-xfce/recipes-xfce/xfce4-settings/xfce4-settings_git.bb b/meta-xfce/recipes-xfce/xfce4-settings/xfce4-settings_git.bb
new file mode 100644
index 0000000000..4b75dd7ee6
--- /dev/null
+++ b/meta-xfce/recipes-xfce/xfce4-settings/xfce4-settings_git.bb
@@ -0,0 +1,45 @@
+DESCRIPTION = "Xfce4 settings"
+SECTION = "x11/wm"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
+DEPENDS = "exo garcon gtk+ libxfce4util libxfce4ui xfconf dbus-glib libxi virtual/libx11 xrandr libnotify libxcursor libxklavier"
+
+inherit xfce
+
+SRC_URI = " git://gitorious.org/xfce/xfce4-settings.git;protocol=git;branch=for-oe \
+            file://0001-xsettings.xml-remove-trouble-causing-comment.patch \
+            file://0002-xsettings.xml-Set-default-themes.patch \
+            file://touchscreen/invisible \
+            file://touchscreen/wait \
+            file://touchscreen/0001-add-cursor-theme-xfce-invisible.patch \
+            file://touchscreen/0002-mouse-settings-dialog-add-touchscreen-pointer-option.patch \
+            file://touchscreen/0003-XfcePointersHelper-gets-a-pointer-to-XfceXSettingsHe.patch \
+            file://touchscreen/0004-XfceXSettingsHelper-gets-a-property-touchscreen-poin.patch \
+            file://touchscreen/0005-pointers-detect-a-change-of-pointer-device-used-and-.patch \
+"
+SRCREV = "b7a0e1fd77f5bb5c372223ff62aec7acf252f061"
+S = "${WORKDIR}/git"
+PV = "4.10.0+git${SRCPV}"
+ 
+EXTRA_OECONF += "--enable-maintainer-mode --disable-debug"
+
+PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES','systemd','datetime-setter','',d)}"
+PACKAGECONFIG[datetime-setter] = "--enable-datetime-settings, --disable-datetime-settings,, tzdata"
+PACKAGECONFIG[notify] = "--enable-libnotify,--disable-libnotify,libnotify"
+
+do_configure_prepend() {
+    NOCONFIGURE=yes ./autogen.sh
+}
+
+FILES_${PN} += " \
+    ${libdir}/xfce4 \
+    ${datadir}/xfce4 \
+"
+
+do_install_prepend() {
+    # somehow binary files are not patched correctly by oe-patch - so copy them
+    cp ${WORKDIR}/touchscreen/invisible ${S}/cursors
+    cp ${WORKDIR}/touchscreen/wait ${S}/cursors
+}
+
+RRECOMMENDS_${PN} += "gnome-icon-theme"